mysql/fr

From Free Pascal wiki
Jump to: navigation, search

English (en) español (es) français (fr)

Portail de la base de données

Références:

Tutoriels/articles pratiques :

Bases de données

Advantage - MySQL - MSSQL - Postgres - Interbase - Firebird - Oracle - ODBC - Paradox - SQLite - dBASE - MS Access - Zeos

Vue d'ensemble

Vous pouvez utiliser Free Pascal/Lazarus pour accéder à un serveur de base de données MySQL. Aussi vous pouvez utiliser les composant MySQL Data Access (MyDAC) comme un composant pour connecter Lazarus à MySQL. Les composants Lazarus MyDAC sont libres en téléchargement.

Win64: veuillez lire les avertissements ici sur l'inadéquation de certaines versions Win64 de FPC/Lazarus.

Avantages de MySQL:

  • Il est très largement utilisé et disponible.
  • Bien que les plus anciennes versions avaient la réputation de ne pas être de vrais SGBDR, les nouvelles versions prennent en charge les propriétés ACID si correctement configurées (avec le bon stockage en arrière plan (backend storage))

Inconvénients de MySQL:

  • Les mainteneurs de MySQL ne conservent pas la compatibilité entre les versions de bibliothèque client. Ce qui signifie que la traduction en FPC/Lazarus doit être faite pour chaque nouvelle version, ce qui ralentit les choses.
  • La licence peut être restrictive pour certaines utilisations (p.ex. les déploiements commerciaux). Il existe une alternative comme MariaDB compatible et sasn doute moins restrictive.

De nombreux utilisateurs de Lazarus/FPC préfèrent les SGBDR Firebird ou PostgreSQL pour cette raison.

Licence de MySQL

Avant un déploiement significatif de MySQL, n'oubliez pas de lire sa licence.

SQLDB

Lazarus 1.2 (with FPC 2.6.2), supports

  • Bibliothèque cliente MySQL 4.0
  • Bibliothèque cliente MySQL 4.1
  • Bibliothèque cliente MySQL 5.0
  • Bibliothèque cliente MySQL 5.1
  • Bibliothèque cliente MySQL 5.5 (pris en charge depuis Lazarus 1.0.8)
  • Bibliothèque cliente MySQL 5.6 (pris en charge depuis Lazarus <à remplir>)

sqldbcomponents.png

De plus récentes versions de FPC/Lazarus peuvent supporter de plus récentes bibliothèques clientes de MySQL.

Assurez-vous que vous utilisez le composant de connexion correct pour votre version de bibliothèque client. Ainsi si vous avez les bibliothèques clientes installées pour MySQL 4.1, vous devez utiliser le composant TMySQL41Connection, même si le serveur fonctionne en version 4.0 ou 5.0. La raison à cela est que les bibliothèques clientes MySQL casse souvent la compatibilité de leurs API et donc chaque version demande un pilote Pascal différent.

Sur les systèmes *nix, le code SQLdb peut rechercher la version pure de la bibliothèque sans suffixe de numéro de version. Il y a plusieurs manières de pouvoir traiter ceci :

  • (sur plusieurs Linux) installer la version -dev de la bibliothèque.
  • créer un lien symbolique sur le nom de bibliothèque spécifique vers celui que recherche FPC (plutôt que hacker)
  • utiliser TSQLDBLibraryLoader pour spécifier le nom de bibliothèque avant le chargement de la connexion.

Tutoriels SQLDB et exemple de code

Faire fonctionner MySQL dans Linux ou Windows

Suivez les instructions dans le Manuel Utilisateur de MySQL. Assurez-vous que le daemon mysqld tourne de manière fiable, que tous les utilisateurs potentiels (y compris root, mysql, vous-mêmes et quiconque en aurait besoin) aient les priilèges qu'ils exigent, de n'importe quel hôte qu'il y a besoin (tel que 'localhost', le nom d'hôte local, et d'autres hôte sur votre réseau) tout en restant cohérent avec la sécurité. Il est préférable que les tous les utilisateurs, y compris le root, (NdT : sic) aient des mots de passe. Testez l'action du système de base de donnée en utilisant les exemples donnés dans le manuel et contrôlez que tous les utilisateurs ont des accès fiables.

Faire fonctionner MySQL avec FPC en mode texte

Il y a un répertoire avec un programme d'exemple dans $(fpcsrcdir)/packages/base/mysql/. Vous pouvez trouver le répertoire des sources dans Lazarus: Tools -> Options -> Files -> FPC source directory. Les chemins possibles pour le répertoire mysql sont /usr/share/fpcsrc/packages/base/mysql/ (installation par rpm) ou C:\lazarus\fpcsrc\packages\base\mysql\ (windows). Ce répertoire contient aussi les unités mysql.pp, mysql_com.pp et mysql_version.pp. Avant d'exécuter le script de test, vous avez besoin une base de données nommée testdb: faites ceci en vous connectant au moniteur mysql (en root avec tous les privilèges) et lancer les ordres SQL suivants :

CREATE DATABASE testdb;

puis assurez-vous que tous les utilisateurs concernés ont les privilèges d'accès appropriés pour cela :

GRANT ALL ON testdb TO johnny-USER IDENTIFIED BY 'johnnyspassword';

Il y a un script appelé mkdb que vous devriez maintenant essayer de lancer :

sh ./mkdb

Cela échouera probablement, car le système ne permet pas à un utilisateur anonyme d'accéder à la base de données. Il faut donc changer le script en utilisant un éditeur à la ligne :

mysql -u root -p  ${1-testdb} << EOF >/dev/null

et essayez d'exécuter à nouveau en entrant votre mot de passe à l'invite. Avec de la chance, vous avez peut-être réussi à créer la base de données de test : testez-la (tant que vous être connectés dans le moniteur mysql) en lançant l'ordre mysql

SELECT * FROM FPdev;

Vous devriez voir une table listant l'ID, le nom d'utilisateur et l'adresse e-mail de quelques développeurs FPC. Maintenant, essayer d'exécuter le programme de test testdb.pp (il peut avoir besoin d'être compilé, et échouera certainement au premier essai !!).

J'ai trouvé que le programme ne pourrait pas se connecter à mysql pourt plusieurs raisons :

  • Mon système (SuSE Linux v9.0) installe mysql v4.0.15, pas la version 3 pour laquelle le paquet a été conçu.
  • Le programme a besoin d'avoir les noms d'utilisateur et les mots de passe pour obtenir l'accès à la base de données.
  • Le compilateur demande à savoir où trouver les bibliothèques mysql (SI VOUS N'AVEZ PAS INSTALLER LES BIBLIOTHEQUES DE DEV, FAITES-LE MAINTENANT !)

J'ai créé une copie de testdb.pp appelée trydb.pp, plutôt qu'éditer l'original - cela veut dire que les fichiers originaux peuvent encore être corrigés par les mise à jour de CVS. J'ai aussi copié les fichiers trouvés dans le sous-répertoire mysql/ver40/ dans le sous-répertoire mysql/, en les renommant mysql_v4.pp, mysql_com_v4.pp et mysql_version_v4.pp, en adaptant les nomes d'unités dans chacun des fichiers en conséquence. J'ai changé l'instruction uses dans trydb.pp en

uses mysql_v4

et l'instruction dans mysql_v4.pp en

uses mysql_com_v4

J'ai ajouté une ligne à /etc/fpc.cfg pour pointer vers mes bibliothèques :

-Fl/lib;/usr/lib

L'étape suivante pourrait être moins nécessaire si les bibliothèques de dév. sont installées car les liens sont installés pour vous, mais cela ne coûte rien de vérifier. J'ai dû trouvé le vrai nom de la bibliothèque cliente de mysql dans le répertoire /usr/lib et dans mon cas j'ai dû lancer la commande shell :

ln -s libmysqlclient.so.12.0.0 lmysqlclient

pour faire un lien symbolique permettant à FPC de trouver la bibliothèque. Pour faire bonne mesure, j'ai aussi créé le lien :

ln -s libmysqlclient.so.12.0.0 mysqlclient

et placé des liens similaires dans divers autres répertoires : pas strictement nécessaire, mais juste au cas où ... ! Certains utilisateurs pourraient avoir besoin d'ajouter le lien suivant :

ln -s libmysqlclient.so.12.0.0 libmysqlclient.so

J'ai modifié trydb.pp pour inclure les détails utilisateur, initialement en ajoutant l'hôte, l'utilisateur et le mot de passe en constantes :

const
  host : Pchar= 'localhost';
  user : Pchar= 'myusername';
  passwd: Pchar = 'mypassword';
Warning-icon.png

Avertissement: Cette section semble extrêmement obsolète. Si vous êtes encore sur MySQL 4 peut-être est-il temps de vous mettre à jour.

J'ai aussi trouvé que je ne pouvais pas me connecter à mysql en utilisant l'appel à mysql_connect(),mais devais utiliser mysql_real_connect() qui a plusieurs paramètres. Pour compliquer un peu plus les choses, le nombre de paramètres semble avoir été changé entre la version 3 (où il y en a sept) et la version 4 (où il y en a huit). Avant d'utiliser mysql_real_connect j'ai dû utiliser mysql_init() lequel n'est pas trouvé dans le mysql.pp original mais est trouvé dans mysql_v4.pp.

Donc le code pour la connexion à la base de données est maintenant :

{ a few extra variables}
var
  alloc : PMYSQL;
 
{main program fragment}
 
begin
  if paramcount=1 then
  begin
    Dummy:=Paramstr(1)+#0;
    DataBase:=@Dummy[1];
  end;
 
  Writeln('Allocating Space...');
  alloc := mysql_init(PMYSQL(@qmysql));
  Write('Connecting to MySQL...');
  sock := mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
  if sock=Nil then
  begin
    Writeln(stderr,'Couldn''t connect to MySQL.');
    Writeln(stderr, 'Error was: ', mysql_error(@qmysql));
    halt(1);
  end;
  Writeln('Done.');
  Writeln('Connection data:');
 {$ifdef Unix}
  writeln('Mysql_port      : ',mysql_port);
  writeln('Mysql_unix_port : ',mysql_unix_port);
 {$endif}
  writeln('Host info       : ',mysql_get_host_info(sock));
  writeln('Server info     : ',mysql_stat(sock));
  writeln('Client info     : ',mysql_get_client_info);
 
  Writeln('Selecting Database ',DataBase,'...');
  if mysql_select_db(sock, DataBase) < 0 then
  begin
    Writeln(stderr,'Couldn''t select database ',Database);
    Writeln(stderr,mysql_error(sock));
    halt(1);
  end;
 {... as original contents of testdb.pp}

Maintenant - prêt pour démarrer le compilation de trydb.pp ?

 fpc trydb

Réussite ! Vous opouvez dorénavant l'exécuter :

 ./trydb

Youpi ! J'ai eu le listing des développeurs FPC !

Un petit raffinement supplémentaire : Rendre l'entrée des détails de l'utilisateur et les commandes mysql interactives, utiliser des variables plutôt que des constantes et permettre l'entrée de plusieurs commandes SQL, jusqu'à ce que nous émettions la commande quit : voir liste complète des programmes, où les détails de l'utilisateur sont entrés dans la console, et le programme passe dans une boucle où les commandes SQL sont entrées depuis la console (sans le point-virgule terminal) et les réponses sont imprimées, jusqu'à ce que "quit" soit saisi à partir du clavier.

Voir Exemple de listing console.

Se connecter à MySQL depuis une application Lazarus

Ce tutoriel montre comment connecter Lazarus à une base de données MySQL, et exécute de simples requêtes, en utilisant les composants Lazarus de base ; il utilise aucun composant sensible aux données, mais illustre les principes d'interaction avec la base de données.

Créez un nouveau projet dans Lazarus :

Project -> New Project -> Application

Une nouvelle forme automatiquement générée apparaîtra.

Agrandissez la fiche à environ la moitié de l'écran, ensuite renommez la fiche et sa légende (caption) en 'TryMySQL'.

Depuis l'onglet Standard de la palette de composant, placez trois TEdit en haut à gauche de la fiche et immédiatement en dessus de chaque TEdit placez une étiquette (Label). Changez les noms et les légendes en 'Hôte' (avec HostLLabel, HostEdit), 'Nom d'utilisateur' (avec UserLabel, UserEdit) et 'Mot de passe' (avec PasswdLabel et PasswdEdit). De manière alternative; vous pourriez utiliser des composants LabelledEdit depuis l'onglet Additional.

Sélectionnez le champ de saisie Mot de passe et trouvez la propriété PasswordChar : changez-la en '*' ou quelque autre caractère, ce qui empêchera les caractères saisis d'apparaître à l'écran, ce caractère apparaîtra à la place. Assurez-vous que les propriétés Text sont à blanc.

Maintenant placez une autre zone de saisie TEdit et une étiquette (TLabel) en haut du côté droit de votre fiche. Changez l'étiquette en 'Entrez un ordre SQL'. et nommez-le CommandEdit.

Placez trois boutons sur la fiche : deux sur la gauche sous les champs de saisie et un à droite sous la zone Ordre.

Changez les légendes des boutons de gauche en 'Se connecter' (ConnectButton) et 'Terminer' (ExitButton) et pour celui à droite 'Envoyer la requête' (QueryButton).

Placez un TMemo large étiqueté et nommé 'Résultats' (ResultMemo) dans le bas à droite, de façon à remplir au mieux la place libre. Trouvez la propriété ScrollBars et sélectionnez ssAutoBoth, ainsi les barres de défilement apparaîtront automatiquement si l le texte remplit l'espace. Définissez la propriété WordWrap à True.

Placez une barre de status (depuis l'onglet Contrôles Communs) tout en bas de la fiche et et mettre dans sa propriété SimpleText 'TryMySQL'.

Une capture d'écran de la fiche peut être vue ici : Exemple Mysql.

Maintenant vous devez coder quelques gestionnaires d'événement.

Les trois boîtes d'édition sur la gauche sont des entrées pour le nom d'hôte, le nom d'utilisateur et le mot de passe. Quand elles sont entrées de manière satisfaisante, le bouton Connect est cliqué. Le gestionnaire OnClick de ce bouton est basé en partie sur la programme en mode texte du dessus.

Les réponses de la base de données devraient être converties en chaînes et affichées dans le mémo. Les procédures Pascal en mode texte Write et WriteLn sont capables de faire beaucoup de conversions 'en vol', mais l'utilisation de la boîte Mémo pour la sortie de texte nécessite une conversion explicite de types de donnée vers la chaîne correcte : donc les variables PChar doivent être converties en chaînes en utilisant StrPas et les entiers doivent être convertis avec IntToStr . Les chaînes sont affichées dans le Mémo en utilisant :

procedure ShowString(S : string);
(* display a string in a Memo box *)
begin
  trymysqlForm1.ResultsMemo.Lines.Add(S)
end;

Le gestionnaire de l'événément du ConnectButton devient alors :

procedure TtrymysqlForm1.ConnectButtonClick(Sender: TObject);
(* Connect to MySQL using user data from Text entry boxes on Main Form *)
var strg: string;
 
begin
  dummy1 :=  trymysqlForm1.HostEdit.text+#0;
  host := @dummy1[1];
  dummy2 := trymysqlForm1.UserEdit.text+#0;
  user := @dummy2[1] ;
  dummy3 := trymysqlForm1.PasswdEdit.text+#0;
  passwd := @dummy3[1] ;
 
  alloc := mysql_init(PMYSQL(@qmysql));
  sock :=  mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
  if sock=Nil then
    begin
      strg :='Couldn''t connect to MySQL.'; showstring (strg);
      Strg :='Error was: '+ StrPas(mysql_error(@qmysql)); showstring (strg);
    end
    else
    begin
      trymysqlForm1.statusBar1.simpletext := 'Connected to MySQL';
      strg := 'Now choosing database : ' + database; showstring (strg);
 {$ifdef Unix}
      strg :='Mysql_port      : '+ IntToStr(mysql_port); showstring (strg);
      strg :='Mysql_unix_port : ' + StrPas(mysql_unix_port); showstring (strg);
 {$endif}
      Strg :='Host info       : ' + StrPas(mysql_get_host_info(sock));
      showstring (strg);
      Strg :='Server info     : ' + StrPas(mysql_stat(sock)); showstring (strg);
      Strg :='Client info     : ' + Strpas(mysql_get_client_info);  showstring (strg);
 
      trymysqlForm1.statusbar1.simpletext := 'Selecting Database ' + DataBase +'...';
      if mysql_select_db(sock,DataBase) < 0 then
      begin
        strg :='Couldn''t select database '+ Database; ShowString (strg);
        Strg := mysql_error(sock); ShowString (strg);
      end
    end;
end;

La zone de texte sur la droite permet d'entrer un ordre SQL, sans le point-virgule final ; quand vous êtes satisfait du contenu ou de sa syntaxe, le bouton SendQuery est enfoncé et la requête exécutée, avec ses résultats écrits dans le mémo ResultsMemo.

Le gestionnaire d'événement de SendQuery est à nouveau basé sur la version en mode texte de FPC, sauf que, une fois de plus, la conversion de type explicite doit être effectuée avant que les chaînes ne soient affichées dans la boîte.

La différence avec la version en mode texte est que si une condition d'erreur est détectée, le programme ne s'arrête pas et MySQL n'est pas fermé ; au lieu de cela, le contrôle est rendu à la fiche principale et il devient possible de corriger l'entrée avant de soumettre à nouveau l'ordre SQL. L'application se termine enfin (avec la fermeture de MySQL) quand le bouton Exit est cliqué.

Le code de SendQuery est le suivant :

procedure TtrymysqlForm1.QueryButtonClick(Sender: TObject);
var
  dumquery, strg: string;
begin
  dumquery := TrymysqlForm1.CommandEdit.text;
  dumquery := dumquery+#0;
  query := @dumquery[1];
  trymysqlForm1.statusbar1.simpletext := 'Executing query : '+ dumQuery +'...';
  strg := 'Executing query : ' + dumQuery; showstring (strg);
  if (mysql_query(sock,Query) < 0) then
  begin
    Strg :='Query failed '+ StrPas(mysql_error(sock)); showstring (strg);
  end
  else
  begin
    recbuf := mysql_store_result(sock);
    if RecBuf=Nil then
    begin
      Strg :='Query returned nil result.'; showstring (strg);
    end
    else
    begin
      strg :='Number of records returned  : ' + IntToStr(mysql_num_rows (recbuf));
      Showstring (strg);
      Strg :='Number of fields per record : ' + IntToStr(mysql_num_fields(recbuf));
      showstring (strg);
      rowbuf := mysql_fetch_row(recbuf);
      while (rowbuf <>nil) do
      begin
        Strg :='(Id: '+ rowbuf[0]+', Name: ' + rowbuf[1]+ ', Email : ' +
        rowbuf[2] +')';
        showstring(strg);
        rowbuf := mysql_fetch_row(recbuf);
      end;
    end;
  end;
end;

Enregistrez votre projet et exécutez (menu Run -> Run).

Télécharger le code source de l'exemple

Warning-icon.png

Avertissement: Les versions actuelles de Lazarus/FPC demande de valider toutes les transactions MySQL. Ceci n'était pas nécessaire dans les version précédentes. Le code téléchargé ne tournera certainement pas tant qu'il ne sera pas mis à jour.

Un listing complet du programme est disponible ici Sample Source Code.

Lazarus, MySQL et UTF-8

Ce qui suit peut être aussi bien nécessaire pour d'autres pages de code/jeux de caractères.

L'Unicode UTF-8 est un encodage de jeu de caractères multi-octet commode, qui permet de travailler avec des textes multilingues sans demander de WideStrings (2 octets par caratère). Il est supporté aussi bien par les composants SQLdb Lazarus que par MySQL depuis la version 4.1 en choisissant le jeu de caractères approprié.

Néanmoins, en réglant simplement cet encodage comme défaut pour

  • vos tables et
  • le composant de connexion MySQL (p.ex. TMySQL51Connection.CharSet:='UTF8';)

aboutira à un stockage et à la récupération de chaînes UTF-8 incorrects : tout caractères accentués/international sera montré avec des point d'interrogation (?). Apparemment, la raison à cela est que la bibliothèque client est compilée pour s'attendre à des caractère Latin1 défini par défaut.

En vue d'une communication correcte entre Lazarus, la bibliothèque client MySQL et le serveur MySQL, dexu requêtes supplémentaires demandes à être exécutées à chaque fois qu'une connexion à la bse de données est établie :

SET CHARACTER SET `utf8`

et

SET NAMES 'utf8'

La première requête s'assurera que votre application reçoive des chaînes correctement encodées, et la seconde demande à MtySQL de ne pas convertir les chaînes qu'il reçoit de votre application.

Simple démo MySQL utilisant le composant TMySQL5xConnection

Voici du code qui fonctionne comme une démo vite fait pour démarrer et s'exécuter simplement. Comme avec tous les composants SQLdb, assurez-vos que la bibliothèque client est à l'emplacement correct :

  • dans Windows: la DLL p.ex. libmysql.dll est mise dans dossier de sortie du projet (où l'exécutable est généré). Vous pouvez aussi la placer dans votre répertoire Windows/system32.
  • dans Linux/OSX: installez la bibliothèque client de MySQL dans votre chemin (p.ex. en utilisant votre gestionnaire de paquet, rpm, deb...).

Lors de la distribution de votre application, assurez-vous que la bonne bibliothèque client de MySQL est présente sur l'ordinateur de votre utilisateur. Comme cela peut être un problème, peut-être qu'utiliser un moteur de base de données différent peut être plus pertinent.

Exemple conduit par le code

Cet exemple utilise du code pour remplir des contrôles avec de la donnée. Vous pouvez aussi utiliser des contrôles sensibles aux données (TDBEdit...), ce qui pourrait être plus facile/rapide. Voir l'exemple du dessous ou le Tutoriel SQLdb 1 pour cela.

Placez trois champs d'édition (TEdit), un champ Mémo et quelques boutons sur la fiche. Vous devez ajoutez mysqlXXconn and sqldb dans la clause Uses.

Dans cet exemple, le SGBD MySQL a un utilisateur 'root' sans mot de passe et une base de données 'test1' avec une table 'tPerson' qui a trois champs : 'personid' (int), 'surname' (varchar(40)) et 'dob' (datetime). Aussi quelques données de test ont été ajoutées.

Le bouton btnTest doit être cliqué en premier car il crée la connexion avec le, SGBD. Notez la ligne qui applique les mises à jour - sans cela, les données modifiées ou nouvelles ne seront pas retournées au DB même si elles seront en mémoire et peuvent être visualisées à l'aide de btnFirst et btnNext.

unit unt_db;
// Example based on:
// http://www.lazarus.freepascal.org/index.php?name=PNphpBB2&file=viewtopic&t=5761
// from tpglemur on that forum
{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  mysql50conn, sqldb, StdCtrls;
type
  { TForm1 }
  TForm1 = class(TForm)
    btnTest: TButton;
    btnNext: TButton;
    btnFirst: TButton;
    btnNew: TButton;
    edtPersonID: TEdit;
    edtSurname: TEdit;
    edtDOB: TEdit;
    Memo1: TMemo;
    procedure btnFirstClick(Sender: TObject);
    procedure btnNewClick(Sender: TObject);
    procedure btnNextClick(Sender: TObject);
    procedure btnTestClick(Sender: TObject);
  private
    { private declarations }
    conn : TMySQL50Connection;
    query : TSQLQuery;
    transaction : TSQLTransaction;
    procedure Display;
  public
    { public declarations }
  end;
var
  Form1: TForm1;
implementation
{ TForm1 }
procedure TForm1.btnTestClick(Sender: TObject);
var
  S: String;
begin
  conn := TMySQL50Connection.Create(nil);
  query := TSQLQuery.Create(nil);
  transaction := TSQLTransaction.Create(nil);
  try
    try
      // Adjust to your own database server, username and password:
      conn.HostName := '127.0.0.1';
      conn.UserName := 'root';
      conn.Password := '';
      // If you use a different database name, adjust here:
      conn.DatabaseName := 'test1';
      conn.Connected := True;
      conn.Transaction := transaction;
      query.DataBase := conn;
      //query.ParseSQL := true; //line not needed - this is the default anyway
      //query.ReadOnly := false; //line not needed - this is the default anyway
      query.SQL.Text := 'select * from tperson';
      query.Open;
 
      query.Last;
      S := IntToStr(query.RecordCount) + #13#10;
      query.First;
 
      while not query.EOF do
      begin
        S := S + query.FieldByName('surname').AsString + #13#10;
        query.Next;
      end;
    finally
      //query.Free;
      //conn.Free;
    end;
  except
    on E: Exception do
      ShowMessage(E.message);
  end;
  Memo1.Text:= S;
end;
 
procedure TForm1.Display;
begin
  edtPersonID.Text := query.FieldByName('personid').AsString;
  edtSurname.Text := query.FieldByName('surname').AsString;
  edtDOB.Text := query.FieldByName('dob').AsString;
end;
 
procedure TForm1.btnFirstClick(Sender: TObject);
begin
  query.First;
  Display;
end;
 
procedure TForm1.btnNewClick(Sender: TObject);
begin
  query.Append;
  query.FieldValues['personid'] := edtPersonID.Text;
  query.FieldValues['surname'] := edtSurname.Text;
  query.FieldValues['dob'] := edtDOB.Text;
  query.Post;  
  query.ApplyUpdates; //to apply update
  transaction.Commit; //Needed since FPC 2.6.4; todo: somebody should check if this is enough
end;
 
procedure TForm1.btnNextClick(Sender: TObject);
begin
  query.Next;
  Display;
end;
 
initialization
  {$I unt_db.lrs}
end.

RAD/Contrôles liés aux données

Veuillez voir Tutoriel SQLdb 1, Tutoriel SQLdb 2 et plus de tutoriels.

Zeos

Voir ZeosDBO

Pascal Data Objects (PDO)

Pascal Data Objects is an alternative data access layer that seems to support:

  • Clients MySQL 4.0
  • Clients MySQL 4.1
  • Clients MySQL 5.0
  • (et aussi) Firebird 1.5 et 2.0

Les fonctions introduites dans MySQL 4.1 et 5.0 comme les instructions préparées, la liaison et les procéduresstockées sont prises en charge. PDO est inspiré de PHP Data Objects. Tout le code et la documentation nécessaire à l'emploi de cette API est disponible sur sourceforge.

Paquet MySQL : Les unités de bas-niveau

Comme avec toute les bases de données, le code SQLdb dépend d'une unité spécifique à MySQL de bas niveau qui enveloppe la bibliothèque du pilote MySQL (.so/.dll). Normalement, vous utiliseriez le code SQLdb de haut niveau car il vous permet de coder plus rapidement, de changer plus facilement de SGBD, etc.

Utiliser ceci est très facile, tout ce dont vous avez besoin est de compiler certaines unités, et d'utiliser ces unités dans votre programme. Vous avez besoin de spécifier l'emplacement dans le système de fichiers de la bibliothèque client MySQL (libmysqlclient sur Linux) lors de la compilation, et c'est tout.

Unités et programmes fournis

Le paquet fournit 3 unités, desquelles seulement le première est nécessaire :

  • mysql la principale unité mysql.
  • mysql<version> (p.ex. mysql50) fournit l'accès à une bibliothèque pour cette version. note : la version de la bibliothèque cliente n'est pas corrélée à celle du serveur en usage - sauf si vous voulez que ces versions soient compatibles.
  • mysql<version>com contient quelques routines internes de MySQL (Vraisemblablement une traduction de mysql_com.h) ; elle ne devrait normalement pas être utilisée à moins que vous vouliez accéder à certains types internes.

Des programmes d'exemple peuvent être trouvés dans le répertoire <fpc>\packages\mysql\examples.

Installation

L'interface à MySQL est distribuée avec les paquets Free Pascal et est fourni avec la distribution du compilateur : normalement aucune action ne doit être entreprise pour travailler avec MySQL.

Au cas où vous voulez modifier et compiler les unités vous-mêmes, le sources pour MySQL sont dans le répertoire des paquets : packages/mysql.

Ce répertoire contient les unités, un programme de test et un fichier make. Placez-vous (commande cd) dans le répertoire et tapez :

make

Ceci devrait compiler les unités. Si la compilation est réussie, vous pouvez installer avec :

make install

Vous pouvez tester le programme en exécutant :

make test

Ceci aura pour effet :

  • d'exécuter un script pour créer une table dans la base de données et de la remplier avec quelques données. (le programme MySQL doit être accessible via la variable PATH pour cela). Par défaut, la base de données utilisée est 'testdb',
  • d'exécuter le programme de test testdb,
  • d'exécuter un nouveau shell pour supprimer la table créée.

Vous verrez beaucoup de messages sur votre écran, vous donnant des retours d'information et des résultats. Si quelque chose n'a pas marché, make vous en informera.

Retour à la liste des paquets.

Voir aussi