Avoiding implicit try finally section

From Free Pascal wiki

English (en) suomi (fi) Bahasa Indonesia (id) русский (ru)

overview

When optimizing code it helps to know that the compiler will wrap certain code constructs in an implicit tryfinally-block. This is needed whenever you use variables such as ansiStrings, variants or dynamic arrays which require initialization and finalization (i.e. where the standard procedures initialize and finalize are needed for correct allocation and release of acquired memory).

For example, a procedure like

procedure doSomething;
var
	msg: ansiString;
begin
	// do something with msg
end;

is actually expanded by the compiler to look like this (difference highlighted):

procedure doSomething;
var
	msg: ansiString;
begin
	initialize(msg);
	try
		// do something with msg
	finally
		finalize(msg);
	end;
end;

The compiler thereby ensures that the reference count of msg will be properly decremented when procedure doSomething exits with exception[s]?. However, often this may have significant adverse effects on the generated code's speed.

This is issue was a subject on the fpc-devel list in the TList slowness classes thread.

Note, that temporary ansiString variables can be created implicitly. The only way to be completely certain about what actually is being done is to read the assembler output.

possible solutions

  • use {$implicitexceptions off}: Ensure this applies to release versions only. Debugging can become cumbersome with that switch especially locating memory leaks and corruption.
  • split off rarely used code that causes an implicit tryfinally into separate procedures. (You can use procedures in procedures)
  • use const parameters rather than value parameters. This avoids the need to change refcount but temporary variables could still be an issue.
  • use global variables: You have to be careful with reentrancy issues here though and temporary variables could still be an issue.
  • use non-reference-counted types like shortstrings.

risks and when to apply

Warning-icon.png

Warning: These exception frames are generated for a reason. If you leave them out any exception in that code will leave a memory leak

In 2007 {$implicitExceptions} was added to the strutils unit. Meanwhile, sysutils has probably followed. For this, the following approach was followed:

  • A routine that calls a routine that raises exceptions is unsafe – e.g. strToInt, but not strToIntDef.
  • A routine that raises exceptions itself is unsafe.
  • Very large routines are not worth the trouble, because of the risk and low gains – e.g. date formatting routines.
  • Floating point usage can raise exceptions that are converted into catchable exceptions by sysUtils. I'm not sure if this really is sufficient reason, but I skipped floating point using routines initially for this reason.

If you detect problems with these changes please contact Marco.

demo program

Below is a small demo program that

  • when run, clearly shows that avoiding an implicit try … finally-block can make code a lot faster. When I run this program on my system, I get
time of fooNormal: 141
time of fooFaster: 17
  • Shows a trick how to avoid implicit try finally-block (without changing the meaning or safety of the code) in some cases (when you don't need to actually use that AnsiString/Variant/something every time procedure is called but e.g. only if some parameter has some particular value).
 1 program implicitExceptionDemo(input, output, stderr);
 2 
 3 // for exceptions
 4 {$mode objfpc}
 5 // data type 'string' refers to 'ansistring'
 6 {$longstrings on}
 7 
 8 uses
 9   {$IFDEF UNIX}
10     // baseUnix, unix needed only to implement clock
11     BaseUnix, Unix,
12   {$ENDIF}
13     sysUtils;
14 
15 function clock(): int64;
16 
17 var
18   {$IFDEF UNIX}
19     dummy: tms;
20   {$ELSE}
21     TS : TTimeStamp;
22   {$ENDIF}
23 begin
24   {$IFDEF UNIX}
25 	clock := fpTimes(dummy);
26   {$ELSE}
27    TS:=DateTimeToTimeStamp(Now);
28    result := TS.Time;
29   {$ENDIF}
30 end;
31 
32 
33 
34 // Note: when fooNormal and fooFaster are called
35 //       i is always >= 0, so no exception is ever actually raised.
36 // So string constants SNormal and SResString are not really used.
37 
38 procedure fooNormal(i: integer);
39 var
40 	s: string;
41 begin
42 	if i = -1 then
43 	begin
44 		s := 'Some operation with AnsiString';
45 		raise exception.create(s);
46 	end;
47 end;
48 
49 procedure fooFaster(i: integer);
50 	procedure raiseError;
51 	var
52 		s: string;
53 	begin
54 		s := 'Some operation with AnsiString';
55 		raise exception.create(s);
56 	end;
57 begin
58 	if i = -1 then
59 	begin
60 		raiseError;
61 	end;
62 end;
63 
64 
65 // M A I N =================================================
66 const
67 	testCount = 10000000;
68 var
69 	i: integer;
70 	start: int64;
71 begin
72 	start := clock();
73 	for i := 0 to testCount do
74 	begin
75 		fooNormal(i);
76 	end;
77 	writeLn('time of fooNormal: ', clock() - start);
78 	
79 	start := clock();
80 	for i := 0 to testCount do
81 	begin
82 		fooFaster(i);
83 	end;
84 	writeLn('time of fooFaster: ', clock() - start);
85 end.

By putting raiseError into a nested scope of fooFaster, exception handling does not become part of the main thread of execution.