LazActiveX/es

This article applies to Windows only.

See also: Multiplatform Programming Guide

│ English (en) │ español (es) │

Resumen

   El paquete LazActiveX contiene el componente TActiveXContainer y la integración con el IDE de las herramientas necesarias para crear componentes ActiveX desde una biblioteca de tipos o directamente desde el objeto (exe o dll). ActiveX es una tecnología de Microsoft Windows y sólo se puede utilizar en esa plataforma. Compilación cruzada para Windows es posible, pero el importador de biblioteca de tipos (typelib) para crear los enlaces COM sólo funciona en Windows (no probado en Wine)

Instalación

   Aviso: LazActiveX necesita FPC >= 2.6.1. La importación de bibliotecas de tipos sólo funciona en Windows XP o posterior.

   Desde la opción del menú 'Paquete'/'Instalar/Desinstalar Paquetes ...' en la ventana, seleccionar LazActiveX 0.1, y dar al botón 'Instalar Seleccionado' y después a 'Guardar y Reconstruir el IDE'. Alternativamente, abrir el paquete LazActiveX.lpk y pulsar en 'Usar >>'/'Instalar'.

   Cuando la instalación termine correctamente, una nueva pestaña 'ActiveX' se añade a la paleta de componentes.

Utilización

   Existen 3 maneras diferentes de utilizar los componentes de ActiveX:

1. Poner el componente TActiveXContainer en un formulario y asignar el nombre de la clase ActiveX a la propiedad OleClassName. Adecuado para el enlace en tiempo de ejecución ( o tardío) y sin el apoyo directo para eventos.
2. Importar la biblioteca de tipo ActiveX, poner el componente TActiveXContainer en un formulario, crear una instancia del objeto ActiveX y asignarlo a la propiedad ComServer. Adecuado para el enlace en tiempo de compilación (o anticipado) y con el apoyo para eventos.
3. Crear un nuevo componente desde la biblioteca de tipos o el objeto y poner nuevo componente en el formulario. Esto también utiliza enlace anticipado y tiene soporte completo para eventos. Los controladores de eventos pueden ser asignados desde el IDE.

Enlace tardío de TActiveXContainer

   Aunque la teoría es bastante compleja, el enlace en tiempo de ejecución (o tardío) es la manera más rápida para crear y ejecutar un componente ActiveX.

   Por enlace tardío se refiere el hecho de que la interfaz con el objeto se realiza completamente en tiempo de ejecución. Las referencias a objetos se almacenan como dispinterfaces en variables variant y los métodos y propiedades de los objetos se descubren en tiempo de ejecución. El compilador genera toda la magia de tiempo de ejecución para ti, pero el inconveniente es que el compilador no es capaz de ayudar a encontrar los nombres de los métodos o propiedades en tiempo de diseño. Una buena documentación para el objeto ActiveX es muy importante (el código de ejemplo para VB puede ser fácilmente traducido a pascal). Todos los errores en los nombres de método y sus parámetros serán errores en tiempo de ejecución. El descubrimiento en tiempo de ejecución también agregará sobrecarga al proceso.

   Ejemplo: Embeber el reproductor VLC en un formulario. ¡VLC ha de estar correctamente instalado!

• Colocar un TActiveXContainer, un TButton y un TFileNameEdit en un formulario.

• Da el tamaño y la posición deseada al componente TActiveXContainer y escribe 'VideoLAN.VLCPlugin.2' en la propiedad OleClassName, pon a verdadera la propiedad Active. Esto dará un formulario similar al siguiente:

• Crea un evento Onclick para el botón con este código:

 procedure TForm1.Boton1Click(Sender: TObject);
 var
   Actx:variant;
 begin
   Actx:=ActiveXContainer1.ComServer;
   Actx.playlist.add(widestring(FileNameEdit1.FileName));
   Actx.playlist.play;
 end;

• Ejecuta el programa, selecciona una película y haz clic en el botón para verla. Ten en cuenta que VLC juntocon gdb parecen causar algunos problemas (lenta puesta en marcha en el mejor de los casos, se cuelga o se bloquea). Mejor ejecuta el programa fuera del IDE.

TActiveXContainer early binding

Early binding means that all interfaces are known to the compiler. So we need to create the pascal bindings for the ActiveX object. The importtl.exe tool in the fpc utils directory does that for you and creates coclasses and event listeners to facilitate the use of the objects in pascal. A GUI for the importtl.exe tool is integrated with the LazActiveX package and is accessible in the Tools menu: Import Type Library.

Check 'Convert dependent typelibs' to convert also the typelibs for the COM objects that are eventually used by the selected object. Clicking OK will start the typelib import and create new units in the IDE. The units have the following naming: LibraryName_MajorVersion_MinorVersion_TLB. Ex: Access_9_0_TLB.

Delphi users: Delphi unit naming does not use version numbers.

Instantiating an ActiveX object is done at run-time by calling the Create method for the appropriate CoClass created for the library. Some ActiveX libraries expose several objects and multiple CoClasses are created. Consult the documentation for the ActiveX library in case of doubt. Assigning the instantiated ActiveX object to the ComServer property of an TActiveXContainer on a form and setting it's active property to true is all that is needed to embed it in the application.

Example: Embed VLC player in a form. VLC has to be installed !!

- Drop a TActiveXContainer, a TButton and a TFileNameEdit on a form. Resize and position TActiveXContainer to your liking

- Open 'Import Type Library' from the tools menu and select 'axvlc.dll' in your VLC installation directory. Click OK. The AXVLC_1_0_TLB unit is created.

- Add AXVLC_1_0_TLB to the uses clause.

- Create an OnClick event for the button and an OnCreate event for the form. Enter the following code:

var
  VLC:IVLCControl2;

procedure TForm1.Button1Click(Sender: TObject);
begin
  VLC.playlist.add(utf8decode(FileNameEdit1.FileName),'',vararrayof([':aspect-ratio=16:9']));
  VLC.playlist.play;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  VLC:=CoVLCPlugin2.Create;
  ActiveXContainer1.ComServer:=VLC;
  ActiveXContainer1.Active:=true;
end;

- Run the program, select a movie and click the button to view the movie.

The typelib importer adds also event support for ActiveX that generate them. In that case, alongside the CoClass a TEventSink descendant is defined that implements the ActiveX object and all its OnEvent properties. Use the TEventSink descendant instead of the CoClass if you want to use the events. Its name starts with TEvs followed by the class name.

Example: Internet Explorer in a form with event support.

- Drop a TActiveXContainer, a TButton, TLabel and a TEdit on a form. Resize and position TActiveXContainer to your liking

- Open 'Import Type Library' from the tools menu and select 'C:\WINDOWS\system32\ieframe.dll'. Click OK. The SHDocVw_1_1_TLB unit is created.

- Add SHDocVw_1_1_TLB to the uses clause.

- Create an OnClick event for the button and an OnCreate event for the form.

- Create in class TForm1 the private procedure OnStatusTextChange(Sender: TObject;Text_:WideString);

- Enter the following code:

var
  Browser:TEvsWebBrowser;

procedure TForm1.Button1Click(Sender: TObject);
var
  url,onull:Olevariant;

begin
  url:=Utf8decode(Edit1.Text);
  onull:=NULL;
  Browser.ComServer.Navigate2(url,onull,onull,onull,onull);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Browser:=TEvsWebBrowser.Create(Self);
  ActiveXContainer1.ComServer:=Browser.ComServer;
  ActiveXContainer1.Active:=true;
  Browser.OnStatusTextChange:=@OnStatusTextChange;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Browser.Free;
end; 

procedure TForm1.OnStatusTextChange(Sender: TObject; Text_: WideString);
begin
  Label1.Caption:=UTF8Encode(Text_);
end;

- Run the program, enter an URL in the Edit control and click the button to navigate to the URL. Label1 will show the status messages sent by the browser.

- To access the document object (DOM) you have to import also the typelib from C:\WINDOWS\system32\mshtml.tlb and add the created MSHTML_4_0_TLB to the uses clause. To display for example the contents of the <body> tag of the downloaded page, add a TMemo and a second TButton to the form and add the following code:

procedure TForm1.Button2Click(Sender: TObject);
var  Doc: IHTMLDocument2; //defined in MSHTML_4_0_TLB
begin
  Doc := Browser.ComServer.Document as IHTMLDocument2;
  Memo1.Lines.Text := utf8encode(Doc.parentWindow.document.Get_body.innerHTML);
end;

Note that CoClasses are not destroyed. As all COM objects they are reference counted and destroy themselves when the last reference goes out of scope. The TEventSink descendant has to be destroyed.

Creating visual ActiveX components from type libraries or objects

Instead of using the TActiveXContainer component directly the importtl tool can create TActiveXContainer descendants for every ActiveX object embedded in the type library and create a lpk package for you. The descendants have full support for events generated by the objects. To create a package with the ActiveX components open the 'Import Type Library' window in the 'Tools' menu. Select the library to import, check 'Create package' and eventually 'Convert dependent typelibs', click on 'OK' to create the package. You will be prompted for a directory to store the package. Install the new package. After the Lazarus rebuild you'll find the new components in the ActiveX tab of the component palette.

Example: Embed VLC player in a form. VLC has to be installed !!

- Open 'Import Type Library' from the tools menu and select 'axvlc.dll' in your VLC installation directory. Check 'Create package'. Click OK. Select a directory to store the package. The AXVLC_1_0_TLBP package and all the needed units are created. Install the AXVLC_1_0_TLBP package and rebuild the IDE.

- Drop a TAxcVLCPlugin2 (from ActiveX component tab), a TButton and a TFileNameEdit on a form.

- Set TAxcVLCPlugin2.Active to true and resize and position TActiveXContainer to your liking.

- Create an Onclick event for the button and enter:

uses variants;
...
procedure TForm1.Button1Click(Sender: TObject);
begin
  AxcVLCPlugin2_1.OleServer.playlist.add(widestring(FileNameEdit1.FileName,'',vararrayof([':aspect-ratio=16:9']));
  AxcVLCPlugin2_1.OleServer.playlist.play;
end;

- Run the program, select a movie and click the button to view the movie.

Event handlers for the components can be created directly from the Object Inspector. (Note the VLC version 1.1.5.0 typelib advertises events but fails to establish a connection point. This appears to be a bug in VLC).

Delphi users: Delphi creates a stub for every method and property in its ActiveX components. importtl does not add this additional layer and the AxctiveX methods are called through the components OleServer property. Fe. AxcVLCPlugin2_1.OleServer.playlist.play is the equivalent to VLCPlugin21.playlist.play in Delphi.