Understanding Interfaces/es

From Lazarus wiki

English (en) español (es)

La razón de las interfaces

Las clases que extienden otras clases pueden llamarse sub-clases o clases derivadas. Por ejemplo, podría extenderse la clase bicicleta para tener una sub-clase montañera, y una sub-clase paseo. Estas clases heredan muchas de las funciones comunes de la clase bicicleta, pero añaden opciones únicas como la baca para la de paseo. Puedes llamar métodos de bicicleta, sabiendo que se aplican generalmente a todos los tipos de bicicleta.

Este es un uso tradicional y estándar para las clases, dado que las sub-clases son solamente variaciones sobre un tema. Pero suponiendo que hubiera una aplicación donde existieran objetos de clase bicicleta, de automóviles, de lavacoches y otros, y en dicha aplicación se quisiera que cada clase tuviera el siguiente método:

function EsReciclable : Boolean;

Esto permitiría saber si el objeto contiene materiales reciclables. Se podría definir una clase de alto nivel que contuviera este método, y definir todas las clases derivadas de ella. O simplemente podrías agregar el método a cada sub-clase. O podrían usarse interfaces. Las interfaces simplemente pondrían orden en esta situación. Definiendo una interfaz que agrupe estos métodos juntos, establece una norma para todas las clases que implementen la interfaz. Hacen más fácil que el programador se discipline en desarrollar la aplicación; todas las clases tienen un conjunto de métodos que son idénticos y el compilador insiste que todos los métodos en una interfaz se implementen.

Regresando al escenario del objeto reciclable, cada sub-clase hereda funciones comunes de su clase padre en particular. Esto describe la estructura básica de la sub-clase. También hereda (por implementación) las funciones comunes que se extienden por todas las clases.


Ejemplo de interfaz

Como muchas ideas, un ejemplo es la mejor forma de ilustrar los conceptos. Lo haremos por etapas para que las cosas sean tan simples como sea posible. Primero, definamos una clase automóvil:

type
(* Definimos nuestra clase Automóvil. *)
  TAutomovil = class
  private
    fMarca: String;
    fEdad: Byte;
  public
  (* Constructor del Automóvil. *)
    constructor Create (aMarca: String);
  published
  (* Propiedades del Automóvil. *)
    property Marca: String read fMarca;
    property Edad: Byte read fEdad write fEdad;
  end;

Esta clase se define por defecto basado en TObject dado que no especificamos el tipo de clase base. Esta clase tiene dos propiedades, y un constructor, que se muestran aquí:

(* Constructor de la implementación para la clase Automóvil. *)
  constructor TAutomovil.Create (aMarca : String);
  begin
  (* Guarda el marca del automóvil y pone la edad por defecto. *)
    fMarca := aMarca;
    fEdad := 0
  end;

Aquí asignamos las dos propiedades del automóvil: su marca y edad. La marca se pasa como parámetro y asignamos una edad por defecto de 0. Ahora definiremos otra clase – una clase bicicleta:

type
(* Definimos nuestra clase Bicicleta. *)
  TBicicleta = class
  private
    fFemenina: Boolean;
    fEdad: Byte;
  public
  (* Constructor de la Bicicleta. *)
    constructor Create (aFemenina: Boolean; aEdad: Byte);
  published
  (* Propiedades de la Bicicleta. *)
    property esFemenina: Boolean read fFemenina;
    property Edad: Byte read fEdad write fEdad;
  end;

Esta clase tiene dos propiedades y un constructor como aquí se muestra:

(* Constructor de la implementación para la clase bicicleta. *)
  constructor TBicicleta.Create (aFemenina: Boolean; aEdad: Byte);
  begin
  (* Save the passed parameters. *)
    fFemenina := aFemenina;
    fEdad := aEdad
  end;

Esta clase es un poco distinta de la clase automóvil, lo suficiente para ver que podríamos no haber basado el automóvil en la bicicleta o la bicicleta en el automóvil. Ahora definiremos una interfaz que diga si un clase de objeto es reciclable:

  type
  (* Una definición de interfaz. *)
    IReciclable = Interface (IInterface)
    (* Una sola función que da soporte a la propiedad. *)
      function MaterialEsReciclable: Boolean;
    (* Una sola propiedad. *)
      property esReciclable: Boolean read MaterialEsReciclable;
    end;

Nuestra interfaz usa la definición estándar IInterface como base. Las definiciones de interfaces son como definiciones de clase con todos los elementos abstractos, así que no tenemos que declararlos como abstractos – lo son por defecto.

Esta interfaz añade una propiedad esReciclable a cada clase que la implemente. Para cada clase que la implemente se garantizará que tendrá exactamente la misma forma de preguntar si es reciclable. Este es el poder y el beneficio de las interfaces – uniformidad a través de clases potencialmente muy distintas.

Cualquier clase puede implementar tantas interfaces como se quiera – puede conformar cualquier estándar global en efecto. Nótese que debemos definir la propiedad usando una función – no podemos declarar un campo de datos Boolean en la interrfaz dado que las interfaces no contienen datos.

Ahora cambiemos nuestras clases para que den soporte a esta definición de interfaz:

  type
  (* Definimos nuestra clase Automóvil. *)
    TAutomovil = class (TInterfacedObject, IReciclable)
    private
      fMarca: String;
      fEdad: Byte;
      fEsReciclable: Boolean; { Añadido para dar soporte a IReciclable. }
      function MaterialEsReciclable: Boolean; { Añadido para IReciclable. }
    public
    (* Constructor del Automóvil. *)
      constructor Create (aMarca: String);
    published
    (* Propiedades del Automóvil. *)
      property Marca: String read fMarca;
      property Edad: Byte read fEdad write fEdad;
    (* Añadido para IReciclable. *)
      property esReciclable: Boolean read MaterialEsReciclable;
    end;

Nótese que pusimos la función usada por la propiedad de interfaz esReciclable en la sección privada (private) – queremos que la propiedad la use sólo quien la llame.

[Nota del autor: cuando se compila, el compilador insiste en la presencia de la función MaterialEsReciclable, pero no en la parte más importante – la propiedad. Así como lo puede ver el autor, esto no obliga la opción predominante de la interfaz – ¡la propiedad!]

Ahora hemos basado nuestra clase en la clase TInterfaceObject, la cual provee de algo de soporte estándar para las clases que implementan interfaces. Y hemos también basado nuestra clase en IReciclable, nuestra nueva interfaz.

Pero también debemos declarar la nueva función MaterialEsReciclable:

(* Función del automóvil requerida por el atributo EsReciclable. *)
  function TAutomovil.MaterialEsReciclable: Boolean;
  begin
    Result := fEsReciclable
  end;

Y no debemos olvidar asignar este valor reciclable. Lo haremos diréctamente aquí en el constructor:

(* Constructor para la clase automóvil. *)
  constructor TAutomovil.Create (aMarca: String);
  begin
  (* Guarda la marca del automóvil y asigna una edad por defecto. *)
    fMarca := aMarca;
    fEdad := 0;
    fEsReciclable := true { Asigna que es reciclable. }
  end;

¡Vaya! Pero debemos hacer lo mismo para la clase Bicicleta para mostrar el auténtico efecto. Veremos el código completo para definir y usar estas clases, las cuales puedes copiar y pegar en el Editor de Código:

unit Unit1;

{$mode objfpc}{$H+}

interface

  uses
    Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs;

  type
  (* Una definición de interfaz. *)
    IReciclable = Interface (IInterface)
    (* Una sola función que da soporte a la propiedad. *)
      function MaterialEsReciclable: Boolean;
    (* Una sola propiedad. *)
      property esReciclable: Boolean read MaterialEsReciclable;
    end;

  (* Definimos nuestra clase Automóvil. *)
    TAutomovil = class (TInterfacedObject, IReciclable)
    private
      fMarca: String;
      fEdad: Byte;
      fEsReciclable: Boolean; { Añadido para dar soporte a IReciclable. }
      function MaterialEsReciclable: Boolean; { Añadido para IReciclable. }
    public
    (* Constructor del Automóvil. *)
      constructor Create (aMarca: String);
    published
    (* Propiedades del Automóvil. *)
      property Marca: String read fMarca;
      property Edad: Byte read fEdad write fEdad;
    (* Añadido para IReciclable. *)
      property esReciclable: Boolean read MaterialEsReciclable;
    end;

  (* Definimos nuestra clase Bicicleta. *)
    TBicicleta = class (TInterfacedObject, IReciclable)
    private
      fFemenina: Boolean;
      fEdad: Byte;
      function MaterialEsReciclable: Boolean; { Añadido para IReciclable. }
    public
    (* Constructor de la Bicicleta. *)
      constructor Create (aFemenina: Boolean; aEdad: Byte);
    published
    (* Propiedades de la Bicicleta. *)
      property esFemenina: Boolean read fFemenina;
      property Edad: Byte read fEdad write fEdad;
    (* Añadido para IReciclable. *)
      property esReciclable: Boolean read MaterialEsReciclable;
    end;

{ TForm1 }
  TForm1 = class (TForm)
    procedure FormCreate (Sender: TObject);
  private 
    { private declarations }
  public
    { public declarations }
  end;

  var
    Form1: TForm1;

implementation

{$R *.frm}

{ TForm1 }

  procedure TForm1.FormCreate (Sender: TObject);
  var
    biciMama: TBicicleta;
    cochePapa: TAutomovil;
  begin
  { Instancia los objetos bicicleta y automóvil. }
    biciMama := TBicicleta.Create (true, 36);
    cochePapa := TAutomovil.Create ('Toyota Hilux');
  { Pregunta a cada si cada uno si es reciclable. }
    if cochePapa.esReciclable then
      ShowMessage ('El coche de papá es reciclable.')
    else
      ShowMessage ('El coche de papá no es reciclable.');
    if biciMama.esReciclable then
      ShowMessage ('La bici de mamá es reciclable.')
    else
      ShowMessage ('La bici de mamá no es reciclable.')
  end;



(* Constructor para la clase automóvil. *)
  constructor TAutomovil.Create (aMarca: String);
  begin
  (* Guarda la marca del automóvil y asigna una edad por defecto. *)
    fMarca := aMarca;
    fEdad := 0;
    fEsReciclable := true { Asigna que es reciclable. }
  end;

(* Función del Automóvil requerida para el atributo esReciclable. *)
  function TAutomovil.MaterialEsReciclable: Boolean;
  begin
    Result := fEsReciclable
  end;



(* Constructor de la implementación para la clase bicicleta. *)
  constructor TBicicleta.Create (aFemenina: Boolean; aEdad: Byte);
  begin
  (* Save the passed parameters. *)
    fFemenina := aFemenina;
    fEdad := aEdad
  end;

(* Función de la Bicicleta requerida para el atributo esReciclable. *)
  function TBicicleta.MaterialEsReciclable: Boolean;
  begin
  { Vamos a presuponer que sólo las bicibletas para hombre son reciclables. }
    Result := not self.esFemenina
  end;

end.

Al ejecutar... ShowMessage muestra lo siguiente:

El coche de papá es reciclable.
La bici de mamá no es reciclable.


Este post fue tomado de un artículo de internet que me pareció bien interesante para modificar y entender las interfaces. Siempre ha sido un tema tabú(?) preguntar y cuando se usan, puede darle más claridad a tu código.

Ver también