LazActiveX/es

From Free Pascal wiki
Jump to: navigation, search

English (en) español (es)

Resumen

   El paquete LazActiveX contiene el componente TActiveXContainer y la integración con el IDE de las herramientas necesarias para crear componentes ActiveX desde una librería de tipos o directamente desde el objeto (exe o dll). ActiveX es una tecnología de Microsoft Windows y sólo se puede utilizar en esa plataforma. Compilación cruzada para Windows es posible, pero el importador de librerías de tipos (typelib) para crear los enlaces COM sólo funciona en Windows (no probado en Wine)

Instalación

   Aviso: LazActiveX necesita FPC >= 2.6.1. La importación de librerías de tipos sólo funciona en Windows XP o posterior.

   Desde la opción del menú 'Paquete'/'Instalar/Desinstalar Paquetes ...' en la ventana, seleccionar LazActiveX 0.1, y dar al botón 'Instalar Seleccionado' y después a 'Guardar y Reconstruir el IDE'. Alternativamente, abrir el paquete LazActiveX.lpk y pulsar en 'Usar >>'/'Instalar'.

   Cuando la instalación termine correctamente, una nueva pestaña 'ActiveX' se añade a la paleta de componentes.

LazActiveX-Install1.png

Utilización

   Existen 3 maneras diferentes de utilizar los componentes de ActiveX:

  1. Poner el componente TActiveXContainer en un formulario y asignar el nombre de la clase ActiveX a la propiedad OleClassName. Adecuado para el enlace en tiempo de ejecución ( o tardío) y sin el apoyo directo para eventos.
  2. Importar la biblioteca de tipo ActiveX, poner el componente TActiveXContainer en un formulario, crear una instancia del objeto ActiveX y asignarlo a la propiedad ComServer. Adecuado para el enlace en tiempo de compilación (o temprano) y con el apoyo para eventos.
  3. Crear un nuevo componente desde la librería de tipos o el objeto y poner nuevo componente en el formulario. Esto también utiliza enlace anticipado y tiene soporte completo para eventos. Los controladores de eventos pueden ser asignados desde el IDE.

Enlace tardío de TActiveXContainer

   Aunque la teoría es bastante compleja, el enlace en tiempo de ejecución (o tardío) es la manera más rápida para crear y ejecutar un componente ActiveX.

   Por enlace tardío se refiere el hecho de que la interfaz con el objeto se realiza completamente en tiempo de ejecución. Las referencias a objetos se almacenan como dispinterfaces en variables variant y los métodos y propiedades de los objetos se descubren en tiempo de ejecución. El compilador genera toda la magia de tiempo de ejecución para ti, pero el inconveniente es que el compilador no es capaz de ayudar a encontrar los nombres de los métodos o propiedades en tiempo de diseño. Una buena documentación para el objeto ActiveX es muy importante (el código de ejemplo para VB puede ser fácilmente traducido a pascal). Todos los errores en los nombres de método y sus parámetros serán errores en tiempo de ejecución. El descubrimiento en tiempo de ejecución también agregará sobrecarga al proceso.

   Ejemplo: Embeber el reproductor VLC en un formulario. ¡VLC ha de estar correctamente instalado!

  • Colocar un TActiveXContainer, un TButton y un TFileNameEdit en un formulario.
  • Da el tamaño y la posición deseada al componente TActiveXContainer y escribe 'VideoLAN.VLCPlugin.2' en la propiedad OleClassName, pon a verdadera la propiedad Active. Esto dará un formulario similar a este:

LazActiveX-VLC-Form.png

  • Crea un evento Onclick para el botón con este código:
 procedure TForm1.Boton1Click(Sender: TObject);
 var
   Actx:variant;
 begin
   Actx:=ActiveXContainer1.ComServer;
   Actx.playlist.add(widestring(FileNameEdit1.FileName));
   Actx.playlist.play;
 end;
  • Ejecuta el programa, selecciona una película y haz clic en el botón para verla. Ten en cuenta que VLC junto con gdb parecen causar algunos problemas (lenta puesta en marcha en el mejor de los casos, se cuelga o se bloquea). Mejor ejecuta el programa fuera del IDE.

Enlace temprano de TActiveXContainer

   El Enlace temprano permite conocer todos los interfaces al compilador. Así que tenemos que crear los enlaces pascal para el objeto ActiveX. La herramienta importtl.exe en el directorio utils FPC lo hace por ti y crea coclases y detectores de eventos para facilitar el uso de los objetos en pascal. Una interfaz gráfica de usuario para la herramienta importtl.exe está integrada con el paquete LazActiveX y es accesible en el menú Herramientas: Import Type Library

LazActiveX-Importtl.png

   Marca 'Convert dependent typelibs' para convertir también las librerías de tipos para los objetos COM que son finalmente utilizados por el objeto seleccionado. Al hacer clic en Aceptar, se comenzará la importación de librería de tipos y creará nuevas unidades en el IDE. Las unidades tienen la siguiente nomenclatura: NombreLibreriaVersionMayor_VersionMenor_TLB. Ej: Access_9_0_TLB.

Usuarios Delphi: Los nombres de unidad en Delphi no utilizan los números de versión.

   La creación de instancias de un objeto ActiveX se realiza en tiempo de ejecución mediante una llamada al método Create para la CoClass apropiado creado para la librería. Algunas librerías ActiveX exponen varios objetos y por tanto se crean múltiples coclases. Consulta la documentación de la librería ActiveX en caso de duda. Asignar el objeto instanciado ActiveX a la propiedad de un ComServer TActiveXContainer en un formulario y establecer la propiedad Active en True es todo lo que se necesita para embeberlo en la aplicación

   Ejemplo: Embeber el reproductor VLC en un formulario. ¡VLC ha de estar correctamente instalado!

  • Pon un TActiveXContainer, un TButton y un TFileNameEdit en un formulario. Da el tamaño y la posición deseada al componente TActiveXContainer.
  • Abre 'Import Type Library' desde el menú de herramientas y selecciona 'axvlc.dll' en el directorio de instalación de VLC. Clic OK. Se creará la unidad AXVLC_1_0_TLB.
  • Añade AXVLC_1_0_TLB a la cláusula uses.
  • Crea un evento OnClick para el botón y un evento OnCreate para el formulario. Escribe el siguiente código:
 var
   VLC:IVLCControl2;
 
 procedure TForm1.Button1Click(Sender: TObject);
  begin
    VLC.playlist.add(utf8decode(FileNameEdit1.FileName),'',vararrayof([':aspect-ratio=16:9']));
    VLC.playlist.play;
  end;
 
 procedure TForm1.FormCreate(Sender: TObject);
  begin
    VLC:=CoVLCPlugin2.Create;
    ActiveXContainer1.ComServer:=VLC;
    ActiveXContainer1.Active:=true;
  end;
  • Ejecuta el programa, selecciona una película y pulsa el botón para verla.

   El importador de tipos de librerías también añade soporte para los eventos que el ActiveX genera. En este caso, junto a la CoClass se define un descendiente de TEventSink para implementar el objeto ActiveX y todas sus propiedades OnEvent. Utiliza el descendiente de TEventSink en lugar de la CoClass si deseas utilizar los eventos. Su nombre empieza con TEvs seguido por el nombre de la clase.

Ejamplo: Internet Explorer en un formulario con soporte de eventos.

  • Pon un a TActiveXContainer, un TButton, un TLabel y un TEdit en un formulario. Da el tamaño y la posición deseada al componente TActiveXContainer.
  • Abre 'Import Type Library' desde le menú Herramientas y selecciona 'C:\WINDOWS\system32\ieframe.dll'. Pulsa OK. Se creará la unidad SHDocVw_1_1_TLB.
  • Añade la unidad SHDocVw_1_1_TLB a la cláusula uses.
  • Crea un evento OnClick para el botón y un evento OnCreate para el formulario.
  • Crea en la clase TForm1 el procedimiento privado OnStatusTextChange(Sender: TObject;Text_:WideString);
  • Escribe este código:
 var
  Browser:TEvsWebBrowser;
 
 procedure TForm1.Button1Click(Sender: TObject);
  var
   url,onull:Olevariant;
 
  begin
    url:=Utf8decode(Edit1.Text);
    onull:=NULL;
    Browser.ComServer.Navigate2(url,onull,onull,onull,onull);
  end;
 
 procedure TForm1.FormCreate(Sender: TObject);
  begin
    Browser:=TEvsWebBrowser.Create(Self);
    ActiveXContainer1.ComServer:=Browser.ComServer;
    ActiveXContainer1.Active:=true;
    Browser.OnStatusTextChange:=@OnStatusTextChange;
  end;
 
 procedure TForm1.FormDestroy(Sender: TObject);
  begin
    Browser.Free;
  end; 
 
 procedure TForm1.OnStatusTextChange(Sender: TObject; Text_: WideString);
  begin
    Label1.Caption:=UTF8Encode(Text_);
  end;
  • Ejecuta el programa, introduce una URL en el control de edición y haz clic en el botón para navegar hasta la dirección URL. Label1 mostrará los mensajes de estado enviados por el navegador.
  • Para acceder al objeto de documento (DOM), tienes que importar también la biblioteca de tipos de C:\WINDOWS\system32\mshtml.tlb y añadir la unidad MSHTML_4_0_TLB creada a la cláusula uses. Para mostrar por ejemplo el contenido de la etiqueta <body> de la página descargada, agrega un TMemo y un segundo TButton al formulario y agrega el siguiente código
 procedure TForm1.Button2Click(Sender: TObject);
  var  Doc: IHTMLDocument2; //defined in MSHTML_4_0_TLB
   begin
     Doc := Browser.ComServer.Document as IHTMLDocument2;
     Memo1.Lines.Text := utf8encode(Doc.parentWindow.document.Get_body.innerHTML);
   end;

   Ten en cuenta que coclases no se destruye. Como todos los objetos COM tiene un contador de referencias y se destruyen cuando la última referencia está fuera de ámbito. El descendiente TEventSink tiene que ser destruido.

Crear componentes visuales ActiveX desde objetos de librerías de tipos

   En lugar de utilizar el componente TActiveXContainer directamente la herramienta importtl puede crear descendientes de TActiveXContainer para cada objeto ActiveX incluido en la librería de tipos y crear un paquete lpk. Los descendientes tienen soporte completo para los eventos generados por los objetos. Para crear un paquete con los componentes ActiveX abre el diálogo 'Import Type Library' desde el menú 'Herramientas'. Selecciona la librería a importar, marca 'Create package' y adicionalmente 'Convert dependent typelibs', haz clic en 'OK' para crear el paquete. Se preguntará por un directorio para almacenar el paquete. Instala el nuevo paquete. Después de la reconstrucción de Lazarus encontrarás los nuevos componentes en la pestaña ActiveX de la paleta de componentes.

LazActiveX-Install2.png

Ejemplo: Embeber el reproductor VLC en un formulario. ¡VLC ha de estar instalado correctamente!

  • Abre 'Import Type Library' desde el menú Herramientas y selecciona 'axvlc.dll' en el directorio de instalación de VLC. Marca 'Create package'. Haz clic en Aceptar. Selecciona un directorio para almacenar el paquete. El paquete AXVLC_1_0_TLBP y todas las unidades necesarias se crearan. Instala el paquete AXVLC_1_0_TLBP y reconstruye el IDE.
  • Pon un TAxcVLCPlugin2 (desde la pestaña de componentes ActiveX), un TButton y un TFileNameEdit en un formulario.
  • Establece TAxcVLCPlugin2.Active en true y cambia el tamaño y la posición de TActiveXContainer a tu gusto.
  • Crea un evento de clic para el botón y escribe:
 uses variants;
   ...
  procedure TForm1.Button1Click(Sender: TObject);
   begin
     AxcVLCPlugin2_1.OleServer.playlist.add(widestring(FileNameEdit1.FileName,'',vararrayof([':aspect-ratio=16:9']));
     AxcVLCPlugin2_1.OleServer.playlist.play;
   end;
  • Ejecuta el programa, selecciona una película y haz clic en el botón para verla.

   Los manejadores de eventos para los componentes se pueden crear directamente desde el Inspector de Objetos. (Nota de la versión 1.1.5.0 de la typelib de la VLC de tipos avisa de los eventos, pero falla al establecer un punto de conexión. Esto parece ser un error en la VLC).

Usuarios Delphi: Delphi crea un esqueleto para todos los métodos y propiedades de los componentes ActiveX, importtl no añade esta capa adicional y los métodos AxctiveX son llamados a través de la propiedad OleServer del componente. Por ejemplo: AxcVLCPlugin2_1.OleServer.playlist.play es el equivalente a VLCPlugin21.playlist.play en Delphi.