Difference between revisions of "Dialog Examples/es"

From Free Pascal wiki
Jump to navigationJump to search
Line 111: Line 111:
  
 
  [[Image:Lazarus_MessageDlg.png]]</center>
 
  [[Image:Lazarus_MessageDlg.png]]</center>
 +
 +
=== QuestionDlg ===
 +
Question dialog allows changing button captions and setting default and cancel buttons.
 +
Example:
 +
<syntaxhighlight>
 +
    case QuestionDlg ('Caption','Message',mtCustom,[mrYes,'Positive', mrNo, 'Negative', 'IsDefault'],'') of
 +
        mrYes: QuestionDlg ('Caption','So you mean „Yes“',mtCustom,[mrOK,'That is right'],'');
 +
        mrNo:  QuestionDlg ('Caption','Oh, you mean „No“',mtCustom,[mrOK,'Exactly'],'');
 +
        mrCancel: QuestionDlg ('Caption','You canceled the dialog with ESC or close button.',mtCustom,[mrOK,'Exactly'],'');
 +
    end;
 +
</syntaxhighlight>
 +
<center> [[image:QuestionDlg.png]]
 +
</center>
 +
 +
{{Note|If the user cancels the dialog and there is no 'IsCancel' button defined, mrCancel is returned! If you want to redirect ESC/close to a defined button use the 'IsCancel' parameter just after the cancel button.}}
 +
 +
Advanced examples for buttons (from promptdialog.inc)
 +
<syntaxhighlight>
 +
    [mrOk,mrCancel,'Cancel now',mrIgnore,300,'Do it','IsDefault']
 +
</syntaxhighlight>
 +
This will result in 4 buttons:
 +
* 'Ok' returning mrOk
 +
* 'Cancel now' returning mrCancel
 +
* 'Ignore' returning mrIgnore
 +
* 'Do it' returning 300. This will be the default button (focused)
 +
 +
Usually buttons in Lazarus dialogs have icons. In order to prevent icons from being shown non standardize values for message results can be used. Currently highest standardized value is 11. For example:
 +
 +
<syntaxhighlight>
 +
  case QuestionDlg ('Caption','Message',mtCustom,[20,'Positive', 21, 'Negative',22,'I do not know','IsCancel'],'') of
 +
    20: QuestionDlg ('Caption','So you mean „Yes“',mtCustom,[20,'That is right'],'');
 +
    21:  QuestionDlg ('Caption','Oh, you mean „No“',mtCustom,[21,'Exactly'],'');
 +
    22:  QuestionDlg ('Caption','So, please find out!',mtCustom,[22,'Maybe'],'');
 +
  end;
 +
</syntaxhighlight>
 +
In order to facilitate work, constants can be defined. For example:
 +
 +
<syntaxhighlight>
 +
const
 +
  mrNoneNI=      20;
 +
  mrOkNI=        mrNoneNI+1;
 +
  mrCancelNI=    mrNoneNI+2;
 +
  mrAbortNI=    mrNoneNI+3;
 +
  mrRetryNI=    mrNoneNI+4;
 +
  mrIgnoreNI=    mrNoneNI+5;
 +
  mrYesNI=      mrNoneNI+6;
 +
  mrNoNI=        mrNoneNI+7;
 +
  mrAllNI=      mrNoneNI+8;
 +
  mrYesToAllNI=  mrNoneNI+10;
 +
  mrCloseNI=    mrNoneNI+11;
 +
  mrLastNI=      mrCloseNI;
 +
begin
 +
  case QuestionDlg ('Caption','Message',mtCustom,[mrYesNI,'Positive', mrNoNI, 'Negative',mrCancelNI,'I do not know','IsCancel'],'') of
 +
    mrYesNI: QuestionDlg ('Caption','So you mean „Yes“',mtCustom,[mrYesNI,'That is right'],'');
 +
    mrNoNI:  QuestionDlg ('Caption','Oh, you mean „No“',mtCustom,[mrNoNI,'Exactly'],'');
 +
    mrCancelNI:  QuestionDlg ('Caption','So, please find out!',mtCustom,[mrCancelNI,'Maybe'],'');
 +
  end; //case
 +
end;
 +
</syntaxhighlight>
 +
<center> [[File:QuestionDlgNoButIcons.png]] </center>
  
 
== Diálogos de entrada de texto ==
 
== Diálogos de entrada de texto ==

Revision as of 20:31, 19 February 2016

Deutsch (de) English (en) español (es) suomi (fi) français (fr) 日本語 (ja) polski (pl) русский (ru) slovenčina (sk) 中文(中国大陆)‎ (zh_CN)

Algunos diálogos útiles

   Aquí tenemos algunos diálogos útiles, que no aparecen en la Paleta de Componentes:

   Cada uno de ellos da lugar a la aparición de una ventana emergente, que contiene cierta información y espera una respuesta del usuario: presionar un botón, introducir algún texto o ambas cosaa. Los programadores tienen poco control sobre el formato, tamaño o posición de estas ventanas, pero pueden cambiar su contenido textual.
   La razón de que haya varias alternativas es permitir diferentes métodos de crear la ventana y de recibir datos de respuesta para procesar en nuestro código.

Diálogos con mensaje

   Las ventanas de diálogo con mensaje muestran un mensaje y esperan que se salga de ellos mediante la pulsación de unos de los botones que muestran, o cerrando la ventano con cualquier otra opción disponible.

ShowMessage

 Procedure ShowMessage (const Msg: string);
{el procedimiento está definido en la unidad ''Dialogs.pp''}

   Es la ventana de diálogo más simple: recibe una cadena como parámetro, y la muestra en una ventana predefinida, con un botón (OK o Aceptar) y un icono de Información. El diálogo se muestra hasta que se cierra con alguna de las opciones posibles: pulsar el único botón o el aspa de la barra de título.
  La ventana del diálogo es modal, es decir, se muestra, toma el foco y no permite interacción con la aplicación que la originó.

Ejemplo:

 Program UnMensajeConLazarus;
  Uses Dialogs;
  var  mi_mensaje: string;
  begin
    mi_mensaje:= 'Este es un texto que se extiende a lo largo de'#13'de dos líneas';
    ShowMessage (mi_mensaje);
  end.

   (nota: cómo se puede ver en el ejemplo el const de la definición del procedimiento significa que no es necesaria una variable, aunque se puede utilizar una variable si lo queremos. Así mismo vemos que los mensajes los podemos dividir en las líneas que deseemos mediante #13, sLineBreak o LineEnding, esto lo podemos usar en todos los cuadros de los que hablamos aquí)

Lazarus ShowMessage.png

MessageBox

 Function Application.MessageBox (Mensaje, Titulo: PChar; Marcadores: longint) : Integer;

   Función definida en Forms.pp como parte de TApplication, de ahí que tengamos que usarla de esta forma: Application.Messagebox ( ); o bien utilizando la construcción 'With Application do ...'].

   Sus parámetros:

  • Mensaje: El texto del mensaje que queremos mostrar al usuario;
  • Titulo: El título de la ventana del cuadro de diálogo;
  • Marcadores: Un entero construido al sumar varias constantes (definidas en el módulo LCLType) que definen el icono y botones que mostrará el cuadro, por ejemplo MB_ABORTRETRYIGNORE + MB_ICONQUESTION hará que se muestre un signo de interrogación (?) y tres botones: Abortar, Reintentar e Ignorar.

   La función devuelve un valor entero que corresponde al botón que se presionó; su valor se puede determinar por referencia a las constantes [IDOK..IDHELP]

  Si no necesitamos el valor del botón pulsado la podemos invocar cómo un procedimiento, en Pascal no es obligatorio recoger el valor devuelto por una función - véase el ejemplo siguiente:

   Ejemplo:

 Uses Forms, Dialogs, LCLType;
 
 Procedure MuestraMessageBox;
  var resp, estilo: integer;
    texto: pchar;
 begin
   with application do
     begin
      estilo :=  MB_ABORTRETRYIGNORE + MB_ICONQUESTION;
      resp :=  MessageBox ('Pulsa un botón', 'Ejemplo de MessageBox', estilo); //recogemos el valor de la función
      case resp of
        IDABORT: texto := 'Abortar';
        IDRETRY: texto :=  'Reintentar';
        IDIGNORE: texto := 'Ignorar';
        else texto := 'Has cerrado el cuadro con el aspa: ';
      end; //case
      MessageBox (texto, 'Respuesta', MB_ICONHAND); // no recogemos el valor devuelto por MessageBox
     end; //with   
 end; //procedmiento
Lazarus MessageBox.png Lazarus MessageBoxRespuesta.png

http://lazarus-ccr.sourceforge.net/kbdata/MessageBoxDemo.png http://lazarus-ccr.sourceforge.net/kbdata/ReplyYes.png

MessageDlg

function MessageDlg(const aMsg:String; DlgType:TMsgDlgType; Buttons:TMsgDlgButtons; HelpCtx:LongInt):Integer;
function MessageDlg(const aCaption:String; const aMsg:String; DlgType:TMsgDlgType; 
                     Buttons:TMsgDlgButtons; HelpCtx:longInt):Integer;
function MessageDlg(const aCaption:String; const aMsg:String; DlgType:TMsgDlgType; 
                     Buttons:TMsgDlgButtons; HelpCtx:LongInt;  DefaultButton:TMsgDlgBtn):Integer;
function MessageDlg(const aCaption:String; const aMsg:String; DlgType:TMsgDlgType; 
                    Buttons:TMsgDlgButtons; const HelpKeyword: String):Integer;
Ver Tipos de mensaje(TMsgDlgType), Botones(TMsgDlgButtons) Botones(TMsgDlgBtn) Las dos clase de botones definen exactamente lo mismo¿¡!?)

   Hay cuatro versiones de esta función, en la primera al omitir el título, se pondrá cómo título el identificador de la aplicación; en las demás podemos poner como título de la ventana el texto que nos convenga. En la tercera podemos especificar mediante el parámetro DefaultButton qué botón será el activo por defecto. En la cuarta podemos mostrar la ayuda especificada en HelpKeyword.

   Es el más completo y elaborado de las ventanas de diálogo, y permite al programador un considerable control sobre su aspecto.

   Los parámetros que definen el tipo de cuadro y el icono es un tipo enumerado, y los botones se pueden especificar como un conjunto entre corchetes, por ejemplo [mbRetry, mbIgnore, mbAbort, mbCancel].

   HelpCtx se utiliza para especificar qué tema del archivo de ayuda debe ser demostrado, o cero para no mostrar nínguno. Si se utiliza HelpKeyword se mostrará la ayuda de esa palabra.

   El valor devuelto por la función corresponde al botón presionado, expresado como un entero (ver más edelante las definiciones de [mrNone..mrAll]).

Ejemplo:
 Uses forms, dialogs, lcltype, controls;
 
 procedure EstoSiQueEsUnMensaje;
   var  tipo: TMsgDlgType;
        botones: TMsgDlgButtons;
   begin
    tipo := mtWarning;
    botones:= [mbYesToAll, mbNoToAll];
    MessageDlg ('Cosas para no olvidar', 'las personas son las que dan sentido,'#13+
                              'coherencia y lógica a las cosas', tipo, botones,0);
   end;
http://lazarus-ccr.sourceforge.net/kbdata/Question.png
Lazarus MessageDlg.png

QuestionDlg

Question dialog allows changing button captions and setting default and cancel buttons. Example:

    case QuestionDlg ('Caption','Message',mtCustom,[mrYes,'Positive', mrNo, 'Negative', 'IsDefault'],'') of
        mrYes: QuestionDlg ('Caption','So you mean „Yes“',mtCustom,[mrOK,'That is right'],'');
        mrNo:  QuestionDlg ('Caption','Oh, you mean „No“',mtCustom,[mrOK,'Exactly'],'');
        mrCancel: QuestionDlg ('Caption','You canceled the dialog with ESC or close button.',mtCustom,[mrOK,'Exactly'],'');
    end;
QuestionDlg.png
Light bulb  Nota: If the user cancels the dialog and there is no 'IsCancel' button defined, mrCancel is returned! If you want to redirect ESC/close to a defined button use the 'IsCancel' parameter just after the cancel button.

Advanced examples for buttons (from promptdialog.inc)

    [mrOk,mrCancel,'Cancel now',mrIgnore,300,'Do it','IsDefault']

This will result in 4 buttons:

  • 'Ok' returning mrOk
  • 'Cancel now' returning mrCancel
  • 'Ignore' returning mrIgnore
  • 'Do it' returning 300. This will be the default button (focused)

Usually buttons in Lazarus dialogs have icons. In order to prevent icons from being shown non standardize values for message results can be used. Currently highest standardized value is 11. For example:

  case QuestionDlg ('Caption','Message',mtCustom,[20,'Positive', 21, 'Negative',22,'I do not know','IsCancel'],'') of
     20: QuestionDlg ('Caption','So you mean „Yes“',mtCustom,[20,'That is right'],'');
     21:  QuestionDlg ('Caption','Oh, you mean „No“',mtCustom,[21,'Exactly'],'');
     22:  QuestionDlg ('Caption','So, please find out!',mtCustom,[22,'Maybe'],'');
  end;

In order to facilitate work, constants can be defined. For example:

const
  mrNoneNI=      20;
  mrOkNI=        mrNoneNI+1;
  mrCancelNI=    mrNoneNI+2;
  mrAbortNI=     mrNoneNI+3;
  mrRetryNI=     mrNoneNI+4;
  mrIgnoreNI=    mrNoneNI+5;
  mrYesNI=       mrNoneNI+6;
  mrNoNI=        mrNoneNI+7;
  mrAllNI=       mrNoneNI+8;
  mrYesToAllNI=  mrNoneNI+10;
  mrCloseNI=     mrNoneNI+11;
  mrLastNI=      mrCloseNI; 
begin
  case QuestionDlg ('Caption','Message',mtCustom,[mrYesNI,'Positive', mrNoNI, 'Negative',mrCancelNI,'I do not know','IsCancel'],'') of
    mrYesNI: QuestionDlg ('Caption','So you mean „Yes“',mtCustom,[mrYesNI,'That is right'],'');
    mrNoNI:  QuestionDlg ('Caption','Oh, you mean „No“',mtCustom,[mrNoNI,'Exactly'],'');
    mrCancelNI:  QuestionDlg ('Caption','So, please find out!',mtCustom,[mrCancelNI,'Maybe'],'');
  end; //case
end;
QuestionDlgNoButIcons.png

Diálogos de entrada de texto

InputBox

   Junto con el mensaje muestra una caja de edición para que el usuario pueda escribir un texto que será pasado a la aplicación.

 Function InputBox(const ATitulo, ACursor, ADefecto : String) : String;

   Se puede especificar el título de la Ventana (ATitulo), el mensaje que indicará al usuario que tipo de entrada de texto se espera que realice (ACursor) e incluso un texto ya predefinido (ADefecto). El texto escrito por el usuario o el proporcionado es devuelto a la aplicación como resultado de la función. La vnta muestr loa botones mbOK y mbCancel)

   Ejemplo:

 Uses forms, lcltype, dialogs, controls;
 
 procedure VentanaEntradaTexto;
   var textoUsuario: string;
  begin
    textoUsuario := InputBox ('Introducción de texto por el usuario',
                             'Por favor, escribe algo aquí:', 
                             'Si no quieres escribir, este es el texto que se devolverá');
    ShowMessage (textoUsuario);
  end
Lazarus InputBox.png

   (nota: ojo con esta ventana, el texto de ACursor tiene un límite de longitud visible, ya que la ventana tiene un ancho y un alto limitado y fijo, y muestrará el texto en una única línea -al menos a día de hoy-)

InputQuery

 Function InputQuery(const ATitulo, ACursor : String; Enmascarar : Boolean; var TextoUsuario : String) : Boolean;
 Function InputQuery(const ATitulo, ACursor : String; var TextoUsuario : String) : Boolean;

   La función InputQuery, que como InputBox, permite al usuario introducir texto, tiene dos versiones; en la primera se utiliza el parámetro Enmascarar que indica si el texto que escribe el usuario se sustituye por asteriscos (valor true) o no (false), como para escribir una contraseña; en la segunda se omite este parámetro, lo que equivale a darle el valor false. El texto introducido por el usuario se devuelve en el parámetro TextoUsuario (por eso es variable); la función devuelve true si se presionó el botón Aceptar, o falso si se cerró la ventana de cualquier otra forma (por ejemplo, pulsando el icono 'X' de la barra de título).

   Ejemplo:

 Uses forms, lcltype, dialogs, controls;
 
 procedure TryInputQuery;
   var respuesta: boolean;
       TextoUsuario: string;
  begin
     respuesta := InputQuery ('Una cuestión de geografía', '¿Capital de Nicaragua?', true, TextoUsuario);
     if respuesta {= true} and (TextoUsuario = 'Managua') then
       ShowMessage ('Efectivamente ' + TextoUsuario + ' es la capital de Nicaragua')
     else
       begin
         InputQuery ('Prueba de nuevo', 'No has pulsado ''OK'' o tu respuesta (' + TextoUsuario
                                                      + ') no es la capital de Nicaragua', TextoUsuario);
         ShowMessage (' Tu respuesta ha sido: ' + TextoUsuario);
      end;
  end;
Lazarus InputQuery.png      Lazarus InputQueryNoMascara.png

   Nota: en la segunda imagen apreciamos que InputQuery padece el mismo defecto que InputBox respecto del texto que puede mostrar por la limitación de las dimensiones de la ventana. En Linux, con Lazarus 0.09.30-0 y FPC 2.4.2 este defecto no aparece y la ventana se expande; además se pueden crear nuevas líneas con #13)

InputQuery ES Linux LAZ 0.9.30-0 FPC-2.4.2.png
http://lazarus-ccr.sourceforge.net/kbdata/MessageDlgQuestion.png
http://lazarus-ccr.sourceforge.net/kbdata/DontBeSillly.png

PasswordBox

 Function PasswordBox(const ACaption, APrompt : String) : String;

   Su comportamiento es parecido a InputBox, consistiendo las diferencias en que no hay texto por defecto y el texto que el usuario escribe se enmascara.

   Constantes y tipos importantes que se utilizan en estos diálogos y que están predefinidas en la biblioteca LCL:

   Constantes enteras para definir tipos de botones e iconos que se muestran en MessageBox, definidos en la unidad LCLType.pp:

 //Botones
 MB_OK = $00000000;
 MB_OKCANCEL = $00000001;
 MB_ABORTRETRYIGNORE = $00000002;
 MB_YESNOCANCEL = $00000003;
 MB_YESNO = $00000004;
 MB_RETRYCANCEL = $00000005;
 //Iconos
 MB_ICONHAND = $00000010;
 MB_ICONQUESTION = $00000020;
 MB_ICONEXCLAMATION = $00000030;
 MB_ICONASTERICK = $00000040;
 MB_ICONWARNING = MB_ICONEXCLAMATION;
 MB_ICONERROR = MB_ICONHAND;
 MB_ICONINFORMATION = MB_ICONASTERICK;

   Constantes enteras que definen el valor devuelto desde MessageBox según el botón que se presione:

 IDOK = 1; 	ID_OK = IDOK;
 IDCANCEL = 2;	ID_CANCEL = IDCANCEL;
 IDABORT = 3;	ID_ABORT = IDABORT;
 IDRETRY = 4;	ID_RETRY = IDRETRY;
 IDIGNORE = 5;	ID_IGNORE = IDIGNORE;
 IDYES = 6;	ID_YES = IDYES;
 IDNO = 7;	ID_NO = IDNO;
 IDCLOSE = 8;	ID_CLOSE = IDCLOSE;
 IDHELP = 9;	ID_HELP = IDHELP;

   Definen si el botón por omisión es el primero, el segundo o el tercero:

 MB_DEFBUTTON1 = $00000000;
 MB_DEFBUTTON2 = $00000100;
 MB_DEFBUTTON3 = $00000200;
 MB_DEFBUTTON4 = $00000300;

   El valor del parámetro Marcadores de MessageBox se forma al añadir una constante botón [MB_OK..MB_RETRYCANCEL], una constante icono [MB_ICONHAND..MB_ICONINFORMATION] y una constante opcional, de botón por defecto [MB_DEFBUTTON1..MB_DEFBUTTON3]

   Los tipos que se utilizan en MessageDlg, los cuales necesitan parámetros AType de TMsgDlgType y AButtons de TMSgDlgButtons:

 { Definido en Dialogs.pp }
 type
  TMsgDlgType = (mtWarning, mtError, mtInformation,  mtConfirmation, mtCustom);
  TMsgDlgBtn = (mbYes, mbNo, mbOK, mbCancel, mbAbort, mbRetry, mbIgnore, mbAll, mbNoToAll, mbYesToAll, mbHelp, mbClose);
  TMsgDlgButtons = set of TMsgDlgBtn;
  
 const
  mbYesNoCancel = [mbYes, mbNo, mbCancel];
  mbOKCancel = [mbOK, mbCancel];
  mbAbortRetryIgnore = [mbAbort, mbRetry, mbIgnore];
  
  MsgDlgBtnToBitBtnKind: array[TMsgDlgBtn] of TBitBtnKind = (bkYes, bkNo, bkOK, bkCancel, bkAbort, bkRetry,
                                                             bkIgnore, bkAll, bkNoToAll, bkYesToAll, bkHelp, bkClose);
 
  BitBtnKindToMsgDlgBtn: array[TBitBtnKind] of TMsgDlgBtn = (mbOk, mbOK, mbCancel, mbHelp, mbYes, mbNo, mbClose,
                                                             mbAbort, mbRetry, mbIgnore, mbAll, mbNoToALl, mbYesToAll);
 
 { Definido en Controls.pp }
 const
  mrNone = 0;
  mrOK = mrNone + 1;
  mrCancel = mrNone + 2;
  mrAbort = mrNone + 3;
  mrRetry = mrNone + 4;
  mrIgnore = mrNone + 5;
  mrYes = mrNone + 6;
  mrNo = mrNone + 7;
  mrAll = mrNone + 8;
  mrNoToAll = mrNone + 9;
  mrYesToAll = mrNone + 10;
  mrLast = mrYesToAll;

   Sobre las ventanas de diálogo: Referencia de la unidad Dialogs: Procedimientos y funciones

Créditos

   Traducción original por Mgsalvador

   Reescritura, formato más legible, estampas y ejemplos más ilustrativos. Iskraelectrica. 2008/06/14

    La versión original de esta página se importó desde el epikwiki version.