Executing External Programs/es

From Free Pascal wiki
Jump to: navigation, search

Deutsch (de) English (en) español (es) français (fr) italiano (it) 日本語 (ja) Nederlands (nl) português (pt) русский (ru) slovenčina (sk)

Introducción

   Hay varias formas de ejecutar programas externos, pero nos centraremos en una, TProcess.

Si en Delphi utilizabas siempre ShellExecute y/o WinExec, puedes empezar a usar TProcess como alternativa en FPC/Lazarus (es válido también si estás ejecutando Lazarus en Linux, porque TProcess es multiplataforma).

   Nota: FPC/Lazarus puede utilizar ShellExecute y/o WinExec, pero sólo en Win32. Si tu programa está enfocado a varias plataformas, utiliza TProcess, ¡es mejor!.


Aquí tenemos las diferentes maneras disponibles sobre como ejecutar un programa/proceso/mandato externo en RTL, FCL y LCL.

Metodo Librería Plataformas Línea simple Características
ExecuteProcess RTL Plataforma Cruzada Si Muy limitado, synchronous
ShellExecute WinAPI MS Windows only Yes Muchos. Permite iniciar programas con permisos de elevación/admin.
fpsystem, fpexecve Unix Unix solamente
TProcess FCL Plataforma cruzada No Completas
RunCommand FCL Plataforma cruzada, Requiere FPC 2.6.2+ Si Cubre el uso común de TProcess
OpenDocument LCL Plataforma cruzada si Solo para abrir documentos. El documento debe abrirse con la aplicación asociada al tipo de documento.

TProcess

   Puedes utilizar TProcess para ejecutar programas externos. Algunas de sus ventajas son:

  • Independiente de la plataforma
  • Capaz de leer desde la entrada estándar (stdout) y de escribir en la salida estándar (stdin).

   Nota: TProcess no es un terminal de shell! No puedes ejecutar directamente secuencias de comandos o reorientar la salida usando operadores como "|", ">", "<", "&", etc. Es posible obtener los mismos resultados con TProcess utilizando Pascal, mira algunos ejemplos más abajo..

   Importante: Debes especificar la ruta completa al ejecutable. Por ejemplo "/bin/cp " en lugar de "cp". Si el programa está en la ruta estándar, puedes utilizar la función FindDefaultExecutablePath de la unidad FileUtil de la LCL.

Un ejemplo sencillo

 // Este es un programa de demostración que enseña como lanzar
 // un programa externo.
 program lanzarprograma;
 
 uses 
   Classes, SysUtils, Process;
 
 // Definición de "UnProceso" como una variable 
 // de tipo "TProcess"
 var 
   UnProceso: TProcess;
 
 begin
   // Ahora creamos UnProceso.
   UnProceso := TProcess.Create(nil);
 
   // Asignamos a UnProceso la orden que debe ejecutar.
   // Vamos a lanzar el compilador de FreePascal 
   UnProceso.CommandLine := 'ppc386 -h';
 
   // Definimos una opción de comportamiento de 'TProccess'
   // La opción poWaitOnExit hará que nuestro programa
   // se detenga hasta que termine el programa lanzado
   UnProceso.Options := UnProceso.Options + [poWaitOnExit];
 
   // Lanzamos la ejecución de 'ppc386 -h'.
   UnProceso.Execute;
 
   // Nuestro programa espera hasta que 'ppc386' finaliza.
   UnProceso.Free;   
 end.

   ¡Eso es todo! Acabas de aprender cómo se ejecuta un programa externo desde dentro de tu propio programa.

Un ejemplo mejorado

   De acuerdo, pero ¿cómo leo la salida que produce un programa que he ejecutado?

   Bien, vamos a ampliar un poco nuestro ejemplo mediante lo siguiente:

 program lanzarprograma2;
 
 uses 
   Classes, SysUtils, Process;
 
 // Definición de "UnProceso" como una variable de tipo "TProcess"
 // También añadimos un TStringList para almacenar los datos 
 // leídos desde la salida del programa.
 var 
   UnProceso: TProcess;
   UnaLista: TStringList;
 
 // Aquí comienza a ejecutarse nuestro programa.
 begin
 
   // Creamos el objeto TStringList.
   UnaLista := TStringList.Create;
 
   // Ahora creamos UnProceso.
   UnProceso := TProcess.Create(nil);
 
   // Asignamos a UnProceso la orden que debe ejecutar.
   // Vamos a lanzazar el compilador de FreePascal 
   UnProceso.CommandLine := 'ppc386 -h';
 
   // Definimos una opción de comportamiento de 'TProccess'
   // La opción poWaitOnExit hará que nuestro programa
   // se detenga hasta que termine el programa lanzado
   // con la opción poUsePipes    advertimos que vamos a utilizar tuberías de Entrada/Salida                                        
   // para que se capture la salida y así poder recuperar su contenido desde nuestro programa
 
   UnProceso.Options := UnProceso.Options + [poWaitOnExit, poUsePipes];
 
   // Lanzamos la ejecución de 'ppc386 -h'.
   UnProceso.Execute;
 
   // Nuestro programa se detiene hasta que 'ppc386' finaliza.
 
   // Ahora leemos la salida del programa que acabamos de ejecutar
   // dentro de TStringList.
   UnaLista.LoadFromStream(UnProceso.Output);
 
   // Guardamos la salida en un archivo.
   UnaLista.SaveToFile('salida.txt');
 
   // Ahora que hemos guardado el archivo podemos liberar la memoria
   // TStringList y TProcess.
   UnaLista.Free;
   UnProceso.Free;   
 end.

Lectura de muchos datos de salida

   En el ejemplo anterior esperamos a que el programa termine. En ese momento leemos lo que el programa ha escrito en la salida. Pero si el programa escribe muchos datos, la tubería se llena y será necesario leerlos para vaciarla, pero el programa llamante no leerá hasta que el programa llamado haya terminado. Nos encontraremos ante un típico bloqueo de la muerte.

   El siguiente ejemplo, por tanto, no utiliza poWaitOnExit, sino que va leyendo la salida mientras el programa llamado se está ejecutando. La salida se almacena en una memoria intermedia, que se utilizará más tarde para leer en un TStringList, por ejemplo.

 program procoutlarge;
 {   Copyright (c) 2004 by Marc Weustink
 
     Este ejemplo se ha creado con la esperanza de que resulte útil,
     pero SIN NINGUNA GARANTÍA; ni tan siquiera la garantía implícita de
     COMERCIALIZACIÓN o ADECUACIÓN A UN OBJETIVO PARTICULAR.
 }
 
 uses
   Classes, Process, SysUtils;
 
 const
   READ_BYTES = 2048;
 
 var
   S: TStringList;
   M: TMemoryStream;
   P: TProcess;
   n: LongInt;
   BytesRead: LongInt;
 
 begin
   // No podemos utilizar poWaitOnExit porque no
   // conocemos el tamaño de la salida. En Linux el tamaño
   // de la salida de la tubería es de 2 kB. Si los datos de salida son más 
   // necesitamos leerlos. Esto no es posible, ya que estamos
   // esperando. Así que aquí nos encontramos en un punto muerto.
   //
   // Se utiliza un Memorystream temporal para almacenar la salida
 
   M := TMemoryStream.Create;
   BytesRead := 0;
 
   P := TProcess.Create(nil);
   P.CommandLine := 'ppc386 -va bogus.pp';
   P.Options := [poUsePipes];
   WriteLn('-- ejecutando --');
   P.Execute;
   while P.Running do
   begin          
     // nos aseguramos de tener espacio
     M.SetSize(BytesRead + READ_BYTES);
 
     // intentamos leerlo
     n := P.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
     if n > 0 
     then begin
       Inc(BytesRead, n);
       Write('.')
     end
     else begin     
       // sin datos, esperamos 100 milisegundos
       Sleep(100); 
     end;
   end;
   // leemos la última parte
   repeat
     // nos aseguramos de tener espacio
     M.SetSize(BytesRead + READ_BYTES);
     // intentamos leerlo
     n := P.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
     if n > 0 
     then begin
       Inc(BytesRead, n);
       Write('.');
     end;
   until n <= 0;
   if BytesRead > 0 then WriteLn;
   M.SetSize(BytesRead); 
   WriteLn('-- ejecutado --');
 
   S := TStringList.Create;
   S.LoadFromStream(M);
   WriteLn('-- total de líneas = ', S.Count, ' --');
   for n := 0 to S.Count - 1 do
   begin
     WriteLn('| ', S[n]);
   end;
   WriteLn('-- fin --');
   S.Free;
   P.Free;
   M.Free;
 end.

Uso de entrada y salida de un TProcess

   Véase el ejemplo processdemo en Lazarus-CCR SVN

Notas sobre la utilización de TProcess

   Si estas creando un programa que funciones en diversas plataformas, puedes cambiar el programa a ejecutar de acuerdo con el sistema operativo, mediante las directivas {$IFDEF} y {$ENDIF}.

   Ejemplo:

 {...}
   unProceso:TProcess.Create(nil)
   {$IFDEF WIN32}
   unProceso.CommandLine := 'calc.exe'; //calculadora de Windows
   {$ENDIF}
   {$IFDEF LINUX}
   unProceso.CommandLine := 'kcalc'; //calculadora de KDE o bien xcalc si no tienes KDE
   {$ENDIF}
   unProceso.Execute; //también puedes utilizar unProceso.Active:=True
 {...}

En cuanto a TProcess tomando como referencia las propiedades del componente visual tiene las siguientes opciones (po=process options):

  • poDebugOnlyThisProcess.
  • poDebugProcess.
  • poDefaultErrorMode
  • poNewConsole.
  • poNewProcessGroup.
  • poNoConsole.
  • poRunSuspended.
  • poStderrToOutPut.
  • poUsePipes: utilizado para interconectar procesos.
  • poWaitOnExit: esperar a que finalice el programa.
TProcess Options.PNG

A falta de explicar que hace cada opción.

Referencia TProcess.

Ejemplo de conversación con el proceso aspell

   Dentro del código fuente pasdoc puedes encontrar dos unidades que realizan corrección ortográfica conversando con un proceso aspell a través de tuberías:

  • PasDoc_ProcessLineTalk.pas unit ejecuta la clase TProcessLineTalk, descendiente de TProcess, que se puede utilizar fácilmente para comunicar con cualquier proceso línea a línea.
  • PasDoc_Aspell.pas units ejecuta la clase TAspellProcess, que realiza corrección ortográfica utilizando la instancia fundamental TProcessLineTalk para ejecutar aspell y comunicarse con el proceso aspell que se está ejecutando.

   Ambas unidades son bastante independientes del resto de fuentes de pasdoc, así que pueden servir como ejemplos reales de la utilización de TProcess para ejecutar y comunicarse a través de tuberías con otros programas.

Reemplazar operadores de Shell como "|", "<" y ">"

   A veces queremos ejecutar una orden compleja que envía (entuba) sus datos a otra orden o a un archivo. Algo como

 ShellExecute('primeraorden.exe | segundaorden.exe');

o

 ShellExecute('dir > salida.txt');

    Esto no funciona con TProcess. p.e.:

 // esto no funciona
 Process.CommandLine := 'primeraorden.exe | segundaorden.exe'; 
 Process.Execute;

¿Por qué utilizar operadores especiales para redirigir la salida no funciona?

   TProcess es justamente, eso, un proceso, no es un entorno de shell. No es dos procesos, únicamente es un proceso. Es posible, no obstante, redirigir la salida de la manera que queremos. Ver más adelante, la siguiente sección.

Cómo redirigir la salida con TProcess

   Podemos redirigir la salidad de un comando a otro comando utilizando una instancia de TProcess para cada commando.

   Este es un ejemplo que explica cómo redirigir la salida de un proceso a otro. Para redirigir la salida de un proceso a un archivo o flujo ver el ejemplo Lectura de muchos datos de salida

 program Proyecto1;
 
  uses
    Classes, sysutils, process;
 
  var
    PrimerProceso,
    SegundoProceso: TProcess;
    Buffer: array[0..127] of char;
    ContadorLectura: Integer;
    TamanyoLectura: Integer;
  begin
    PrimerProceso  := TProcess.Create(nil);
    SegundoProceso := TProcess.Create(nil);
 
    PrimerProceso.Options  := [poUsePipes];
    SegundoProceso.Options := [poUsePipes,poStderrToOutPut];
 
    PrimerProceso.CommandLine  := 'pwd';
    SegundoProceso.CommandLine := 'grep '+ DirectorySeparator+ ' -';
    // esto sería lo mismo que "pwd | grep / -"
 
    PrimerProceso.Execute;
    SegundoProceso.Execute;
 
    while PrimerProceso.Running or (PrimerProceso.Output.NumBytesAvailable > 0) do
    begin
      if PrimerProceso.Output.NumBytesAvailable > 0 then
      begin
      // asegurate de que no lees más datos que los asignados
      // en el buffer
        TamanyoLectura := PrimerProceso.Output.NumBytesAvailable;
        if TamanyoLectura > SizeOf(Buffer) then
          TamanyoLectura := SizeOf(Buffer);
        // ahora leemos la salida en el buffer
        ContadorLectura := PrimerProceso.Output.Read(Buffer[0], TamanyoLectura);
        // y escribimos el buffer en el segundo proceso
        SegundoProceso.Input.Write(Buffer[0], ContadorLectura);
 
        // Si SegundoProceso escribe muchos datos en la salida a continuación,
        // debes leer los datos aquí para evitar un punto muerto
        // ver el ejemplo anterior "Lectura de muchos datos de salida"
      end;
    end;
    // Cerrar la entrad de SegundoProceso
    // y finaliza el procesamiento de datos
    SegundoProceso.CloseInput;
 
     // y esperar a que finalice
     // ten cuidado con que comando se ejecuta porque no puede terminar cuando
     // la entrada está cerrada y la siguiente línea será un bucle sin fin
    while SegundoProceso.Running do
      Sleep(1);
     // ¡eso es todo! el resto del programa es sólo un ejemplo
     // es poco "útil"
 
     // vamos a  reutilizar el buffer para la salida del SegundoProceso
     // a la salida estándar de este programa
    WriteLn('Comienza la salida de Grep:');
    TamanyoLectura := SegundoProceso.Output.NumBytesAvailable;
    if TamanyoLectura > SizeOf(Buffer) then
      TamanyoLectura := SizeOf(Buffer);
    if TamanyoLectura > 0 then
    begin
      ContadorLectura := SegundoProceso.Output.Read(Buffer, TamanyoLectura);
      WriteLn(Copy(Buffer,0, ContadorLectura));
    end
    else
      WriteLn('grep NO encontró lo que se buscaba. ', SegundoProceso.ExitStatus);
    WriteLn('Termina la salida de Grep:');
 
    // Liberamos los objetos TProcess
    PrimerProceso.Free;
    SegundoProceso.Free;
  end.

   Eso es todo. Ahora podemos redirigir la salida de un programa a otro.

Notas

   Este ejemplo puede parecer exagerado, ya que es posible ejecutar "complicados" comandos shell con TProcess como:

 Process.Commandline := 'sh -c "pwd | grep / -"';

   Pero el ejemplo es más multiplataforma, ya que no necesita ninguna modificación para ejecutarse en Windows o Linux, etc. sh puede o no existir en su plataforma y, en general sólo disponible en plataformas *nix. También tenemos más flexibilidad en nuestro ejemplo ya que se puede leer y escribir desde/a la entrada, salida y salida de error estándar de cada proceso individual, lo que podría ser muy ventajoso para tu proyecto.

Redirigir entrada y salida bajo root

   Un problema común en Unix (OSX) y Linux surge cuando se desea ejecutar algún programa en la cuenta de root (o, en otra cuenta de usuario). Un ejemplo sería ejecutar el comando ping'.

   Si puedes usar sudo para esto, se puede adaptar el ejemplo siguiente, una adaptación de uno publicado por andyman en el foro ([1]). Este ejemplo ejecuta la orden ls en el /root, pero por supuesto puede ser adaptada.

   "Una forma mejor de hacerlo es usar el paquete PolicyKit, que debería estar disponible en todos los Linux recientes. ver el hilo del foro para más detalles.

   Gran parte de este código es similar al ejemplo anterior, pero también se muestra cómo redirigir los flujos stdout y stderr del proceso llamado a los flujos stdout y stderr de nuestro propio código.

 program rootls;
 
 { Demonstrates using TProcess, redirecting stdout/stderr to our stdout/stderr,
 calling sudo on Linux/OSX, and supplying input on stdin}
 {$mode objfpc}{$H+}
 
 uses
   Classes,
   Math, {for min}
   Process;
 
   procedure RunsLsRoot;
   var
     Proc: TProcess;
     CharBuffer: array [0..511] of char;
     ReadCount: integer;
     ExitCode: integer;
     SudoPassword: string;
   begin
     WriteLn('Please enter the sudo password:');
     Readln(SudoPassword);
     ExitCode := -1; //Start out with failure, let's see later if it works
     Proc := TProcess.Create(nil); //Create a new process
     try
       Proc.Options := [poUsePipes, poStderrToOutPut]; //Use pipes to redirect program stdin,stdout,stderr
       Proc.CommandLine := 'sudo -S ls /root'; //Run ls /root as root using sudo
       // -S causes sudo to read the password from stdin.
       Proc.Execute; //start it. sudo will now probably ask for a password
 
       // write the password to stdin of the sudo program:
       SudoPassword := SudoPassword + LineEnding;
       Proc.Input.Write(SudoPassword[1], Length(SudoPassword));
       SudoPassword := '%*'; //short string, hope this will scramble memory a bit; note: using PChars is more fool-proof
       SudoPassword := ''; // and make the program a bit safer from snooping?!?
 
       // main loop to read output from stdout and stderr of sudo
       while Proc.Running or (Proc.Output.NumBytesAvailable > 0) or
         (Proc.Stderr.NumBytesAvailable > 0) do
       begin
         // read stdout and write to our stdout
         while Proc.Output.NumBytesAvailable > 0 do
          begin
           ReadCount := Min(512, Proc.Output.NumBytesAvailable); //Read up to buffer, not more
           Proc.Output.Read(CharBuffer, ReadCount);
           Write(StdOut, Copy(CharBuffer, 0, ReadCount));
          end;
         // read stderr and write to our stderr
         while Proc.Stderr.NumBytesAvailable > 0 do
          begin
           ReadCount := Min(512, Proc.Stderr.NumBytesAvailable); //Read up to buffer, not more
           Proc.Stderr.Read(CharBuffer, ReadCount);
           Write(StdErr, Copy(CharBuffer, 0, ReadCount));
          end;
       end;
       ExitCode := Proc.ExitStatus;
     finally
       Proc.Free;
       Halt(ExitCode);
    end;
  end;
 
 begin
   RunsLsRoot;
 end.

   Otras cuestiones:

   Sería, sin duda, aconsejable ver si realmente sudo pide una contraseña. Esto se puede comprobar consistetemente estableciendo la variable de entorno SUDO_PROMPT a algo que tener en cuenta mientras la lectura de la salida estándar de TProcess para evitar el problema de que el sistema es diferente para diferentes idiomas. Configurar una variable de entorno hace que los valores predeterminados (heredados de nuestro proceso) se borren, así que tenemos que copiar el entorno de nuestro programa, si es necesario.

Parámetros que contienen espacios (Reemplazar comillas del interprete)

   En el interprete de Linux, es posible escribir los argumentos entrecomillados así:

 gdb --batch --eval-command="info symbol 0x0000DDDD" miprograma

   Y GDB recibirá 3 argumentos (además del primer argumento que es la ruta completa al ejecutable):

 #--batch
 #--eval-command=info symbol 0x0000DDDD
 #la ruta completa a miprograma

   TProcess además pasa los parámetros que contengan espacios, pero utiliza un estilo diferente de entrecomillado. En lugar de sólo entrecomillar parte del parámetro, entrecomilla todo él. Tal que así:

 TProcess.CommandLine := '/usr/bin/gdb --batch "--eval-command=info symbol 0x0000DDDD" /midirectorio/yo/miprograma';

   Y también recuerda pasar sólo rutas completas.

   Véase también la discusión al respecto: http://bugs.freepascal.org/view.php?id=14446

Alternativas

   A veces, no es necesario llamar explícitamente a un programa externo para obtener la funcionalidad que necesitas. A continuación se presentan algunos ejemplos

Abrir una página web en el navegador web predeterminado

   Algo así sería más fácil:

 uses LCLIntf;
 ...
 OpenURL(URL);

   Sin embargo, puedes utilizar algo como esto:

 uses Process, LCLIntf;
 
 procedure OpenWebPage(URL: string);
 // Apparently you need to pass your URL inside ", like "www.lazarus.freepascal.org"
 var
   Browser, Params: string;
 begin
  FindDefaultBrowser(Browser, Params);
  with TProcess.Create(nil) do
  try
    Executable := Browser;
    Params:=Format(Params, [URL]);
    Params:=copy(Params,2,length(Params)-2); // elimina "", la nueva versión de TProcess.Parameters los hace por sí mismo
    Parameters.Add(Params);
    Options := [poNoConsole];
    Execute;
  finally
    Free;
  end;
 end;

Ver también