Difference between revisions of "Executing External Programs/es"

From Free Pascal wiki
Jump to navigationJump to search
Line 56: Line 56:
 
   Bien, vamos a ampliar un poco nuestro ejemplo mediante lo siguiente:
 
   Bien, vamos a ampliar un poco nuestro ejemplo mediante lo siguiente:
  
<delphi> program launchprogram;
+
<delphi> program lanzarprograma2;
 
   
 
   
 
  uses  
 
  uses  

Revision as of 12:57, 21 July 2008

Deutsch (de) English (en) español (es) français (fr) italiano (it) 日本語 (ja) Nederlands (nl) polski (pl) português (pt) русский (ru) slovenčina (sk) 中文(中国大陆)‎ (zh_CN)

Introducción

   Hay varias formas de ejecutar programas externos, pero nos centraremos en una, TProcess.

Si en Delphi utilizabas siempre ShellExecute y/o WinExec, puedes empezar a usar TProcess como alternativa en FPC/Lazarus (es válido también si estás ejecutando Lazarus en Linux, porque TProcess es multiplataforma).

   Nota: FPC/Lazarus puede utilizar ShellExecute y/o WinExec, pero sólo en Win32. Si tu programa está enfocado a varias plataformas, utiliza TProcess, ¡es mejor!.

TProcess

   Puedes utilizar TProcess para ejecutar programas externos. Algunas de sus ventajas son:

  • Independiente de la plataforma
  • Capaz de leer desde la entrada estándar (stdout) y de escribir en la salida estándar (stdin).

Un ejemplo sencillo

<delphi> // Este es un programa de demostración que enseña como lanzar

// un programa externo.
program lanzarprograma;

uses 
  Classes, SysUtils, Process;

// Definición de "UnProceso" como una variable 
// de tipo "TProcess"
var 
  UnProceso: TProcess;
begin
  // Ahora creamos UnProceso.
  UnProceso := TProcess.Create(nil);

  // Asignamos a UnProceso la orden que debe ejecutar.
  // Vamos a lanzar el compilador de FreePascal 
  UnProceso.CommandLine := 'ppc386 -h';

  // Definimos una opción de comportamiento de 'TProccess'
  // Esta opción hará que nuestro programa
  // se detenga hasta que termine el programa lanzado
  //                                       vvvvvvvvvvvvvv
  UnProceso.Options := UnProceso.Options + [poWaitOnExit];

  // Lanzamos la ejecución de 'ppc386 -h'.
  UnProceso.Execute;

  // Nuestro progama se detiene hasta que 'ppc386' finaliza.
  UnProceso.Free;   
end.</delphi>

   ¡Eso es todo! Acabas de aprender cómo se ejecuta un programa externo desde dentro de tu propio programa.

Un ejemplo mejorado

   De acuerdo, pero ¿cómo leo la salida que produce un programa que he ejecutado?

   Bien, vamos a ampliar un poco nuestro ejemplo mediante lo siguiente:

<delphi> program lanzarprograma2;

uses 
  Classes, SysUtils, Process;

// Definición de "UnProceso" como una variable de tipo "TProcess"
// También añadimos un TStringList para almacenar los datos 
// leídos desde la salida del programa.
var 
  UnProceso: TProcess;
  UnaLista: TStringList;

// Aquí comienza a ejecutarse nuestro programa.
begin

  // Creamos el objeto TStringList.
  UnaLista := TStringList.Create;

  // Ahora creamos UnProceso.
  UnProceso := TProcess.Create(nil);

  // Asignamos a UnProceso la orden que debe ejecutar.
  // Vamos a lanzazar el compilador de FreePascal 
  UnProceso.CommandLine := 'ppc386 -h';

  // Definimos una opción de comportamiento de 'TProccess'
  // Esta opción hará que nuestro programa
  // se detenga hasta que termine el programa lanzado
  //                                       vvvvvvvvvvvvvv
  UnProceso.Options := UnProceso.Options + [poWaitOnExit, poUsePipes];
  // con esta                                             ^^^^^^^^^^
  // haremos que se cpature la salida para poder recuperar su
  // contenido desde nuestro programa
  // Lanzamos la ejecución de 'ppc386 -h'.
  UnProceso.Execute;

  // Nuestro progama se detiene hasta que 'ppc386' finaliza.

  // Ahora leemos la salida del programa que acabamos de ejecutar
  // dentro de TStringList.
  UnaLista.LoadFromStream(UnProceso.Output);
  
  // Guardamos la salida en un archivo.
  UnaLista.SaveToFile('salida.txt');

  // Ahora que hemos guardado el archivo podemos liberar de la memoria
  // TStringList y TProcess.
  UnaLista.Free;
  UnProceso.Free;   
end.</delphi>

Lectura de muchos datos de salida

   En el ejemplo anterior esperamos a que el programa termine. En ese momento leamos lo que el programa ha escrito en la salida. Pero si el programa escribe muchos datos, la tubería se llena y será necesario leerlos para vaciarla, pero el programa llamante no leerá hasta que el programa llamado haya terminado. Nos encontraremos ante un típico bloqueo de la muerte.

   El siguiente ejemplo, por tanto, no utiliza poWaitOnExit, sino que lee la salida mientras el programa llamado se está ejecutando. La salida se almacena en una memoria intermedia, que se utilizará más tarde para leer en un TStringList, por ejemplo.

<delphi> program procoutlarge;

{   Copyright (c) 2004 by Marc Weustink

    Este ejemplo se ha creado con la esperanza de que resulte útil,
    pero SIN NINGUNA GARANTÍA; ni tan siquiera la garantía implícita de
    COMERCIALIZACIÓN o ADECUACIÓN A UN OBJETIVO PARTICULAR.
}

uses
  Classes, Process, SysUtils;

const
  READ_BYTES = 2048;
  
var
  S: TStringList;
  M: TMemoryStream;
  P: TProcess;
  n: LongInt;
  BytesRead: LongInt;

begin
  // No podemos utilizar poWaitOnExit porquue no
  // conocemos el tamaño de la salida. En Linux el tamaño
  // de la salida de la tubería es de 2 kB. Si los datos de salida son más 
  // necesitamos leerlos. Esto no es posible, ya que estamos
  // esperando. Así que aquí nos encontramos en un punto muerto.
  //
  // Se utiliza un Memorystream temporal para almacenar la salida
  
  M := TMemoryStream.Create;
  BytesRead := 0;

  P := TProcess.Create(nil);
  P.CommandLine := 'ppc386 -va bogus.pp';
  P.Options := [poUsePipes];
  WriteLn('-- executing --');
  P.Execute;
  while P.Running do
  begin          
    // nos aseguramos de tener espacio
    M.SetSize(BytesRead + READ_BYTES);
    
    // intentamos leerlo
    n := P.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
    if n > 0 
    then begin
      Inc(BytesRead, n);
      Write('.')
    end
    else begin     
      // sin datos, esperamos 100 milisegundos
      Sleep(100); 
    end;
  end;
  // leemos la última parte
  repeat
    // nos aseguramos de tener espacio
    M.SetSize(BytesRead + READ_BYTES);
    // intentamos leerlo
    n := P.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
    if n > 0 
    then begin
      Inc(BytesRead, n);
      Write('.');
    end;
  until n <= 0;
  if BytesRead > 0 then WriteLn;
  M.SetSize(BytesRead); 
  WriteLn('-- executed --');
  
  S := TStringList.Create;
  S.LoadFromStream(M);
  WriteLn('-- linecount = ', S.Count, ' --');
  for n := 0 to S.Count - 1 do
  begin
    WriteLn('| ', S[n]);
  end;
  WriteLn('-- end --');
  S.Free;
  P.Free;
  M.Free;
end.</delphi>

Notas sobre la utilización de TProcess

Si está creando un programa de plataforma cruzada, puede cambiar la orden de acuerdo con el sistema operativo, mediante las directivas "{$IFDEF}s" y "{$ENDIF}s".

Ejemplo:

{...}
  AProcess:TProcess.Create(nil)
  {$IFDEF WIN32}
  AProcess.CommandLine := 'calc.exe'; //Windows Calc
  {$ENDIF}
  {$IFDEF LINUX}
  AProcess.CommandLine := 'kcalc'; //KDE Calc
  {$ENDIF}
  AProcess.Execute; //in alternative, you can use AProcess.Active:=True
{...}

Ejemplo de "talking" con el proceso aspell

Dentro del código fuente pasdoc puede encontrar dos unidades que realizan corrección ortográfica mediante "talking" con ejecución del proceso aspell a través de tuberías:

  • PasDoc_ProcessLineTalk.pas unit ejecuta la clase TProcessLineTalk, descendiente de TProcess, que se puede utilizar fácilmente para comunicar con cualquier proceso línea a línea.
  • PasDoc_Aspell.pas units ejecuta la clase TAspellProcess, que realiza corrección ortográfica utilizando la instancia fundamental TProcessLineTalk para ejecutar aspell y comunicarse con el proceso aspell que se está ejecutando.

Ambas unidades son bastante independientes del resto de fuentes de pasdoc, así que pueden servir como ejemplos del mundo real de la utilización de TProcess para ejecutar y comunicarse a través de tuberías con otros programas.