Difference between revisions of "Extending the IDE"

From Free Pascal wiki
(Menu items)
m (Extending the IDE)
Line 5: Line 5:
 
== Overview ==
 
== Overview ==
  
The IDE supports several types of plugins:
+
The Lazarus IDE supports several types of plugins:
  
; Components : These are the items in the component palette. For a example TButton can be used to create Buttons.
+
; Components : These are the items found on the Component Palette. For example, TButton (found on the Standard page) can be used to create Buttons.
  
; Component Editors : Component editors are used when you double click on a component in the designer or to add some extra items to the popup menu of the designer, when you right click on a component.
+
; Component Editors : When you double-click a component in the Designer, a component editor is invoked. The component editor may also add an extra item to the Designer's popup menu (accessed when you right-click on a component in the Designer).
  
; Property Editors : These are used by the rows in the object inspector.
+
; Property Editors : Each row in the grid section of the Object Inspector uses a property editor to allow that property's value to be set or altered.
  
; Experts : These are all other types. They register new menu items, short cuts or extend other IDE features.
+
; Experts : Experts encompass all other plugin types. They might register new menu item(s), register short cuts, or extend other IDE features.
  
  
There are two possibilities to add your own plugins to Lazarus:
+
There are two possible ways to add your own plugins to the Lazarus IDE:
  
# Write a package, install it and register your plugins in the 'Register' procedure of a unit.
+
# Write a package, install it and register your plugin(s) in the 'Register' procedure of a unit.
# Extend the lazarus code, and send your svn diff to the lazarus mailing list.
+
# Extend the Lazarus code, and send your svn diff to the Lazarus mailing list.
  
 
=Menu items=
 
=Menu items=

Revision as of 21:43, 29 January 2012

Deutsch (de) English (en) español (es) français (fr) 日本語 (ja) русский (ru) slovenčina (sk) 中文(中国大陆)‎ (zh_CN)

Contents

Extending the IDE

Overview

The Lazarus IDE supports several types of plugins:

Components 
These are the items found on the Component Palette. For example, TButton (found on the Standard page) can be used to create Buttons.
Component Editors 
When you double-click a component in the Designer, a component editor is invoked. The component editor may also add an extra item to the Designer's popup menu (accessed when you right-click on a component in the Designer).
Property Editors 
Each row in the grid section of the Object Inspector uses a property editor to allow that property's value to be set or altered.
Experts 
Experts encompass all other plugin types. They might register new menu item(s), register short cuts, or extend other IDE features.


There are two possible ways to add your own plugins to the Lazarus IDE:

  1. Write a package, install it and register your plugin(s) in the 'Register' procedure of a unit.
  2. Extend the Lazarus code, and send your svn diff to the Lazarus mailing list.

Menu items

You can add new menu items, hide or move existing ones and add sub menus, sections. For your own forms you can register the TMainMenu/TPopupMenu so that other packages can extend your form further. The unit MenuIntf of the package IDEIntf contains all registration for menus and many standard menu items of the IDE itself.

Adding a menu item

A single menu item like 'View Object Inspector' is called a TIDEMenuCommand. You can create one with RegisterIDEMenuCommand, which has two forms with lots of parameters:

<Delphi>function RegisterIDEMenuCommand(Parent: TIDEMenuSection;

                               const Name, Caption: string;
                               const OnClickMethod: TNotifyEvent = nil;
                               const OnClickProc: TNotifyProcedure = nil;
                               const Command: TIDECommand = nil;
                               const ResourceName: String = 
                               ): TIDEMenuCommand; overload;

function RegisterIDEMenuCommand(const Path, Name, Caption: string;

                               const OnClickMethod: TNotifyEvent = nil;
                               const OnClickProc: TNotifyProcedure = nil;
                               const Command: TIDECommand = nil;
                               const ResourceName: String = 
                               ): TIDEMenuCommand; overload;</Delphi>

The difference between those two is only how you specify the parent menu section. You can give the menu section directly or indirectly via the path. Many standard sections can be found in the MenuIntf unit. For example the section mnuTools, which is the Tools menu of the main IDE bar. It contains a section itmSecondaryTools, the recommended section for third party tools.

The following registers a new menu command, with the name 'MyTool', the caption 'Start my tool' and when clicked executes the procedure StartMyTool: <Delphi>procedure StartMyTool; begin

 ...executed when menu item is clicked...

end;

procedure Register; begin

 RegisterIDEMenuCommand(itmSecondaryTools, 'MyTool','Start my tool',nil,@StartMyTool);

end;</Delphi>

If you want to call a method instead of a procedure use the OnClickMethod parameter.

This menu item does not have a shortcut. If you want a shortcut you must create a TIDECommand and pass it in the Command parameter. For example:

<Delphi>uses ... IDECommands, MenuIntf; ... var

 Key: TIDEShortCut;
 Cat: TIDECommandCategory;
 CmdMyTool: TIDECommand;

begin

 // register IDE shortcut and menu item
 Key := IDEShortCut(VK_UNKNOWN,[],VK_UNKNOWN,[]);
 Cat:=IDECommandList.FindCategoryByName(CommandCategoryToolMenuName);
 CmdMyTool := RegisterIDECommand(Cat,'Start my tool', 'Starts my tool to do some stuff', Key, nil, @StartMyTool);
 RegisterIDEMenuCommand(itmSecondaryTools, 'MyTool', 'Start my tool', nil, nil, CmdMyTool);

end;</Delphi>

Shortcuts

All shortcuts (keys that invoke some action) are registered in the IDECommandList. Here is an example how to find all commands that react on key Ctrl-D or two key combinations starting with Ctrl-D:

<Delphi> uses

 Classes, SysUtils, LCLProc, IDECommands;

procedure ListCtrlD; // list all idecommands with shortcut Ctrl-D var

 i: integer;
 Cmd: TIDECommand;
 Commands: TFPList;

begin

 Commands:=IDECommandList.FindCommandsByShortCut(IDEShortCut(VK_D,[],VK_UNKNOWN,[]));
 try
   for i:=0 to Commands.Count-1 do begin
     Cmd:=TIDECommand(Commands[i]);
     writeln('Cmd: ',Cmd.Name,
       ' A=',dbgs(Cmd.ShortcutA.Shift1),'-',Cmd.ShortcutA.Key1,
       ',',dbgs(Cmd.ShortcutA.Shift2),'-',Cmd.ShortcutA.Key2,
       ' B=',dbgs(Cmd.ShortcutB.Shift1),'-',Cmd.ShortcutB.Key1,
       ',',dbgs(Cmd.ShortcutB.Shift2),'-',Cmd.ShortcutB.Key2
       );
   end;
 finally
   Commands.Free;
 end;

end; </Delphi>

Config files

Load/Save settings

All configuration files of the IDE are stored in one directory as xml files. Packages can add their own files there too. The primary config directory can be read with:

<Delphi>uses LazIDEIntf; ...

 Directory := LazarusIDE.GetPrimaryConfigPath;</Delphi>

Packages can create their own xml files with:

<Delphi>uses

 ..., LCLProc, BaseIDEIntf, LazConfigStorage;

const

 Version = 1;

var

 Config: TConfigStorage;
 SomeValue: String;
 SomeInteger: Integer;
 SomeBoolean: Boolean;
 FileVersion: LongInt;

begin

 SomeValue:='Default';
 SomeInteger:=3;
 SomeBoolean:=true;
 // save settings
 try
   Config:=GetIDEConfigStorage('mysettings.xml',false);
   try
     // store the version number so future extensions can handle old config files
     Config.SetDeleteValue('Path/To/The/Version',Version,0);
     // store string variable "SomeValue"
     // if SomeValue has the default value the entry is not stored,
     // so only the differences to the default are stored.
     // This way the xml is kept short and defaults may change in future.
     Config.SetDeleteValue('Path/To/Some/Value',SomeValue,'Default');
     Config.SetDeleteValue('Path/To/Some/Integer',SomeInteger,3);
     Config.SetDeleteValue('Path/To/Some/Boolean',SomeBoolean,true);
     // there are more overloads for SetDeleteValue, find out with Ctrl+Space
   finally
     Config.Free;
   end;
 except
   on E: Exception do begin
     DebugLn(['Saving mysettings.xml failed: ',E.Message]);
   end;
 end;
 // load settings
 try
   Config:=GetIDEConfigStorage('mysettings.xml',true);
   try
     // read the version of the config
     FileVersion:=Config.GetValue('Path/To/The/Version',0);
     // read a string variable "SomeValue". If the entry does not exist, use
     // the Default
     SomeValue:=Config.GetValue('Path/To/Some/Value','Default');
     SomeInteger:=Config.GetValue('Path/To/Some/Integer',3);
     SomeBoolean:=Config.GetValue('Path/To/Some/Boolean',true);
   finally
     Config.Free;
   end;
 except
   on E: Exception do begin
     DebugLn(['Loading mysettings.xml failed: ',E.Message]);
   end;
 end;

end;</Delphi>

Components

Writing components

You can create new components via the package editor. For example: Create or open a package, click on add, click on New Component, fill in the items: Ancestor Type = TButton, New class name = TMyButton, palette page = Misc, Unit file name = mybutton.pas (this file will be created), unit name MyButton and click ok.

Giving a new component an icon for the component palette

For example give TMyButton an icon. Create an image file of the format .bmp, .xpm or .png with the same name as the component class. For example tmybutton.png and save it in the package source directory. The image can be created by any graphic program (e.g. gimp) and should be no bigger than 24x24 pixel. Then convert the image to a .lrs file with the lazres tool, which can be found in the lazarus/tools directory:

 ~/lazarus/tools/lazres mybutton.lrs tmybutton.png

This creates an pascal include file, which is used in the initialization section of mybutton.pas:

 initialization
   {$I mybutton.lrs}

Install the package.

Hiding a component in the component palette

Package IDEIntf, unit componentreg:

IDEComponentPalette.FindComponent('TButton').Visible:=false;

Writing component editors

A component editor handles things like double clicking on a component in a designer or adding menu items when right clicking on a component. Writing a component editor is easy. See the unit componenteditors.pas of the package IDEIntf for lots of examples. For instance to show an editor when double clicking see TCheckListBoxComponentEditor.

Writing property editors

Each type of property (integer, string, TFont, ...) in the Object Inspector needs a property editor. If your component has a property Password of type string, then you can define a property editor for your specific component class, with a property named Password of type string. The unit propedits.pp of the package IDEIntf contains many of the standard property editors used by the IDE itself. For example the TStringPropertyEditor is the default property editor for all strings, while TComponentNamePropertyEditor is more specific and handles only TComponent.Name.

Designer

Writing a designer mediator

The standard designer allows to visually edit LCL controls, while all others are shown as icons. To visually edit non LCL control, you can create a designer mediator. This can be used to design webpages, UML diagrams or other widgetsets like fpGUI. There is a complete example in examples/designnonlcl/.

  • Install the example package examples/designnonlcl/notlcldesigner.lpk and restart the IDE. This will register the designer mediator for TMyWidget components and add the new components TMyButton, TMyGroupBox to the component palette.
  • Open the the example project examples/designnonlcl/project/NonLCL1.lpi.
  • Open the unit1.pas and show the designer form (F12). You should see the components as red rectangles, which can be selected, moved and resized like LCL controls.

Create a new unique component name

<Delphi> uses FormEditingIntf;

...

NewName:=FormEditingHook.CreateUniqueComponentName(AComponent);

// Or if you need to create the name before creating the component:

NewName:=FormEditingHook.CreateUniqueComponentName(ComponentClassName,OwnerComponent); // ComponentClassName will be used as prefix, without a leading T. // OwnerComponent is the new owner of the new component. </Delphi>

Select a component in the designer/object inspector

<Delphi>uses propedits; .. GlobalDesignHook.SelectOnlyThis(AComponent);</Delphi>

Event handlers

There are several events in the IDE, for which plugins can add their own handlers.

Designer events

In propedits.pp there is a "GlobalDesignHook" object, which maintains several events for designing. Each event calls a list of handlers. The default handlers are added by the IDE. You can add your own handlers with the AddHandlerXXX and RemoveHandlerXXX methods. They will be called before the default handlers.

Examples:

 Adding your handler (this is normally done in the constructor of your object):
   GlobalDesignHook.AddHandlerComponentAdded(@YourOnComponentAdded);
Removing your handler: GlobalDesignHook.RemoveHandlerComponentAdded(@YourOnComponentAdded);
You can remove all handlers at once. For example, it is a good idea to add this line in the destructor of object: GlobalDesignHook.RemoveAllHandlersForObject(Self);

The handlers of GlobalDesignHook:

 // lookup root
 ChangeLookupRoot
   Called when the "LookupRoot" changed.
   The "LookupRoot" is the owner object of the currently selected components.
   Normally this is a TForm.
// methods CreateMethod GetMethodName GetMethods MethodExists RenameMethod ShowMethod Called MethodFromAncestor ChainCall
// components GetComponent GetComponentName GetComponentNames GetRootClassName ComponentRenamed Called when a component was renamed ComponentAdded Called when a new component was added to the LookupRoot ComponentDeleting Called before a component is freed. DeleteComponent Called by the IDE to delete a component. GetSelectedComponents Get the current selection of components.
// persistent objects GetObject GetObjectName GetObjectNames
// modifing Modified Revert RefreshPropertyValues // Selection SetSelection GetSelection

Getting notified when a designer form is modified

Every designed LCL form has a Designer of type TIDesigner. The IDE creates designers of type TComponentEditorDesigner defined in the IDEIntf unit componenteditors. For example:

<Delphi>procedure TYourAddOn.OnDesignerModified(Sender: TObject); var

 IDEDesigner: TComponentEditorDesigner;

begin

 IDEDesigner:=TComponentEditorDesigner(Sender);
 ...

end;

procedure TYourAddOn.ConnectDesignerForm(Form1: TCustomForm); var

 IDEDesigner: TComponentEditorDesigner;

begin

 IDEDesigner:=TComponentEditorDesigner(Form1.Designer);
 IDEDesigner.AddHandlerModified(@OnDesignerModified);

end;</Delphi>

Project events

These events are defined in unit LazIDEIntf.

  • LazarusIDE.AddHandlerOnProjectClose: called before a project is closed
  • LazarusIDE.AddHandlerOnProjectOpened: called after the project was completely opened (for example all required packages were loaded, units were opened in the source editor)
  • LazarusIDE.AddHandlerOnSavingAll: called before IDE saves everything
  • LazarusIDE.AddHandlerOnSavedAll: called after IDE saved everything
  • LazarusIDE.AddHandlerOnProjectBuilding: called before IDE builds the project
  • LazarusIDE.AddHandlerOnProjectDependenciesCompiling: called before IDE compiles package dependencies of project
  • LazarusIDE.AddHandlerOnProjectDependenciesCompiled: called after IDE compiled package dependencies of project

Other IDE events

  • LazarusIDE.AddHandlerOnIDERestoreWindows: called when IDE is restores its windows (before opening the first project)
  • LazarusIDE.AddHandlerOnIDEClose: called when IDE is shutting down (after closequery, so no more interactivity)
  • LazarusIDE.AddHandlerOnQuickSyntaxCheck: called when the menu item or the shortcut for Quick syntax check is executed

Project

Current Project

The current main project can be obtained by LazarusIDE.ActiveProject. (unit LazIDEIntf)

All units of current project

To iterate through all pascal units of the current main project of the IDE you can use for example:

<Delphi>uses

 LCLProc, FileUtil, LazIDEIntf, ProjectIntf;

procedure ListProjectUnits; var

 LazProject: TLazProject;
 i: Integer;
 LazFile: TLazProjectFile;

begin

 LazProject:=LazarusIDE.ActiveProject;
 if LazProject<>nil then
   for i:=0 to LazProject.FileCount-1 do
   begin
     LazFile:=LazProject.Files[i];
     if LazFile.IsPartOfProject
     and FilenameIsPascalUnit(LazFile.Filename)
     then
       debugln(LazFile.Filename);
   end;

end;</Delphi>

The .lpr, .lpi and .lps file of a project

<Delphi>uses

 LCLProc, FileUtil, ProjectIntf, LazIDEIntf;

var

 LazProject: TLazProject;

begin

 LazProject:=LazarusIDE.ActiveProject;
 // every project has a .lpi file:
 DebugLn(['Project lpi file: ',LazProject.ProjectInfoFile]);
 // if the project session information is stored in a separate .lps file:
 if LazProject.SessionStorage<>pssNone then
   DebugLn(['Project lps file: ',LazProject.ProjectSessionFile]);
 // If the project has a .lpr file it is the main source file:
 if (LazProject.MainFile<>nil)
 and (CompareFileExt(LazProject.MainFile.Filename,'lpr')=0) then
   DebugLn(['Project has lpr file: ',LazProject.MainFile.Filename]);

end;</Delphi>

The executable / target file name of a project

There is a macro $(TargetFile), which can be used in paths and external tools. You can query the macro in code:

<Delphi>uses MacroIntf;

function MyGetProjectTargetFile: string; begin

 Result:='$(TargetFile)';
 if not IDEMacros.SubstituteMacros(Result) then
   raise Exception.Create('unable to retrieve target file of project');

end;</Delphi>

See here for more macros: IDE Macros in paths and filenames.

Add your own project type

You can add items to the 'New ...' dialog:


Add your own file type

You can add items to the 'New ...' dialog:

  • See the unit ProjectIntf of the package IDEIntf.
  • Choose a base class TFileDescPascalUnit for normal units or TFileDescPascalUnitWithResource for a new form/datamodule.

Add a new file type

<Delphi>uses ProjectIntf; ...

 { TFileDescText }
 TFileDescMyText = class(TProjectFileDescriptor)
 public
   constructor Create; override;
   function GetLocalizedName: string; override;
   function GetLocalizedDescription: string; override;
 end;

...

procedure Register;

implementation

procedure Register; begin

 RegisterProjectFileDescriptor(TFileDescMyText.Create,FileDescGroupName);

end;

{ TFileDescMyText }

constructor TFileDescMyText.Create; begin

 inherited Create;
 Name:='MyText'; // do not translate this
 DefaultFilename:='text.txt';
 AddToProject:=false;

end;

function TFileDescText.GetLocalizedName: string; begin

 Result:='My Text'; // replace this with a resourcestring

end;

function TFileDescText.GetLocalizedDescription: string; begin

 Result:='An empty text file';

end;</Delphi>

Add a new form type

<Delphi>uses ProjectIntf;

...

 TFileDescPascalUnitWithMyForm = class(TFileDescPascalUnitWithResource)
 public
   constructor Create; override;
   function GetInterfaceUsesSection: string; override;
   function GetLocalizedName: string; override;
   function GetLocalizedDescription: string; override;
 end;

...

procedure Register;

implementation

procedure Register; begin

 RegisterProjectFileDescriptor(TFileDescPascalUnitWithMyForm.Create,FileDescGroupName);

end;

{ TFileDescPascalUnitWithMyForm }

constructor TFileDescPascalUnitWithMyForm.Create; begin

 inherited Create;
 Name:='MyForm'; // do not translate this
 ResourceClass:=TMyForm;
 UseCreateFormStatements:=true;

end;

function TFileDescPascalUnitWithMyForm.GetInterfaceUsesSection: string; begin

 Result:='Classes, SysUtils, MyWidgetSet';

end;

function TFileDescPascalUnitWithForm.GetLocalizedName: string; begin

 Result:='MyForm'; // replace this with a resourcestring

end;

function TFileDescPascalUnitWithForm.GetLocalizedDescription: string; begin

 Result:='Create a new MyForm from example package NotLCLDesigner';

end;</Delphi>

Packages

Search in all packages

Iterate all packages loaded in the IDE (since 0.9.29).

<Delphi>uses PackageIntf; ... for i:=0 to PackageEditingInterface.GetPackageCount-1 do

 writeln(PackageEditingInterface.GetPackages(i).Name);</Delphi>

Search a package with a name

<Delphi>uses PackageIntf; ... var

 Pkg: TIDEPackage;

begin

 Pkg:=PackageEditingInterface.FindPackageWithName('LCL');
 if Pkg<>nil then 
   ...

end;</Delphi>

Note: FindPackageWithName does not open the package editor. For that use DoOpenPackageWithName.

Install packages

Note: Only install packages with IDE plugins. Installing other packages can make the IDE unstable.

<Delphi> uses PackageIntf, contnrs; ...

 PkgList:=TObjectList.create(true);
 try
   Pkg:=TLazPackageID.Create;
   Pkg.Name:='Cody';
   PkgList.Add(Pkg);
   // check if the IDE can find the cody.lpk and all dependencies
   // The IDE will prompt some warnings/confirmations if something looks strange.
   if not PackageEditingInterface.CheckInstallPackageList(PkgList,[]) then
     exit;
   // in this example we have checked already, so skip the warnings
   // and rebuild the IDE
   if PackageEditingInterface.InstallPackages(PkgList,[piiifSkipChecks,piiifRebuildIDE])<>mrOK then
     exit;
 finally
   PkgList.Free;
 end;

</Delphi>

Open a package file (lpk)

<Delphi> uses PackageIntf, FileUtil; ... var

 pkg: TIDEPackage;

begin

 if PackageEditingInterface.DoOpenPackageFile(LPKFilename,[pofAddToRecent],false)<>mrOk then
   exit;
 Pkg:=PackageEditingInterface.FindPackageWithName(ExtractFilenameOnly(LPKFilename));
 ...

end; </Delphi>

Warning: The IDE automatically closes unused packages on idle. Never keep a reference to an TIDEPackage.

Find the package(s) of a unit

You have the file name of a unit, e.g. '/home/user/unit.pas', and you want to know to which package(s) and project(s) it belongs use this:

<Delphi> uses Classes, PackageIntf, ProjectIntf; ... var

 Owners: TFPList;
 i: Integer;
 o: TObject;

begin

 Owners:=PackageEditingInterface.GetPossibleOwnersOfUnit('/full/path/of/unit.pas',[]);
 if Owners=nil then begin
   // unit is not directly associated with a project/package
   // maybe the unit was for some reason not added, but is reachable
   // search in all unit paths of all projects/packages
   // Beware: This can lead to false hits
   Owners:=PackageEditingInterface.GetPossibleOwnersOfUnit('/full/path/of/unit.pas',
     [piosfExcludeOwned,piosfIncludeSourceDirectories]);
 end;
 if Owners=nil then exit;
 try
   for i:=0 to Owners.Count-1 do begin
     o:=TObject(Owners[i]);
     if o is TIDEPackage then begin
       writeln('Owner is package ',TIDEPackage(o).Name);
     end else if o is TLazProject then begin
       writeln('Owner is project ',TLazProject(o).ProjectInfoFile);
     end;
   end;
 finally
   Owners.Free;
 end;

</Delphi>

Windows

There are basically four types of IDE windows.

  • the main IDE bar is the Application.MainForm. It is always present.
  • floating/dockable windows like the Source Editors, the Object Inspectors and Messages.
  • the modal forms, like the find dialog, options dialogs and questions.
  • hints and completion forms

Adding a new dockable IDE window

What is a dockable IDE window: Windows like the Source Editor or the Object Inspector are floating windows, that can be docked if a docking package is installed, and its state, position and size is stored and restored on next IDE start. In order to restore a window the IDE needs a creator as defined in the unit IDEWindowIntf of the package IDEIntf. Each dockable window must have a unique name. Do not use generic names like 'FileBrowser' because this will easily clash with other packages. And don't use short names like 'XYZ', because the creator is responsible for all forms beginning with this name.

How to register a dockable IDE window

Remember to choose a long unique name that is a valid pascal identifier. Your window can have any caption you want.

<Delphi>uses SysUtils, IDEWindowIntf; ... var MyIDEWindow: TMyIDEWindow = nil;

procedure CreateMyIDEWindow(Sender: TObject; aFormName: string; var AForm: TCustomForm; DoDisableAutoSizing: boolean); begin

 // check the name
 if CompareText(aFormName,MyIDEWindowName)<>0 then exit;
 // create the form if not already done and disable autosizing
 IDEWindowCreators.CreateForm(MyIDEWindow,TMyIDEWindowm,DoDisableAutosizing,Application);
 ... init the window ...
 AForm:=MyIDEWindow;

end;

procedure Register; begin

 IDEWindowCreators.Add('MyIDEWindow',@CreateMyIDEWindow,nil,'100','50%','+300','+20%');
 // the default boundsrect of the form is:
 // Left=100, Top=50% of Screen.Height, Width=300, Height=20% of Screen.Height
 // when the IDE needs an instance of this window it calls the procedure CreateMyIDEWindow.

end;</Delphi>

Showing an IDE window

Do not use Show. Use:

<Delphi>IDEWindowCreators.ShowForm(MyIDEWindow,false);</Delphi>

This will work with docking. The docking system might wrap the form into a docking site. The BringToFront parameter tells the docking system to make the form and all its parent sites visible and bring the top level site to the front.

Notes about IDEWindowCreators and SimpleLayoutStorage

The IDEWindowCreators.SimpleLayoutStorage simply stores the BoundsRect and WindowState of all forms that were once opened. It is used as fallback if no dockmaster is installed. It stores the state even if a DockMaster is installed, so that when the dockmaster is uninstalled the forms bounds are restored.

The IDEWindowCreators is used by all dockable forms to register themselves and to show forms. When showing a form the Creator checks if a IDEDockMaster is installed and will delegate the showing to it. If no IDEDockMaster is installed it simply shows the form. The IDEDockMaster can use the information in the IDEWindowCreators to create forms by names and get an idea where to place a form when showing it for the first time. For more details see the packages AnchorDockingDsgn and EasyDockMgDsgn.

CodeTools

The CodeTools is a package providing a vast amount of functions to parse, search and change pascal sources and some basic functions for other languages as well. You can use them without the IDE too. It is recommended that you read first about the CodeTools in general before using them in the IDE: Codetools.

Before calling any of the CodeTools functions in the IDE you should commit the current changes of the source editor to the CodeTools buffers:

<Delphi>uses LazIDEIntf; ...

 // save changes in source editor to codetools
 LazarusIDE.SaveSourceEditorChangesToCodeCache(-1); // -1: commit all source editors</Delphi>

Adding a resource directive to a file

This adds a {$R example.res} to a pascal unit:

<Delphi>procedure AddResourceDirectiveToPascalSource(const Filename: string); var

 ExpandedFilename: String;
 CodeBuf: TCodeBuffer;

begin

 // make sure the filename is trimmed and contains a full path
 ExpandedFilename:=CleanAndExpandFilename(Filename);
 
 // save changes in source editor to codetools
 LazarusIDE.SaveSourceEditorChangesToCodeCache(-1);
 // load the file
 CodeBuf:=CodeToolBoss.LoadFile(ExpandedFilename,true,false);
 // add the resource directive
 if not CodeToolBoss.AddResourceDirective(CodeBuf,'example.res') then
   LazarusIDE.DoJumpToCodeToolBossError;

end;</Delphi>

The codetools provides also functions like FindResourceDirective and RemoveDirective.

Getting the search paths for units and include files

There are many different search paths in the IDE from projects, packages, the fpc and lazarus directory and there are many types of paths: before or after resolving macros, with or without inherited search paths, as relative or absolute paths. All files in a directory share the same set of search paths. You can get the search paths for each directory fully resolved by asking the codetools:

<Delphi> uses CodeToolManager; ...

Dir:=; // the empty directory is for new files and has the same settings as the project directory

// Getting the search paths for include files: Path:=CodeToolBoss.GetIncludePathForDirectory(Dir);

// Getting the search paths for units: // This search path is passed to the compiler. // It contains the package output directories, but not the package source directories. Path:=CodeToolBoss.GetUnitPathForDirectory(Dir);

// There can be additional unit search paths for the IDE only (not passed to the compiler) Path:=CodeToolBoss.GetSrcPathForDirectory(Dir);

// The complete search path contains also all package source paths for units: Path:=CodeToolBoss.GetCompleteSrcPathForDirectory(Dir); </Delphi>

Source Editor

Active source editor

<Delphi> uses SrcEditorIntf; ... Editor:=SourceEditorManagerIntf.ActiveEditor; if Editor=nil then exit; Filename:=Editor.FileName; ScreenPos:=Editor.CursorScreenXY; TextPos:=Editor.CursorTextXY; </Delphi>

SynEdit

Getting the settings for a TSynEdit

When you have a dialog using a TSynEdit and you want to use the same font and settings like the source editor use:

<Delphi> uses SrcEditorIntf; ... SourceEditorManagerIntf.GetEditorControlSettings(ASynEdit); </Delphi>

Getting the settings for a SynEdit highlighter

When you have a dialog using a TSynEdit with a highlighter and you want to use the same colors like the source editor highlighter for this language use:

<Delphi> uses SrcEditorIntf; ... SourceEditorManagerIntf.GetHighlighterSettings(ASynHighlighter); </Delphi>

See for an example: TSQLStringsPropertyEditorDlg.Create in the unit SQLStringsPropertyEditorDlg.

Help

Adding help for sources

First create a THelpDatabase: <delphi>HelpDB := TFPDocHTMLHelpDatabase(

 HelpDatabases.CreateHelpDatabase('ANameOfYourChoiceForTheDatabase',
 TFPDocHTMLHelpDatabase,true));

HelpDB.DefaultBaseURL := 'http://your.help.org/';

FPDocNode := THelpNode.CreateURL(HelpDB,

 'Package1 - A new package',
 'file://index.html');

HelpDB.TOCNode := THelpNode.Create(HelpDB,FPDocNode);// once as TOC DirectoryItem := THelpDBISourceDirectory.Create(FPDocNode,'$(PkgDir)/lcl',

 '*.pp;*.pas',false);// and once as normal page

HelpDB.RegisterItem(DirectoryItem);</delphi>

Adding lines to the messages window

<Delphi>unit IDEMsgIntf; ... var Dir: String; begin

 Dir:=GetCurrentDir;
 IDEMessagesWindow.BeginBlock;
 IDEMessagesWindow.AddMsg('unit1.pas(30,4) Error: Identifier not found "a"',Dir,0);
 IDEMessagesWindow.EndBlock;

end;</Delphi>

Overview of the various help items

Creating IDE Help