LCL Tips/de

From Free Pascal wiki
Jump to navigationJump to search

│ Deutsch (de) │ English (en) │ français (fr) │ русский (ru) │ 中文（中国大陆）‎ (zh_CN) │

GUI Anwendung per Code erstellen

Es ist möglich eine GUI Anwendung (Graphical User Interface) vollständig durch Pascalcode in Lazarus zu erstellen. Alles, was von der IDE aus möglich ist, ist auch per Code umsetzbar. Die nachfolgenden Beispieldateien für die Programm- und Unitdateien (codegui.lpr und mainform.pas) können Sie als Vorlage verwenden, die Sie anpassen können. Das wichtigste ist, nicht zu vergessen die Parent-Eigenschaft der Komponenten festzulegen. Die Erstellung von Steuerelementen innerhalb des Formulars erfolgt am besten im Konstruktor des Formulars:

Hauptprogrammdatei: 

program codedgui;

{$MODE DELPHI}{$H+}

uses
  Interfaces, Forms, StdCtrls,
  MainForm;

var
  MyForm: TMyForm;
begin
  Application.Initialize;
  Application.CreateForm(TMyForm, MyForm);
  Application.Run;
end.

Die Unit, die das Formular beinhaltet: 

unit mainform;

{$MODE DELPHI}{$H+}

interface

uses Forms, StdCtrls;

type
  TMyForm = class(TForm)
  public
    MyButton: TButton;
    procedure ButtonClick(ASender: TObject);
    constructor Create(AOwner: TComponent); override;
  end;

implementation

procedure TMyForm.ButtonClick(ASender:TObject);
begin
  Close;
end;

constructor TMyForm.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  //Hint: FormCreate() is called BEFORE Create() !
  //so You can also put this code into FormCreate()
  //(This is not the case when creating components ..)

  Position := poScreenCenter;
  Height := 400;
  Width := 400;

  VertScrollBar.Visible := False;
  HorzScrollBar.Visible := False;

  MyButton := TButton.Create(Self);
  with MyButton do
  begin
    Height := 30;
    Left := 100;
    Top := 100;
    Width := 100;
    Caption := 'Close';
    OnClick := ButtonClick;
    Parent := Self;
  end;

  // Erstellen Sie hier noch weitere Komponenten 
end;

end.

Bedienelemente manuell erzeugen ohne Overhead

Parent zuletzt setzen

Für Delphianer: Im Gegensatz zu Delphi erlaubt die LCL beinahe alle Eigenschaften in beliebiger Reihenfolge zu setzen. Zum Beispiel unter Delphi können sie ein Bedienelement nicht ohne a parent positionieren. Die LCL erlaubt dies und dieses Feature kann benutzt werden, den Overhead zu reduzieren. 

 with TButton.Create(Form1) do begin
   // 1. Erzeugen eines button setzt die Vorgabegröße
   // 2. Ändern der Position. Keine Randeffekte, weil Parent=nil
   SetBounds(10,10,Width,Height);
   // 3. Ändern der Größe abhängig vom Thema. Noch nicht, weil Parent=nil
   AutoSize:=true;
   // 4. Ändern der Größe wegen AutoSize=true. Noch nicht, weil Parent=nil
   Caption:='Ok';
   // 5. Setzen sie Parent. Jetzt geschieht all das obige, aber in einer einzigen Aktion.
   Parent:=Form1;
 end;

Wenn ein Bedienelement a Parent hat, dann werden alle Eigenschaften unverzüglich wirksam. Ohne a Parent tun viele Eigenschaften nicht mehr, als den Wert zu speichern. Und sobald the Parent gesetzt ist, wird jede Eigenschaft angewendet. Das trifft besonders für grand children zu: 

 GroupBox1:=TGroupBox.Create(Self);
 with GroupBox1 do begin
   with TButton1.Create(Self) do begin
     AutoSize:=true;
     Caption:='Click me';
     Parent:=GroupBox1;
   end;
   Parent:=Form1;
 end;
 Form1.Show;

Autosizing startet nicht bevor jeder parent eingerichtet ist und das Formular sichtbar wird.

Vermeiden sie eine frühe Handle Erzeugung

Sobald das Handle eines TWinControl erzeugt ist, ändert jede Änderung einer Eigenschaft the visual thing (called the widget), sogar wenn ein Bedienelement nicht sichtbar ist. Wenn es ein Handle hat, sind Änderungen dennoch aufwändig.

Verwenden sie SetBounds anstelle von Left, Top, Width, Height

Anstelle von 

 with Button1 do begin
   Left:=10;
   Top:=10;
   Width:=100;
   Height:=25;
 end;

verwenden sie 

 with Button1 do begin
   SetBounds(10,10,100,25);
 end;

Left, Top, Width, Height rufen SetBounds auf. Und jede Änderung der Position oder Größe ruft die Neuberechnung aller sibling Bedienelemente und eventuell rekursiv die der parent und/oder der grandchild Bedienelemente auf.

DisableAlign / EnableAlign

Wenn sie viele Bedienelemente positionieren, ist es eine gute Idee, die Neuberechnungvon all auto sizing, aligning, anchoring zu deaktivieren. 

 DisableAlign;
 try
   ListBox1.Width:=ClientWidth div 3;
   ListBox2.Width:=ClientWidth div 3;
   ListBox3.Width:=ClientWidth div 3;
 finally
   EnableAlign;
 end;

Anmerkung: Jeder DisableAlign Aufruf benötigt einen EnableAlign Aufruf. Zum Beispiel wenn sie DisableAlign zweimal aufrufen, müssen sie auch EnableAlign zweimal aufrufen.

Für Delphianer: Dies funktioniert rekursiv. Das bedeutet, DisableAlign stoppt aligning in allen childs und grand childs.

Ein nicht-rechteckiges Fenster oder Steuerelement erstellen

Sie können mit Lazarus recht einfach nicht rechteckige Fenster oder Steuerelemente erstellen. Hierzu können Sie einfach TWinControl.SetShape aufrufen, mit den sichtbaren Bereichen als ein Parameter. Hinweis: dies funktioniert für Fenster und Steuerelemente, wie TCustomForm und TCustomControl, die von TWinControl abgeleitet sind. Sie können LCLIntf-Routine SetWindowRgn aufrufen, die vollständig dem Aufruf der SetShape-Methode entspricht.

Mit SetWindowRgn wird der Code wie folgt aussehen: 

uses LCLIntf, LCLType;

procedure TForm1.FormCreate(Sender: TObject);
var
  MyRegion: HRGN;
begin
  MyRegion := CreateRectRgn(0, 0, 100, 100);
  SetWindowRgn(Handle, MyRegion, True);
  DeleteObject(MyRegion);
end;

Nachfolg ein entsprechender Code, welcher ein, eine Ebene höheres, TRegion-Objekt verwendet, verfügbar in Lazarus 0.9.31+ (Hinweis: auch die vorherige Vorgehensweise wird in Zukunft weiterhin unterstützt werden): 

uses Graphics;

procedure TForm1.FormCreate(Sender: TObject);
var
  MyRegion: TRegion;
begin
  MyRegion := TRegion.Create;
  try
    MyRegion.AddRectangle(0, 0, 100, 100);
    Self.SetShape(MyRegion);
  finally
    MyRegion.Free;
  end;
end;

Ein Ergebnis dieses Vorgehens, bei einem Fenster auf einem Mac OS X, welches das Qt Widgetset genutzt hat, sehen Sie hier:

non rectangular window.png

Beachten Sie, dass SetShape auch ein TBitmap nutzen kann, um eine transparente Region zu beschreiben.

Siehe auch:

Dokumentationen:

Einschränkungen:

In Gtk2 kann eine Region erst festgelegt werden, nachdem ein Fenster erstellt wurde. SetWindowRgn im OnShow-Ereignishandler aufzurufen funktioniert nicht, die einzige Möglichkeit scheint der Einsatz eines Timers zu sein, der nach einem Intervall von 1 ms aufgerufen wird. Aktivieren Sie den Timer in Form.OnShow und deaktivieren Sie ihn im OnTimer-Handler.

Simulation von Maus- and Tastatureingaben

Sie können sehr einfach Maus- und Tastatureingaben mit der LCL simulieren. Nutzen Sie dazu einfach die Routinen aus der Unit LCLMessageGlue wie es alle Widgetset Schnittstellen tun. Diese Unit verfügt über Routinen wie: 

unit LCLMessageGlue;

function LCLSendMouseMoveMsg(const Target: TControl; XPos, YPos: smallint;
  ShiftState: TShiftState = []): PtrInt;
function LCLSendMouseDownMsg(const Target: TControl; XPos, YPos: smallint;
  Button: TMouseButton; ShiftState: TShiftState = []): PtrInt;
function LCLSendMouseUpMsg(const Target: TControl; XPos, YPos: smallint;
  Button: TMouseButton; ShiftState: TShiftState = []): PtrInt;
function LCLSendMouseWheelMsg(const Target: TControl; XPos, YPos, WheelDelta: smallint;
  ShiftState: TShiftState = []): PtrInt;
function LCLSendCaptureChangedMsg(const Target: TControl): PtrInt;
function LCLSendSelectionChangedMsg(const Target: TControl): PtrInt;
function LCLSendClickedMsg(const Target: TControl): PtrInt;
function LCLSendMouseEnterMsg(const Target: TControl): PtrInt;
function LCLSendMouseLeaveMsg(const Target: TControl): PtrInt;
...
function LCLSendKeyDownEvent(const Target: TControl; var CharCode: word;
  KeyData: PtrInt; BeforeEvent, IsSysKey: boolean): PtrInt;
function LCLSendKeyUpEvent(const Target: TControl; var CharCode: word;
  KeyData: PtrInt; BeforeEvent, IsSysKey: boolean): PtrInt;

Die virtuelle Tastatur auf Smartphones/Tablets zeigen

Um die virtuelle Tastatur anzuzeigen, wenn ein Steuerelement den Fokus erhält, können Sie einfach csRequiresKeyboardInput ControlStyle hinzufügen: 

constructor TMyTextEditor.Create(AOwner : TComponent);
begin
  inherited Create(AOwner);
  ControlStyle := ControlStyle + [csRequiresKeyboardInput];
...
end;

Virtual keyboard.png

Alle untergeordneten Controls von einem TWinControl durchlaufen

Dies ist sehr einfach zu realisieren. Benutzen Sie einfach eine Schleife. Der Index ist nullbasiert, TWinControl.ControlCount gibt die Anzahl an und TWinControl.Controls[Index] das entspechende Steuerelement. 

procedure TWinControl.WriteLayoutDebugReport(const Prefix: string);
var
  i: Integer;
begin
  inherited WriteLayoutDebugReport(Prefix);
  for i:=0 to ControlCount-1 do
    Controls[i].WriteLayoutDebugReport(Prefix+'  ');
end;
Retrieved from "http://wiki.freepascal.org/index.php?title=LCL_Tips/de&oldid=132573"