Database tutorial SQLdb1/de

From Free Pascal wiki
(Redirected from SQLdb Tutorial1/de)
Jump to: navigation, search

Einleitung

Dieses Tutorial hat das Ziel, die Verwendung des SQLdb Packages anhand praktischer Beispiele zu demonstrieren. Es richtet sich vor allem an Einsteiger. Wer nach Grundlageninformationen über Datenbanken und SQL sucht, dem seien die einschlägigen Bücher empfohlen. Für das Tutorial greife ich auf Firebird mit der Beispieldatenbank employee.fdb zurück.

Bedanken möchte ich mich bei Joost und Michael, ohne deren Hilfe das Tutorial wahrscheinlich nicht zustande gekommen wäre.

Voraussetzungen

Für dieses Tutorial sollten sie möglichst eine aktuelle Lazarus Version verwenden (mit FPC 2.6.2 oder höher). Sollte das SQLdb Package noch nicht installiert sein, dann holen sie das jetzt nach (Package -> Installierte Packages einrichten ... -> SQLDBLaz 1.0.2). Außerdem wird Firebird (möglichst Version 2.5 oder höher) benötigt. Die Beispiele gehen davon aus, dass die Standardvorgaben (SYSDBA und masterkey) nicht verändert wurden.

Beispiel 1

Starten sie ein neues Projekt in Lazarus. Für den Zugriff auf die Datenbank benötigen wir je eine TIBConnection, TSQLTransaction und TSQLQuery von der Seite 'SQLdb' in der Komponentenpalette. Die erste Komponente ist spezifisch für den Zugriff auf Firebird-Datenbanken. Die beiden anderen Komponenten kommen bei allen Datenbanken zum Einsatz, auf die sie mit SQLdb zugreifen können. Für die Anzeige der Daten verwenden wir eine TDBGrid Komponente, die sie auf der Seite 'Data Controls' finden. Für die Verbindung mit den Datenbankkomponenten benötigen wir noch eine TDatasource Komponente von der Seite 'Data Access'. Zum Auslösen der Aktionen verwenden wir einen TButton von der Seite 'Standard'. Damit haben wir alle Komponenten, die wir für das erste Beispiel benötigen. Vergrößern sie das TDBGrid noch etwas, damit genügend Platz für die Anzeige der Daten zur Verfügung steht.

Als nächstes müssen wir die Komponenten miteinander verbinden. Am einfachsten geht das im Objektinspektor. Man kann die Zuweisungen aber auch im Quelltext vornehmen. Ändern sie die 'Transaction' Eigenschaft von IBConnection1 auf 'SQLTransaction1'. Damit wird die 'Database' Eigenschaft von SQLTransaction1 automatisch auf 'IBConnection1' eingestellt. Als nächstes setzen sie die 'Database' Eigenschaft von SQLQuery1 auf 'IBConnection1'. Lazarus ergänzt dann automatisch die 'Transaction' Eigenschaft. Die 'Dataset' Eigenschaft von Datasource1 ändern sie auf 'SQLQuery1'. Zum Schluss müssen sie noch die 'Datasource' Eigenschaft von DBGrid1 auf 'Datasource1' ändern.

Wie kommen jetzt die Daten aus der Datenbank auf den Bildschirm? Zunächst müssen wir IBConnection1 mitteilen, wo sich die employee.fdb befindet (üblicherweise im .../examples/empbuild/ Unterverzeichnis ihrer Firebird-Installation). Sie haben jetzt wieder die Wahl, ob sie auf den Objektinspektor zurückgreifen wollen, oder das Verzeichnis im Quelltext zuweisen wollen. Wir entscheiden uns hier für den Objektinspektor. Ändern sie die 'DatabaseName' Eigenschaft von IBConnection1 auf den Pfad zur Datei employee.fdb (z.B. C:\Programme\Firebird\Firebird_2_5\examples\empbuild\EMPLOYEE.FDB). Wenn sie sich den Pfad nicht merken können, dann können sie ihn idR. auch aus ihrem Dateimanager mittels 'kopieren und einfügen' eintragen. Bevor der Datenbank-Server Daten herausrückt, wird er die Berechtigung über Benutzername und Passwort abfragen. Eine ernsthafte Datenbank-Anwendung wird daher beim Programmstart den Benutzer danach fragen, um die Daten im geeigneten Moment an den Datenbank-Server weiterzureichen. Wir werden der Einfachheit halber wieder auf den Objektinspektor zurückgreifen. Ändern sie die 'UserName' Eigenschaft auf 'SYSDBA' und 'Password' auf 'masterkey'. Um zu prüfen, ob die bisher vorgenommenen Einstellungen formal korrekt sind, können sie die 'Connected' Eigenschaft auf 'True' setzen. Ist der Pfad nicht richtig oder stimmt der Benutzername oder das Passwort nicht, dann erscheint eine Fehlermeldung. War die Verbindung erfolgreich, dann trennen sie diese jetzt wieder (auf 'False' setzen).

Trotz der erfolgreichen Verbindung wurden aber immer noch keine Daten angezeigt. Das erklärt sich dadurch, dass wir dem Datenbank-Server auch noch nicht mitgeteilt haben, was er anzeigen soll. Die Datenbank employee.fdb enthält mehrere Tabellen. Wenn sie im Vorfeld die Struktur einer Datenbank nicht kennen, dann können sie auf Werkzeuge wie FlameRobin zurückgreifen, um sich die Inhalte anzuzeigen. Aber auch Lazarus bietet ein Hilfsmittel - den Datenbank-Desktop. Sie finden ihn im /tools/lazdatadesktop/ Unterverzeichnis von Lazarus. Öffnen sie das Projekt lazdatadesktop.lpi und kompilieren sie es (setzt FPC 2.6.2 voraus) (unser Beispielprojekt haben sie natürlich vorher gesichert).

Der Datenbank-Desktop in Aktion

Zurück zu unserem Beispiel. Wir wollen alle Daten aus der Tabelle 'CUSTOMER' anzeigen. Der SQL Befehl dazu lautet:

select * from CUSTOMER

Diesen Befehl müssen wir der 'SQL' Eigenschaft von SQLQuery1 zuweisen. Im Quelltext unseres Programms würde das so aussehen:

SQLQuery1.SQL.Text := 'select * from CUSTOMER';

Wird der Befehl in Textform angegeben, dann muss er in einfache Anführungszeichen eingeschlossen werden. Man könnte natürlich auch den Inhalt einer anderen Komponente zuweisen.

Die Abfrage der Daten soll erfolgen, wenn der Benutzer auf den Button klickt. Mit einem Doppelklick auf Button1 erzeugt Lazarus das Grundgerüst der dafür notwendigen Prozedur. In ihrem Quelltext sollte jetzt folgendes stehen:

procedure TForm1.Button1Click(Sender: TObject);
begin
 
end;

Zwischen begin und end müssen wir jetzt die Anweisungen eingeben, die zum Anzeigen der Daten erforderlich sind. Die 'SQL' Eigenschaft von SQLQuery1 kann nur geändert werden, wenn SQLQuery1 nicht aktiv ist. Daher schließen wir die Komponente zunächst:

SQLQuery1.Close;

Da wir nicht sicher sein können, ob SQLQuery1 noch irgendwelche Daten enthält, rufen wir die 'Clear' Prozedur auf:

SQLQuery1.SQl.Clear;

Dann weisen wir der 'SQL' Eigenschaft unsere SQL Anweisung zu:

SQLQuery1.SQL.Text := 'select * from CUSTOMER';

Jetzt müssen wir die Verbindung zur Datenbank herstellen sowie die Transaktion aktivieren und dann die Abfrage öffnen:

IBConnection1.Connected := True;
SQLTransaction1.Active := True;
SQLQuery1.Open;

Die ersten beiden Anweisungen können auch weggelassen werden, da sie von der dritten Anweisung automatisch erledigt werden (dies gilt aber nicht im umgekehrten Fall beim Trennen der Verbindung). Es wird aber empfohlen, die Anweisungen nicht wegzulassen, da es sonst in einigen Fällen bei einem ROLLBACK zu Problemen kommen kann. Wenn sie jetzt ihr Programm kompilieren würden, dann würden die Daten aus der Tabelle 'CUSTOMER' bereits angezeigt werden. Ein ordentliches Programm wird aber spätestens beim Beenden dafür sorgen, dass noch offene Verbindungen zur Datenbank geschlossen werden. Die Nebenwirkungen wären sonst nicht absehbar. Wir verwenden das OnClose Ereignis unseres Formulars (mittels Doppelklick im Objektinspektor erzeugen):

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
 
end;

Beim Trennen verwenden wir die umgekehrte Reihenfolge wie beim Verbinden:

SQLQuery1.Close;
SQLTransaction1.Active := False;
IBConnection1.Connected := False;

Zusammenfassung

Wir haben bisher gelernt, wie man mit dem SQLdb Package eine Verbindung zu einer Firebird Datenbank herstellt und die Daten einer Tabelle am Bildschirm anzeigt.

Erweiterung von Beispiel 1

Wenn sie sich an die bisherigen Schritte gehalten haben, dann sollte ihr Quelltext etwa so aussehen:

unit Unit1; 
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  IBConnection, sqldb, DBGrids, db, StdCtrls;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Button1: TButton;
    Datasource1: TDatasource;
    DBGrid1: TDBGrid;
    IBConnection1: TIBConnection;
    SQLQuery1: TSQLQuery;
    SQLTransaction1: TSQLTransaction;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
  private
    { private declarations }
  public
    { public declarations }
  end; 
 
var
  Form1: TForm1; 
 
implementation
 
{ TForm1 }
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  SQLQuery1.Close;
  SQLQuery1.SQL.Clear;
  SQLQuery1.SQL.Text:= 'select * from CUSTOMER';
  IBConnection1.Connected:= True;
  SQLTransaction1.Active:= True;
  SQLQuery1.Open;
end;
 
procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  SQLQuery1.Close;
  SQLTransaction1.Active:= False;
  IBConnection1.Connected:= False;
end;
 
initialization
  {$I unit1.lrs}
 
end.

Nun wird man aber in den seltensten Fällen den kompletten Inhalt einer Tabelle benötigen. Nehmen wir an, es sollen nur die Kunden aus den USA angezeigt werden. Dafür müsste die SQL Anweisung wie folgt lauten:

select * from CUSTOMER where COUNTRY = 'USA'

Diese Anweisung werden wir aus zwei Gründen nicht für unser Beispielprogramm verwenden: Zum einen gibt es ein Problem bei der Verwendung des einfachen Anführungszeichens. Der Compiler würde das Anführungszeichen vor USA als schließendes Zeichen betrachten (das erste Zeichen steht ja vor select from...) und damit die SQL Anweisung ungültig machen. Der zweite und gewichtigere Grund ist die Tatsache, dass bei der Entwicklung des Programms noch gar nicht bekannt ist, welche Einschränkung der Anzeige später vorgenommen werden soll. Der Benutzer soll in seiner Flexibilität nicht eingeschränkt werden. Dazu ersetzen wir zunächst 'USA' durch einen Platzhalter:

select * from CUSTOMER where COUNTRY = :COUNTRY

Die Platzhalter sind durch den führenden Doppelpunkt gekennzeichnet. Um dem Benutzer die Eingabe des Filterwertes zu ermöglichen, platzieren sie eine TEdit Komponente (Seite 'Standard' in der Komponentenpalette) auf ihrem Formular. Löschen sie den Wert der 'Text' Eigenschaft. Über die 'Params' Eigenschaft von TSQLQuery können wir nun mit dem in TEdit eingegebenem Text unseren Platzhalter ersetzen:

SQLQuery1.Params.ParamByName('COUNTRY').AsString := Edit1.Text;

Der Parameter kann sowohl über seine Position als auch seinen Namen spezifiziert werden. Letzteres dürfte vor allem die Lesbarkeit des Quelltextes verbessern. Insgesamt sollte die Prozedur jetzt so aussehen:

procedure TForm1.Button1Click(Sender: TObject);
begin
  SQLQuery1.Close;
  SQLQuery1.SQL.Clear;
  SQLQuery1.SQL.Text:= 'select * from CUSTOMER where COUNTRY = :COUNTRY';
  SQLQuery1.Params.ParamByName('COUNTRY').AsString := Edit1.Text;
  IBConnection1.Connected:= True;
  SQLTransaction1.Active:= True;
  SQLQuery1.Open;
end;

Sie können jetzt ruhig mit den Einstellungen ein wenig herumspielen. Wenn sie einen Filterwert eingeben, der in der Datenbank nicht vorhanden ist, dann wird eine leere Tabelle angezeigt. Es können jedoch auch ernsthafte Probleme auftreten. Da bei einer Client-Server-Anwendung üblicherweise Client und Server räumlich getrennt sind, ist meist nicht auf den ersten Blick ersichtlich, warum es zu einem Problem gekommen ist. Ist der Server heruntergefahren worden oder hat nur jemand einen Stecker gezogen? Zugriffe auf eine Datenbank sollten daher immer in eine try ... except und/oder try ... finally Schleife eingebunden werden. Nur so ist sichergestellt, dass Datenbankfehler abgefangen werden können und der Anwender nicht im Regen stehen gelassen wird. Für unsere Beispielanwendung könnte eine rudimentäre Behandlungsroutine wie folgt aussehen:

begin
  try
    SQLQuery1.Close;
    ...
    SQLQuery1.Open;
  except
    on EDatabaseError do
    begin
      MessageDlg('Fehler','Es ist ein Datenbankfehler aufgetreten.',mtError,[mbOK],0);
      Edit1.Text:='';
    end;
  end;
end;

Hier wird jedoch nur eine einfache Meldung ausgegeben.

Siehe auch