Executing External Programs

From Free Pascal wiki
Revision as of 09:54, 3 October 2011 by Marcov (talk | contribs) (→‎SysUtils.ExecuteProcess: kill createprocess link. It is platform dependent, and not recommended unless TProcess doesn't cut it.)
Jump to navigationJump to search

Deutsch (de) English (en) español (es) français (fr) italiano (it) 日本語 (ja) Nederlands (nl) polski (pl) português (pt) русский (ru) slovenčina (sk) 中文(中国大陆)‎ (zh_CN)

Introduction

There are multiple ways to run an external program, but this article will only focus on one: TProcess.

If you always use ShellExecute and/or WinExec in Delphi, then you can begin to use TProcess as an alternative in FPC/Lazarus (this is valid too if you are running Lazarus in Linux, because TProcess is cross-platform).

Note: FPC/Lazarus has support for ShellExecute and/or WinExec, but this support is only in Win32. If your program is cross-platform, then use TProcess, it is the best way!

SysUtils.ExecuteProcess

The simplest way if you don't need pipes or any form of control is to simply use

<delphi>SysUtils.ExecuteProcess( UTF8ToSys( '/full/path/to/binary'), '' , []);</delphi>

For simplicity's sake, the calling process runs synchronously: it 'hangs'. For more complex forms, see the next section about TProcess.

TProcess

You can use TProcess to launch external programs. Some of the benefits of using TProcess are that it is:

  • Platform Independent
  • Capable of reading from stdout and writing to stdin.
  • Possible wait for a command to finish or let it run while your program moves on.

Note: TProcess is not a terminal/shell! You cannot directly execute scripts or redirect output using operators like "|", ">", "<", "&" etc. It is possible to obtain the same results with TProcess using pascal, some examples are below..

Important: You must specify the full path to the executable. For example '/bin/cp' instead of 'cp'. If the program is in the standard PATH then you can use the function FindDefaultExecutablePath from the FileUtil unit of the LCL.

A Simple Example

<delphi>// This is a demo program that shows how to launch // an external program. program launchprogram;

// Here we include files that have useful functions // and procedures we will need. uses

 Classes, SysUtils, Process;

// This is defining the var "AProcess" as a variable // of the type "TProcess" var

 AProcess: TProcess;

// This is where our program starts to run begin

 // Now we will create the TProcess object, and
 // assign it to the var AProcess.
 AProcess := TProcess.Create(nil);

 // Tell the new AProcess what the command to execute is.
 // Let's use the FreePascal compiler
 AProcess.CommandLine := 'ppc386 -h';

 // We will define an option for when the program
 // is run. This option will make sure that our program
 // does not continue until the program we will launch
 // has stopped running.                vvvvvvvvvvvvvv
 AProcess.Options := AProcess.Options + [poWaitOnExit];

 // Now that AProcess knows what the commandline is 
 // we will run it.
 AProcess.Execute;

 // This is not reached until ppc386 stops running.
 AProcess.Free;   

end.</delphi>

That's it! You have just learned how to run an external program from inside your own program.

An Improved Example

That's nice, but how do I read the Output of a program that I have run?

Well, let's expand our example a little and do just that:

<delphi>// This is a demo program that shows how to launch // an external program and read from it's output. program launchprogram;

// Here we include files that have useful functions // and procedures we will need. uses

 Classes, SysUtils, Process;

// This is defining the var "AProcess" as a variable // of the type "TProcess" // Also now we are adding a TStringList to store the // data read from the programs output. var

 AProcess: TProcess;
 AStringList: TStringList;

// This is where our program starts to run begin

 // Now we will create the TProcess object, and
 // assign it to the var AProcess.
 AProcess := TProcess.Create(nil);

 // Create the TStringList object.
 AStringList := TStringList.Create;

 // Tell the new AProcess what the command to execute is.
 // Let's use the FreePascal compiler
 AProcess.CommandLine := 'ppc386 -h';

 // We will define an option for when the program
 // is run. This option will make sure that our program
 // does not continue until the program we will launch
 // has stopped running. Also now we will tell it that
 // we want to read the output of the file.
 AProcess.Options := AProcess.Options + [poWaitOnExit, poUsePipes];

 // Now that AProcess knows what the commandline is 
 // we will run it.
 AProcess.Execute;
 
 // This is not reached until ppc386 stops running.

 // Now read the output of the program we just ran
 // into the TStringList.
 AStringList.LoadFromStream(AProcess.Output);
  
 // Save the output to a file.
 AStringList.SaveToFile('output.txt');

 // Now that the file is saved we can free the 
 // TStringList and the TProcess.
 AStringList.Free;
 AProcess.Free;   

end.</delphi>

Reading large output

In the previous example we waited until the program exited. Then we read, what the program has written to its output. But suppose the program writes a lot of data to the output, the pipe becomes full and the called progam waits until the pipe has been read from. But the calling program doesn't read from it until the called program has ended. A dead lock occurs.

The following example therefore doesn't use poWaitOnExit, but reads from the output, while the program is still running. The output is stored in a memory stream, that can be used later to read the output into a TStringList.

<delphi>program procoutlarge; {

   Copyright (c) 2004 by Marc Weustink
   This example is created in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

}

uses

 Classes, Process, SysUtils;

const

 READ_BYTES = 2048;
  

var

 S: TStringList;
 M: TMemoryStream;
 P: TProcess;
 n: LongInt;
 BytesRead: LongInt;

begin

 // We cannot use poWaitOnExit here since we don't
 // know the size of the output. On Linux the size of the
 // output pipe is 2 kB. If the output data is more, we 
 // need to read the data. This isn't possible since we are 
 // waiting. So we get a deadlock here.
 //
 // A temp Memorystream is used to buffer the output
 
 M := TMemoryStream.Create;
 BytesRead := 0;

 P := TProcess.Create(nil);
 P.CommandLine := 'ppc386 -va bogus.pp';
 P.Options := [poUsePipes];
 WriteLn('-- executing --');
 P.Execute;
 while P.Running do
 begin          
   // make sure we have room
   M.SetSize(BytesRead + READ_BYTES);
    
   // try reading it
   n := P.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
   if n > 0 
   then begin
     Inc(BytesRead, n);
     Write('.')
   end
   else begin     
     // no data, wait 100 ms
     Sleep(100); 
   end;
 end;
 // read last part
 repeat
   // make sure we have room
   M.SetSize(BytesRead + READ_BYTES);
   // try reading it
   n := P.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
   if n > 0 
   then begin
     Inc(BytesRead, n);
     Write('.');
   end;
 until n <= 0;
 if BytesRead > 0 then WriteLn;
 M.SetSize(BytesRead); 
 WriteLn('-- executed --');
  
 S := TStringList.Create;
 S.LoadFromStream(M);
 WriteLn('-- linecount = ', S.Count, ' --');
 for n := 0 to S.Count - 1 do
 begin
   WriteLn('| ', S[n]);
 end;
 WriteLn('-- end --');
 S.Free;
 P.Free;
 M.Free;

end.</delphi>

Using input and output of a TProcess

See processdemo example in the Lazarus-CCR SVN.

Hints on the use of TProcess

If you are creating a cross-platform program, you can change commandline according to the OS, using directives "{$IFDEF}s" and "{$ENDIF}s".

Example: <delphi>{...} AProcess:=TProcess.Create(nil) {$IFDEF WIN32} AProcess.CommandLine := 'calc.exe'; //Windows Calc {$ENDIF} {$IFDEF LINUX} AProcess.CommandLine := 'kcalc'; //KDE Calc {$ENDIF} AProcess.Execute; //in alternative, you can use AProcess.Active:=True {...}</delphi>

Example of "talking" with aspell process

Inside pasdoc source code you can find two units that perform spell-checking by "talking" with running aspell process through pipes:

  • PasDoc_ProcessLineTalk.pas unit implements TProcessLineTalk class, descendant of TProcess, that can be easily used to talk with any process on a line-by-line basis.
  • PasDoc_Aspell.pas units implements TAspellProcess class, that performs spell-checking by using underlying TProcessLineTalk instance to execute aspell and communicate with running aspell process.

Both units are rather independent from the rest of pasdoc sources, so they may serve as real-world examples of using TProcess to run and communicate through pipes with other program.

Replacing shell operators like "| < >"

Sometimes you want to run a more complicated command that pipes it's data to another command or to a file. Something like <delphi>ShellExecute('firstcommand.exe | secondcommand.exe');</delphi> or <delphi>ShellExecute('dir > output.txt');</delphi>

Executing this with TProcess will not work. i.e:

<delphi>// this won't work Process.CommandLine := 'firstcommand.exe | secondcommand.exe'; Process.Execute;</delphi>

Why using special operators to redirect output doesn't work

TProcess is just that, it's not a shell environment, only a process. It's not two processes, it's only one. It is possible to redirect output however just the way you wanted. See the next section.

How to redirect output with TProcess

You can redirect the output of a command to another command by using a TProcess instance for each command.

Here's an example that explains how to redirect the output of one process to another. To redirect the output of a process to a file/stream see the example Reading Large Output

Not only can you redirect the "normal" output (also known as stdout), but you can also redirect the error output (stderr), if you specify the poStderrToOutPut option, as seen in the options for the second process.

<delphi>program Project1;

uses

 Classes, sysutils, process;
 

var

 FirstProcess,
 SecondProcess: TProcess;
 Buffer: array[0..127] of char;
 ReadCount: Integer;
 ReadSize: Integer;

begin

 FirstProcess  := TProcess.Create(nil);
 SecondProcess := TProcess.Create(nil);

 FirstProcess.Options  := [poUsePipes];
 SecondProcess.Options := [poUsePipes,poStderrToOutPut];
 
 FirstProcess.CommandLine  := 'pwd';
 SecondProcess.CommandLine := 'grep '+ DirectorySeparator+ ' -';    
 // this would be the same as "pwd | grep / -"
 
 FirstProcess.Execute;
 SecondProcess.Execute;
 
 while FirstProcess.Running or (FirstProcess.Output.NumBytesAvailable > 0) do
 begin
   if FirstProcess.Output.NumBytesAvailable > 0 then
   begin
     // make sure that we don't read more data than we have allocated
     // in the buffer
     ReadSize := FirstProcess.Output.NumBytesAvailable;
     if ReadSize > SizeOf(Buffer) then
       ReadSize := SizeOf(Buffer);
     // now read the output into the buffer
     ReadCount := FirstProcess.Output.Read(Buffer[0], ReadSize);
     // and write the buffer to the second process
     SecondProcess.Input.Write(Buffer[0], ReadCount);
 
     // if SecondProcess writes much data to it's Output then 
     // we should read that data here to prevent a deadlock
     // see the previous example "Reading Large Output"
   end;
 end;
 // Close the input on the SecondProcess
 // so it finishes processing it's data
 SecondProcess.CloseInput;

 // and wait for it to complete
 // be carefull what command you run because it may not exit when
 // it's input is closed and the following line may loop forever
 while SecondProcess.Running do
   Sleep(1);
 // that's it! the rest of the program is just so the example
 // is a little 'useful'
 // we will reuse Buffer to output the SecondProcess's
 // output to *this* programs stdout
 WriteLn('Grep output Start:');
 ReadSize := SecondProcess.Output.NumBytesAvailable;
 if ReadSize > SizeOf(Buffer) then
   ReadSize := SizeOf(Buffer);
 if ReadSize > 0 then
 begin
   ReadCount := SecondProcess.Output.Read(Buffer, ReadSize);
   WriteLn(Copy(Buffer,0, ReadCount));
 end
 else
   WriteLn('grep did not find what we searched for. ', SecondProcess.ExitStatus);
 WriteLn('Grep output Finish:');
 
 // free our process objects
 FirstProcess.Free;
 SecondProcess.Free;

end.</delphi>

That's it. Now you can redirect output from one program to another.

Notes

This example may seem overdone since it's possible to run "complicated" commands using a shell with TProcess like: <delphi>Process.Commandline := 'sh -c "pwd | grep / -"';</delphi>

But our example is more crossplatform since it needs no modification to run on Windows or Linux etc. "sh" may or may not exist on your platform and is generally only available on *nix platforms. Also we have more flexibility in our example since you can read and write from/to the input, output and stderr of each process individually, which could be very advantageous for your project.

Redirecting input and output and running under root

A common problem on Unixes (OSX) and Linux is that you want to execute some program under the root account (or, more generally, another user account). If you can use sudo for this, you could adapt the following example adapted from one posted by andyman on the forum ([[1]]). This sample runs ls on the /root directory, but can of course be adapted.

Large parts of this code are similar to the earlier example, but it also shows how to redirect stdout and stderr of the process being called separately to stdout and stderr of our own code.

<delphi> program rootls;

{ Demonstrates using TProcess, redirecting stdout/stderr to our stdout/stderr, calling sudo on Linux/OSX, and supplying input on stdin} {$mode objfpc}{$H+}

uses

 Classes,
 Math, {for min}
 Process;
 procedure RunsLsRoot;
 var
   Proc: TProcess;
   CharBuffer: array [0..511] of char;
   ReadCount: integer;
   ExitCode: integer;
   SudoPassword: string;
 begin
   WriteLn('Please enter the sudo password:');
   Readln(SudoPassword);
   ExitCode := -1; //Start out with failure, let's see later if it works
   Proc := TProcess.Create(nil); //Create a new process
   try
     Proc.Options := [poUsePipes]; //Use pipes to redirect program stdin,stdout,stderr
     Proc.CommandLine := 'sudo -S ls /root'; //Run ls /root as root using sudo
     // -S causes sudo to read the password from stdin.
     Proc.Execute; //start it. sudo will now probably ask for a password
     // write the password to stdin of the sudo program:
     SudoPassword := SudoPassword + LineEnding;
     Proc.Input.Write(SudoPassword[1], Length(SudoPassword));
     SudoPassword := 'password'; //hope this will scramble memory
     SudoPassword := ; // and make the program a bit safer from snooping?!?
     // main loop to read output from stdout and stderr of sudo
     while Proc.Running or (Proc.Output.NumBytesAvailable > 0) or
       (Proc.Stderr.NumBytesAvailable > 0) do
     begin
       // read stdout and write to our stdout
       while Proc.Output.NumBytesAvailable > 0 do
       begin
         ReadCount := Min(512, Proc.Output.NumBytesAvailable); //Read up to buffer, not more
         Proc.Output.Read(CharBuffer, ReadCount);
         Write(StdOut, Copy(CharBuffer, 0, ReadCount));
       end;
       // read stderr and write to our stderr
       while Proc.Stderr.NumBytesAvailable > 0 do
       begin
         ReadCount := Min(512, Proc.Stderr.NumBytesAvailable); //Read up to buffer, not more
         Proc.Stderr.Read(CharBuffer, ReadCount);
         Write(StdErr, Copy(CharBuffer, 0, ReadCount));
       end;
     end;
     ExitCode := Proc.ExitStatus;
   finally
     Proc.Free;
     Halt(ExitCode);
   end;
 end;

begin

 RunsLsRoot;

end.


</delphi>

Other thoughts: It would no doubt be advisable to see if sudo actually prompts for a password. This can be checked consistently by setting the environment variable SUDO_PROMPT to something we watch for while reading the stdout of TProcess avoiding the problem of the prompt being different for different locales. Setting an environment variable causes the default values to be cleared(inherited from our process) so we have to copy the environment from our program if needed.

Parameters which contain spaces (Replacing Shell Quotes)

In the Linux shell it is possible to write quoted arguments like this:

gdb --batch --eval-command="info symbol 0x0000DDDD" myprogram

And GDB will receive 3 arguments (in addition to the first argument which is the full path to the executable):

  1. --batch
  2. --eval-command=info symbol 0x0000DDDD
  3. the full path to myprogram

TProcess and also pass parameters containing spaces, but it uses a different quoting style. Instead of only quoting part of the parameter, quote all of it. Like this:

TProcess.CommandLine := '/usr/bin/gdb --batch "--eval-command=info symbol 0x0000DDDD" /home/me/myprogram';

And also remember to only pass full paths.

See also this discussion about it: http://bugs.freepascal.org/view.php?id=14446

See also