Record/fr

From Free Pascal wiki
Revision as of 18:03, 15 March 2017 by Gillou58 (talk | contribs)
Jump to navigationJump to search

Deutsch (de) English (en) español (es) suomi (fi) français (fr) magyar (hu) polski (pl) português (pt) русский (ru)

Un enregistrement est un type de donnée hautement structuré en Pascal. Les enregistrements sont très largement utilisés en Pascal pour regrouper logiquement des éléments de données.

Alors que de simples structures de données tels les tableaux ou les ensembles sont constitués d'éléments tous du même type, un enregistrement peut être constitué d’éléments de types différents et prendre une forme très complexe. Chaque partie séparée d'un enregistrement est appelé un champ.

Déclaration

Structure fixe

type
  TMember = record
    firstname, surname : string;
    address: array [1..3] of string;
    phone: string;
    birthdate: TDateTime;
    paidCurrentSubscription: boolean
end;

Structure variable

Des structures plus complexes sont possibles, par exemple :

type
  maritalStates = (single, married, widowed, divorced);
  TPerson = record
    (* PARTIE CONSTANTE *)
    (* les enregistrements peuvent être imbriqués *)
    name: record
	first, middle, last: string;
    end;
    sex: (male, female);
    (* date de naissance *)
    dob: TDateTime;
    (* PARTIE VARIABLE *)
    case maritalStatus: maritalStates of
      single: ( );
      married, widowed: (marriageDate: TDateTime);
      divorced: (marriageDate, divorceDate: TDateTime;
				isFirstDivorce: boolean)			
  end;

Ce dernier type d'enregistrement est appelé enregistrement avec variantes. La variable (facultative) qui suit le case est appelé discriminant. Le type seul peut être mentionné s'il n'est pas besoin de manipuler le discriminant dans le code. Dans un enregistrement, on ne peut avoir qu'une seule partie variable qui doit se trouver à la fin de cet enregistrement ; rien n'empêche cependant d'imbriquer des enregistrements avec variantes... La taille du type est égale à la somme de celle de la partie fixe et de celle de la partie variante la plus grande. Attention : comme les différentes alternatives se superposent en mémoire, l'affectation des champs d'une variante modifie le contenu des champs des autres variantes sans vérifier la cohérence de ces changements.

Enregistrement avancé

Un enregistrement avec des méthodes et des propriétés.

  • Souvenez-vous qu'il faut ajouter la directive de compilation {$MODESWITCH ADVANCEDRECORDS}.

Adressage

Champs

On accède aux champs en plaçant un point entre le nom de l'enregistrement et le nom du champ, ainsi :

  a.firstname := 'George';
  a.surname := 'Petersen';
  a.phone := '789534';
  a.paidCurrentSubscription := true;

Éventuellement, l'accès aux groupes de champs peut être effectué sans répéter le nom de l'enregistrement à l'aide de la construction with :

with a do
begin
  firstname := 'George';
  surname := 'Petersen';
  phone := '789534';
  paidCurrentSubscription := true
end;

Instances

Un enregistrement est traité par le programme comme une entité entière. Par exemple, un enregistrement entier peut être copié dans un autre de même type à l'aide d'une seule affectation :

var
  a, b: TMember;

(* programme principal *)
begin
  { ... affecte les valeurs vers le champs de a dans l'enregistrement b .. }
  b := a
  { maintenant b contient la copie de a }
  { à ne pas confondre avec les références : }
  { a et b sont des entités différentes de TMember }
end.

Enregistrement constant

type
  //record declaration
  TSpecialDay = record
    DayName : string;
    month : integer;
    day : integer;
  end;

const
  // TSpecialDay constant
  ChristmasDay : TSpecialDay = 
  (
    DayName : 'Christmas Day';
    month : 12;
    day : 25;
  );

Voir aussi

Types de données
Types de données simples Boolean | Byte |Cardinal | Char | Currency | Extended | Int64 | Integer | Longint | Pointer | Real | Shortint | Smallint | Word
Types de données complexes Array | Class | Record | Set | String | ShortString