Lazarus Tdbf Tutorial/fr

From Lazarus wiki
Jump to: navigation, search

Deutsch (de) English (en) español (es) français (fr) português (pt) русский (ru) 中文(中国大陆)‎ (zh_CN)

Portail de la base de données

Références:

Tutoriels/articles pratiques :

Bases de données

Advantage - MySQL - MSSQL - Postgres - Interbase - Firebird - Oracle - ODBC - Paradox - SQLite - dBASE - MS Access - Zeos

Vue d'ensemble

Ce tutoriel a pour but de vous donner les bases du développement d'une application intégrant une base de données en utilisant le composant TDBF (de Micha Nelissen) sous Lazarus. Vous pourrez y trouver de la documentation complémentaire sur le composant TDBF. Cette page a été créée par Tony Maro mais d'autres contributions sont bienvenues !

Dans Lazarus, le composant DbfLaz fait usage du code du TDbf de FPC.

Documentation

Pour de la documentation complémentaire en PDF, allez sur le site SourceForge. Il peut être utile de garder ce pdf à côté de ce document pendant la lecture.

Ce article Wiki sert comme documentation supplémentaire pour les nouvelles fonctionnalités hors de la documentation d'origine.

Alternatives et problèmes connus

Les alternatives d'emploi de bases de données incorporées sont Firebird embedded (avantage : facilement évolutif vers le client/serveur), SQLite (avantage : déploiement simple), ou ZMSQL (utilisant des fichiers CSV ; avantage : n'est requis que du code Pascal).

Problèmes connus: Le code de TDBF manque de mainteneur depuis lmongtemps. Actuellement (octobre 2013), à la fois le projet SourceForge en amont (se concentrant sur Delphi) et les développeurs FPC de bases de données envisagent de résoudre de nouveau les bugs TDBF. Les correctifs du tronc FPC demandent à être fusionnés avec la version SourceForge, et inversement.

Problème courant : veuillez voir les bugs dans le traqueur de bug, en particulier http://bugs.freepascal.org/view.php?id=22177.

Limitations

  • TDBF définit l'encodage de la base de données en fonction de la langue du système d'exploitation (vous pouvez choisir le vôtre en définissant LanguageID ; voyez la documentation). Le déplacement d'une base de données vers un autre ordinateur qui ne prend pas en charge cet encodage peut amener à une base de données en lecteur seule. Note : Étudier si cela s'applique à Tablelevel 7 (Visual DBase) et 25/30 (Foxpro / Visual Foxpro)
  • Aucun des formats DBF utilisé ne prend en charge l'encodage en Unicode (qu'il s'agisse de UTF-8, UTF-16 ou UTF-32). On peut contourner le problème en utilisant es champs binaires, mais vous perdez la possibilité de trier, etc.
  • L'indexation d'un fichier DBase avec [ixCaseInsensitive] ne fonctionne pas actuellement.
  • Pas encore de prise en charge de l'intégrité référentielle dans les formats de fichier qui la permettent (DBase VII, Visual FoxPro).
  • Pas de prise en charge (maintenant et toujours) pour les fichiers .dbf chiffrés : le mécanisme de chiffrement de DBase IV est de toutes façon plutôt faible. Veuillez utiliser une des méthodes de chiffrement cités au dessous.

FPC 2.6.x et antérieur :

  • Sur les processeurs ARM, le code TDBF est connu pour ne pas fonctionner du fait de problème d'alignement du bus. Ceci est abordé dans la version de développement/tronc de FPC.
  • Le choix de niveau de table FoxPro (25) produira des fichiers qui ne peuvent pas être lus par les pilotes de Visual Foxpro. Cela a été corrigé dans la version de développement/tronc de FPC.

Pas besoin d'installation

Le paquet DbfLaz est installé par défaut à la fois dans FPC et Lazarus. Le paquet DBFLaz utilise le TDbf et les unités associées dans la FCL (Free Component Library) de Free Pascal. En d'autres mots, aucun besoin d'installer quoique que ce soit si vous disposer d'une assez récente version de Lazarus.

Que contient TDBF ?

TDBF permet d'accéder aux tables de dBase et aux bases de données de FoxPro sous Lazarus (entre autres). Il autorise la lecture, l'écriture et la création de table dBase III+, dBase IV, Visual dBase VII et FoxPro. Il n'est pas nécessaire de rajouter de bibliothèques ou de moteurs de base de données additionnels. Posez simplement TDBF sur votre formulaire et vous aurez un accès instantané à un environnement de base de données multi-plateforme. TDBF fonctionne sous Windows et Linux en utilisant Lazarus.

Que faut-il mettre dans votre clause Uses

Si vous utilisez le composant visuel DBF dans Lazarus, ce dernier mettra Dbf dans vos clauses Uses. Si vous utilisez FPC (en mode console) seulement, vous pouvez le mettre vous-mêmes. D'autres unités pratiques sont db pour le support des DataSet et Dbf_Common pour des choses telles que les définitions de type de champ.

Ainsi, vous obtiendrez :

uses Dbf, db, Dbf_Common;

Comment créer une nouvelle table de base de données ?

Il y a une application de bureau pour les bases de données pour Lazarus (ouvrez le projet dans votre in répertoire Lazarus tools/LazDataDesktop). Vous pouvez créer un nouveau dictionnaire de données pus créer le code pour définir les fichiers DBF basés sur ce dictionnaire. À partir de maintenant (Juillet 2011), ce processus est encore un peu compliqué (NdT : non vérifié).

Une autre option est d'utiliser Calc d'OpenOffice ou de LibreOffice et enregistrer votre classeur comme un fichier .dbf.

Vous pouvez aussi (sur Windows - marche avec Wine aussi) essayer cette application : [1].

En tout cas, nous allons illustrer la création d'une nouvelle base de données dans le code ci-dessous.

Définir le chemin

Une bonne idée est de mettre la/les base(s) de données dans un répertoire. Cela simplifie grandement les sauvegardes. Il y a deux manières de paramétrer le chemin :

  • Vous pouvez définir le chemin complet en utilisant la propriété FilePathFull,
  • ou vous pouvez définir un chemin relatif au chemin courant de l'application avec FilePath.

Par exemple, définir "FilePath" à l'exécution à "data/" utilisera un sous-répertoire juste au-dessous du dossier de exécutable. La définition de la propriété "FilePathFull" à "/var/data/" placera tout à cet emplacement exact, ignorant l'emplacement de l'application. Un exemple :

MyDbf.FilePathFull := '/location/to/my/data'; //Directory where all .dbf files will be stored
MyDbf.TableName := 'customers.dbf'; // note: is the .dbf really required?

Choisir un niveau de table

Par défaut, TDBF créera des tables au format dBase IV. Bien que très compatible, il peut y avoir des spécificités que vous souhaitez utiliser et qui ne sont pas supportés par ce format. Par exemple pour un support de l'incrément automatique des champs, vous devrez employer un format plus récent. Les types de table sont :

  • 3 dBase III+
  • 4 dBase IV
  • 7 Visual dBase VII
  • 25 FoxPro
Niveau de table Compatibilité avec le produit de base Prise en charge des champs auto-incrémentés Limite de longueur de champ Remarque
Level 3 dBase III+ Non 10 caractères [2] Plutôt obsolète mais c'est un format très simple. Pratique pour les utilisation en-mémoire.
Level 4 dBase IV Non 10 caractères [3] Etait très populaire. Base pour les fichiers de forme de GIS (.shp)
Level 7 Visual dBase VII Oui 32 caractères [4]
Level 25 FoxPro Oui 10 caractères [5]

[6]

FoxPro ; compatible avec FoxPro pour DOS et Visual FoxPro. Note: l'implémentation dans FPC 2.6.2 produit des fichiers qui ne peuvent pas être lus par les pilotes FoxPro !
Level 30 Visual FoxPro Oui Normalement 10 caractères [7]

[8] Non pris en charge par FPC :en utilisant un fichier DBC (conteneur de base de données) : 27 caractères

Pas encore dans FPC 2.6.2 ; seulement dans le version de développement en cours

Voyez le bug [9] pour plus d'information sur les limitations de longueur de champ.

Pour choisir un format il suffit simplement d'initialiser la propriété TableLevel de façon approprié :

MyDbf.TableLevel := 7; //Visual dBase 7

Ajouter des champs

La façon de créer des champs pour votre nouvelle table à l'exécution, est très proche de l'ancienne norme de Delphi. Une fois que vous avez défini vos propriétés FilePath, TableLevel, et TableName, utilisez la propriété FieldDefs pour mettre en place votre structure. Par exemple :

MyDbf.FilePathFull := '/location/to/my/data';
MyDbf.TableLevel := 7;
MyDbf.TableName := 'customers.dbf'; // note: is the .dbf really required?
With MyDbf.FieldDefs do
begin
  Add('Id', ftAutoInc, 0, True);
  Add('Name', ftString, 80, True);
End;

Le type des champs se définie comme suit - ceux en gras sont actuellement pris en charge par le code DBF. Voyez les types de champ de donnée pour une explication sur les types :

  • ftUnknown
  • ftString
  • ftSmallInt
  • ftInteger
  • ftWord
  • ftBoolean
  • ftFloat
  • ftCurrency (Pris en charge seulement avec le niveau de table 25)
  • ftBCD (Pris en charge seulement avec le niveau de table 25)
  • ftDate
  • ftTime
  • ftDateTime : Sans doute le type recommandé pour stocker des valeurs ftDate ou ftDateTime. Au moins dans FoxPro, semble stocker les millisecondes aussi.
  • ftBytes (Pris en charge seulement avec le niveau de table 25)
  • ftVarBytes
  • ftAutoInc(Pris en charge seulement avec les niveaux de table 7 et 25)
  • ftBlob
  • ftMemo
  • ftGraphic
  • ftFmtMemo
  • ftParadoxOle
  • ftDBaseOle
  • ftTypedBinary
  • ftCursor
  • ftFixedChar
  • ftWideString
  • ftLargeInt
  • ftADT
  • ftArray
  • ftReference
  • ftDataSet
  • ftOraBlob
  • ftOraClob
  • ftVariant
  • ftInterface
  • ftIDispatch
  • ftGuid
  • ftTimeStamp
  • ftFMTBcd

Ajouter des champs en conception

Utilisez la propriété FieldDefs pour créer des champs en conception - cela remplace l'appel FieldDefs.Add du dessus. Il est important de reamarquer que la propriété StoreDefs doit être mise à True pour stocker les définitions dans le fichier .lfm et les rendre disponibles quand la table est créée plus tard à l'exécution.

Allez-y, créez-le !

Une fois que vous avez défini les champs que vous souhaitez employer dans votre nouvelle table, vous pouvez passer à l'étape suivante et la créer avec :

   MyDbf.CreateTable;

Comment ajouter des index à une table ?

Si votre base de données a beaucoup d'enregistrements, il y a de grandes chances que vous souhaitiez définir des index de manière à ce que les recherches soient plus rapides. Pour changer la structure d'index d'une table, il faut un accès exclusif à la table - que nous avons de toute façon au moment de la création.

       MyDbf.Exclusive := True;
       MyDbf.Open;

Maintenant, il ne reste plus qu'a ajouter l'index.

       MyDbf.AddIndex('custid', 'Id', [ixPrimary, ixUnique]);
       MyDbf.AddIndex('custname','Name', [ixCaseInsensitive]);
       MyDbf.Close;

Expressions

Les index et les filtres peuvent utiliser des expressions selon la documentation de TDbf.

Pour plus de détails sur les filtres, voyez dessous.

Index/filtre sur des chaînes

Les chaînes demande à être encadrées/délimitées par des guillemets (") ou des apostrophes (').

Note-icon.png

Remarque: Dans les versions de FPC antérieures à la 3.0 : l'utilisation des apostrophes dans votre filtre ne fonctionne pas (voir l'exemple du dessous). Voir la page des nouveautés de FPC 3.0 : FPC_New_Features_3.0#TDBF.2C_bufdataset_.28and_descendents_such_as_TSQLQuery.29_allow_escaped_delimiters_in_string_expression_filter.


// We have a field called CUSTOMER
// let's delimit with double quotes
// (of course, double up single ' in string to make FPC happy)
MyDBF.Filter:='CUSTOMER = "Felipe''s Bank" ';
// another tricky one, let's delimit with single quotes. Of course,
// we'll need to double these up for FPC to interpret these correctly
MyDBF.Filter:='CUSTOMER = ''Jim "Mighty" McLanahan'' ';
 
// If we have both a ' and a " in our string, we're in trouble.
// the example below only works on FPC 2.7.1+
MyDBF.Filter:='CUSTOMER = "Felipe''s ""Mighty"" Bank" ';
 
MyDBF.Filtered:=true;

Limite des index à des chaînes de 100 caractères

Les expressions d'index qui retourne une chaîne ne doivent pas dépasser une longueur de 100 caractères ; utilisez SUBSTR pour éliminer les caractères en trop, p.ex. :

MyDbf.AddIndex('SOMEFANCYINDEX', 
  'DTOS(DATEFIELD)+SUBSTR(LONGFIELD,1,10)+SUBSTR(LONGFIELD2,1,20)', []);

Index/filtre sur des TDateTimes

Pour définir un index sur un champ date/time, utilisez une expression d'index et la fonction DTOS :

MyDbf.AddIndex('PUBLISHDATEIDX', 'DTOS(PUBLISHDATE)', []);

Le filtrage est similaire - remarque : apparemment, vous devez entourer la valeur de chaîne que vous comparez avec des guillemets doubles. Voyez ci-dessous pour des détails sur la fonction DTOS ; de façon basique vous avez besoin de formater la date en YYYYMMDD:

// we have a field named MODIFIED here:
MyDBF.Filter:='DTOS(MODIFIED) > "20051231"';
 
// if you want to compare datetime, that can be done:
// everything later than 2 January 2006, 4:34PM
MyDBF.Filter:='DTOS(MODIFIED) > "20060102 163400"';
 
MyDBF.Filtered:=true;

P.ex., si vous voulez filtrer un TDbf sur un champ Date en utilisant une valeur sélectionnée depuis une DBlookupComboBox.

var 
mydate: String;
begin
  mydate := formatdatetime('yyyymmdd', strtodate(DBLookupComboBox.Text));
  Filter := 'DTOS(DATE) = ' + AnsiQuotedSTR(mydate,'"'); 
end;

Index/filtre opérateurs/fonctions

Les fonctions prises en charge (depuis la documentation mentionnée plus haut) :

Opérateur/fonction Description
+ Concatène deux chaînes, ou ajoute deux nombres
* Multiplie deux nombres
/ Divise deux nombres
= Compare deux chaînes, nombres or booléens pour l'égalité
<> Compare deux chaînes, nombres or booléens pour l'inégalité
< True si le premier argument est inférieur au second argument
<= True si le premier argument est inférieur ou égal au second argument
> True si le premier argument est supérieur au second argument
>= True si le premier argument est supérieur ou égal au second argument
NOT Inverse la valeur de vérité de son argument (à droite)
AND Retourne True si ses deux arguments booléens sont vrais
OR Retourne False si ses deux arguments booléens sont faux (soit aussi retourne True si l'un des deux est vrai)
STR(num[,size,precision]) Convertit un nombre num en une chaîne avec en option une taille et une précision

num: nombre à convertir size: le nombre total de caractères en sortie precision: le nombre de chiffres après la virgule

DTOS(date) Convertit une date en un chaîne selon le format YYYYMMDD
SUBSTR(str,index,count) Extrait une sous-chaîne depuis une chaîne str depuis la position index et la longueur count
UPPER(str) Retourne l'équivalent en majuscules de la chaîne str
LOWER(str) Retourne l'équivalent en minuscules de la chaîne str

Et vous obtenez...

L'exemple ci-dessous crée une nouvelle table "clients" à partir du code. Ceci est naturellement à faire qu'une seule fois, dans la mesure ou la table est déjà créée, il ne vous reste plus qu'à l'OUVRIR, inutile donc de la recréer. ;-)

{$MODE OBJFPC}
Program DatabaseTest;  
{ We will require the following units be in the USES clause: }
 uses Dbf, db, Dbf_Common;                                   
{ The Dbf is put there when you drop the TDbf on a form...   }
{ but you will need db for the DataSet object and Dbf_Common }
{ for things such as the field type definitions              }
var
  MyDbf: TDbf;
begin
  MyDbf := TDbf.Create(nil);
  try
    { use relative path to "data" directory }
    MyDbf.FilePath := 'data/'; 
    { we want to use Visual dBase VII compatible tables }
    MyDbf.TableLevel := 7;
    MyDbf.Exclusive := True;
    MyDbf.TableName := 'customers.dbf';
    With MyDbf.FieldDefs do begin
      Add('Id', ftAutoInc, 0, True);
      Add('Name', ftString, 80, True);
    End;
    MyDbf.CreateTable;
    MyDbf.Open;
    MyDbf.AddIndex('custid', 'Id', [ixPrimary, ixUnique]);
    { add a secondary index }
    MyDbf.AddIndex('custname','Name', [ixCaseInsensitive]);
    MyDbf.Close;
  finally
    MyDbf.Free;
  end;
end;

Fichiers d'index externes

TDBF supporte également le stockage d'index secondaires dans des fichiers séparés. Ceci peut être utile si on s'attend à ce que la base de données soit très grande. Les fichiers d'index secondaires sont créés de manière presque identique aux index normaux, mais ont l'extension '.ndx' :

    MyDbf.AddIndex('custname.ndx','Name', [ixCaseInsensitive]);


Chaque fois que TDBF est ouvert, le dossier d'index doit être chargé :

    MyDbf.OpenIndexFile('custname.ndx');


Et les index doivent être référencé avec l'extension :

    MyDbf.IndexName := 'custname.ndx';


Les fichiers d'index sont compactés séparément :

    MyDbf.CompactIndexFile('custname.ndx');

NdT : cette solution multi-fichier a cependant l'inconvénient de demander plus de ressources système (fichiers ouverts).

Comment lier TDBF aux composants ad hoc

Les exemples ci-dessus montrent comment créer une nouvelle table de base de données à partir du code. Utiliser cette table est bien plus simple.

Les composants ad hoc sous Lazarus (tel que TDbEdit) peuvent être liés à un composant TDataSource en utilisant leurs propriétés "DataSource" et "DataField". Le composant TDataSource gère la communication entre le moteur de base de données et les composants de données ad hoc. Un TDataSource lié au composant TDBF utilise sa propriété "DataSet". La connexion ressemble à ceci :

TDbEdit-------
             |
TDbEdit------|-->TDataSource-->TDbf
             |
TDbNavigator--


Soyez sûr(e) d'avoir bien défini les propriétés FilePath (ou FilePathFulll), TableLevel, et TableName de votre composant TDBF avant de l'appeler.

TDbf.Active := True;


Il y a beaucoup plus à dire sur la programmation des bases de données sous Lazarus. Vous pouvez vous référer à une ancienne documentation de Delphi concernant les bases de données car les concepts fondamentaux n'ont pas changé depuis des années.

Relations avec la table principale (Master table)

La vraie puissance dans la programmation de base de données commence quand vous avez des tables multiples qui se mettent en référence. Bien que TDBF ne supporte pas encore l'intégrité référentielle, il supporte néanmoins un rapport maître/détail entre TDBF.

Quand une relation est faite entre deux tables, on obtient :

[customers]
Id       <----|
Name          |
Phone         |
Address       |
              |  The CustID in invoices references a customer primary  field
[invoices]    |
Id            |
Amount        |
CustID   -----|  * This field indexed as "idxcustid"


Lorsque vous voulez montrer toutes les factures pour un client donné, la table de détail (factures) reste automatiquement synchro avec la table principale (clients).

Sur les factures le composant de TDBF a placé ce qui suit :

InvDbf.IndexName := 'idxcustid'; // our field that will match the customers table ID
InvDbf.MasterSource := dsCustomers; // datasource that is linked to the customers TDbf
InvDbf.MasterFields := 'Id'; // field on the customers table we are matching against our index

Searching and Displaying a data set by using filters

Simon Batty

Dans cet exemple j'ai cherché à lister tous les titres pour un auteur et afficher le résultat dans un TMemo :

Dbf1.FilePathFull := '/home/somelocatio/database_location/'; // path to the database directory
Dbf1.TableName := 'books.dbase';                             // database file (including extension)
DbF1.Open;
memo1.Clear;                                                 // clear the memo box
 
Dbf1.FilterOptions := [foCaseInsensitive];                   // set FilterOptions before Filter !
Dbf1.Filter := 'AUTHOR=' + QuotedStr('anauthor');            // AUTHOR is the field name containing the authors
                                                             // Note that we need to surround the value with double quotes: "James Joyce"
 
Dbf1.Filtered := true;       // This selects the filtered set
Dbf1.First;                  // moves the the first filtered data
while not dbf1.EOF do        // prints the titles that match the author to the memo box
begin
  memo1.Append(Dbf1.FieldByName('TITLE').AsString);          // TITLE is the field name for titles
  dbf1.next;                                                 // use .next here NOT .findnext!
end;
Dbf1.Close;

Remarquez que vous pouvez utiliser Ddf1.FindFirst pour obtenir le premier enregistrement dans l'ensemble filtré, puis utiliser Dbf1.Next pour vous déplacer à travers les données. J'ai trouvé que l'utilisation de Dbf1.FindNext fait que le programme se bloque.

Exemple d'application – Navigateur de Base de données

J'ai écrit une application simple qui emploiera TDBF pour ouvrir et montrer des tables de base de données en utilisant le composant dbGrid. L'exécutable Linux avec les sources du projet qui devraient se compiler sans problèmes sous Windows est disponible à l'adresse : tony.maro.net

Filters

Il y a dexu façons d'utiliser les filtres :

  • utiliser des filtres d'expression
  • écrire un gestionnaire d'événement pour OnFilterRecord ; si vous voulez montrer l'enregistrement, mettez Accept à True.true.

Dans les deux cas, mettez la propriété Filter à True pour activer le filtrage.

Exemple : Imaginez que vous avez une base de données qui identifie les produits par un code, par exemple, B019, et que vous ayez besoin de filtrer uniquement les produits qui ont ce code et qu'un état est généré par LazReport.

Supposons que votre objet DBF est appelé TDBF1 et le champ avec les codes produit est appelé "product_no".

Expression de filtres

Implémentez le filtrage en utilisant une expression de filtrage comme ceci :

TDBF1.Filter := 'product_code = "B019"'; //string type field; string constants should be quoted by ' or "
TDBF1.Filtered := true;

TDBF1.Filter := 'product_code = "B*"'; //partial match filter; filters all products which code begins with B
TDBF1.Filtered := true;

Filtrer sur des champs multiples :

// Needs to be tested. If it works, please remove this line.
MyDBF.Filter:='LASTNAME;FIRSTNAME';

Adapté depuis : post de forum [10]

Voici un exemple de l'utilisation d'une valeur de DBLookupCombobox dans un instruction de filtre (où NAME est le champ du DBF) :

Filter := 'NAME=' + QuotedStr(DBLookupcomboBox1.Text);

Voici deux exemples d'utilisation des deux ComboBox dans une instruction de filtre composé (i.e. deux champs) (où NAME et TYPE sont des noms de champ d'un DBF) :

Dans cet exemple, vous allez combiner ("and") les deux valeurs.

// unfortunately, this will fail whenever the user types a ' in TypeComboBox.Text...
Filter := 'NAME=' + QuotedStr(DBLookupcomboBox1.Text) + ' and TYPE=' + QuotedStr(TypeComboBox.Text);
Filter := Format('NAME="%s" and TYPE="%s"',[DBLookupcomboBox1.Text, TypeComboBox.Text]);

Un exemple d'utilisation d'un ComboBox qui fournit le nom de champ pour le filtre et qui le compare à la valeur dans le ComboBox de recherche (lookup) :

Filter := FieldComboBox.Text + '=' + QuotedSTR(DBLookupcomboBox1.Text);

Dans cet exemple, le FieldCombobox est alimenté par code avec les noms des champs depuis le DBF :

// fill the combobox with Field Names
for i:=0 to Dbf.FieldCount-1 do
  FieldComboBox.Items.Add(Dbf.Fields[i].FieldName);

Veuillez voir la section #Expressions plus bas pour la liste des expressions prises en charge ainsi que d'autres exemples.

Evénement OnFilterRecords

Pour utiliser cette méthode, vous avez besoin d'écrire une fonction.

Dans votre code principal, écrivez quelque chose comme ceci :

OnFilterRecord := @TestOnFilterProc; //instruct tdbf to lead all records past your OnFilterProductCode procedure
Filtered := True; //actually enable filtering

Puis écrivez votre gestionnaire d'événement :

procedure TTestCursorDBBasics.TestOnFilterProc(DataSet: TDataSet; var Accept: Boolean);
begin
  // Filter out everything except product_no=B019
  Accept := Copy (Trim (Dataset.FieldByName ('product_no'). AsString),1,4) = 'B019';
end;

Tous les enregistrements qui donnent une valeur False à Accept ne seront pas affichés dans l'état car filtrés.

Filtre sur les valeurs nulles

(NdT : la notion de valeurs nulles est en soi sujet à discussion, cela correspond plutôt à un état de la données, en dehors de ces valeurs). Vous pouvez utiliser cette méthode pour ne montrer que les valeurs vides (nulles), quelque chose que vous ne pouvez pas faire avec la propriété Filter.

Un exemple - supposant que vous avez un champ appelé orderdate :

procedure TTestCursorDBBasics.TestOnFilterProc(DataSet: TDataSet; var Accept: Boolean);
begin
  // Show only empty order dates
  Accept := Dataset.FieldByName('orderdate').IsNull;
end;

Plus généralement, l'emploi des filtres par l'événement OnFilterRecord permet la mise en œuvre de filtre plus élaborés que la propriété Filter ne le permet.

Compacter et reconstruire des tables

Quand un enregistrement est supprimé, il n'est pas vraiment enlevé de la table physique. Périodiquement vous devez "compacter" une table pour récupérer cet espace perdu. Ceci doit être fait en mode exclusif.

MyDbf.Exclusive := True;
MyDbf.Open;
MyDbf.PackTable;
// let's also rebuild all the indexes
MyDbf.RegenerateIndexes;
MyDbf.Close;
MyDbf.Exclusive := False;

Chiffrement

Apparemment au moins DBase IV et 5 prennent en charge une sorte de chiffrement (il y a un drapeau de chiffrement dans la structure de la table), mais le mot de passe est dans le DBF lui-même le rendant non sécurisé, (voyez [11]).

Il y a d'autres options si vous voulez chiffrer vos données. Voyez ici la de forum surle chiffrement de DBase.

Chiffrement au niveau du système d'exploitation

Vous pouvez utiliser un système de fichier chiffré tel que TrueCrypt (conteneurs) pour chiffrer le dossier où la base de données est stockée.

Chiffrer le fichier DBF

Vous pouvez utiliser des flux (p.ex. le code du flux chiffré Blowfish fourni par Lazarus/FPC) pour chiffrer les données (toutes les tables etc) en stockant le fichier non chiffré p.ex. en mémoire, puis en l'écrivant sur le disque :

  1. Ouvrir votre fichier dans un TFileStream.
  2. Déchiffrez le TFileStream vers un nouveau flux, YourDecryptedStream
  3. Tdbf.UserStream:= YourDecryptedStream; //Remarque : cela ne déchiffrera pas les fichiers .dbt/memo ! Utilisez UserMemoStream pour cela (dans FPC le tronc de développement depuis Mai 2013 seulement)
  4. Tdbf.Storage:=stoMemory;
  5. Tdbf.Open;

Une fois terminé :

  1. Tdbf.Close
  2. Chiffrez YourDecryptedStream vers TFileStream
  3. Libérez les flux

Du code détaillé peut être trouvé dans le forum mentionné plus haut. Des gens qui auraient implémenté ceci sont les bienvenus pour adapter cet article avec du code qui marche.

Chiffrer le champ de donnée

Vous pourriez aussi choisir de chiffrer le champ de donnée en implémentant les événements OnGetText et OnSetText pour chiffrer/déchiffrer le contenu du champ.

Prendre conscience que

Actuellement il n'y a aucun support de l'intégrité référentielle, ni de cryptage possible des fichiers au format .dbf.

Logiciel tierce partie

  • MyDbf Studio est un outil d'administration pour gérer vos tables dBase. Il est entièrement écrit avec Lazarus et est basé sur le composant TDbf.
  • [12] sont des composants Delphi pour les fichiers DBF.
    • Composant Open Source VKDBF de Vlad Karpov's : [[13]]

Voir aussi