Difference between revisions of "Lazarus Database Tutorial/zh TW"

From Free Pascal wiki
Jump to navigationJump to search
Line 49: Line 49:
 
進行前需要先找到我的 MYSQL 用戶端函式庫是放在 /usr/lib 目錄下面的哪裡,我的狀況是先下 shell 指令:
 
進行前需要先找到我的 MYSQL 用戶端函式庫是放在 /usr/lib 目錄下面的哪裡,我的狀況是先下 shell 指令:
 
  ln -s libmysqlclient.so.12.0.0 lmysqlclient
 
  ln -s libmysqlclient.so.12.0.0 lmysqlclient
to make a symbolic link allowing FPC to find the library.  For good measure I also created the link
+
建立一個軟連結讓 FPC 可以找的到函式庫。為了更準確一些我再建立一個連結
 
  ln -s libmysqlclient.so.12.0.0 mysqlclient
 
  ln -s libmysqlclient.so.12.0.0 mysqlclient
and placed similar links in various other directories:  not strictly necessary, but just in case ...!
+
然後放一個相同的連結在不同的其他目錄裡:不是必需,視請況而定!
Some users might need to add the following link:
+
然後有些使用者也許會需要增加如下的連結:
 
  ln -s libmysqlclient.so.12.0.0 libmysqlclient.so
 
  ln -s libmysqlclient.so.12.0.0 libmysqlclient.so
  
I modified trydb.pp to include user details, initially by adding host, user and password as constants:
+
我修改 trydb.pp 的內容,含括進使用者連線資訊,從上到下計的內容有主機,使用者與密碼:
  
 
  const
 
  const
Line 62: Line 62:
 
   passwd: Pchar = 'mypassword';
 
   passwd: Pchar = 'mypassword';
  
I also found that I couldn't connect to mysql using the mysql_connect() call, but had to use mysql_real_connect() which has many more parameters.  To complicate things further, the number of parameters seems to have changed between version3 (where there are seven) and version4 (where there are eight).  Before using mysql_real_connect I had to use mysql_init() which is not found in the original mysql.pp but is found in mysql_v4.pp.
+
我還發現我忽叫 mysql_connect() 還是無法連上 MySQL,但使用 mysql_real_connect() ,加上一堆參數後就可以了。未來還會更複雜,參數的數目似乎從 3 版(七個)換到 4 版(八個)還有變化。在使用 mysql_real_connect 之前我還得先使用 mysql_init(),但這在原始的 mysql.pp 裡並找不到,但出現於 mysql_v4.pp。
  
So the code for connection to the database is now:
+
所以連線的程式碼將會是現在這樣:
  
  { a few extra variables}
+
  {一些額外的變數}
 
  var
 
  var
 
   alloc : PMYSQL;
 
   alloc : PMYSQL;
 
    
 
    
  {main program fragment}
+
  {主程式片段}
 
    
 
    
 
  begin
 
  begin
Line 109: Line 109:
  
  
Now - ready to start compiling trydb.pp?
+
現在 - 準備好開始編譯 trydb.pp 了嗎?
 
   fpc trydb
 
   fpc trydb
success!  Now run it:
+
成功!現在執行:
 
   ./trydb
 
   ./trydb
whoopee!  I got the listing of the FPC developers!
+
哇!我能讀取得到 FPC 開發者的清單了!
  
A few extra refinements:  make the entry of user details and the mysql commands interactive, using variables rather than constants, and allow several SQL commands to be entered, until we issue the quit command: see the [[Lazarus Database Tutorial/TryDbpp|full program listing]], where user details are entered from the console, and the program goes into a loop where SQL commands are entered from the console (without the terminal semicolon) and the responses are printed out, until 'quit' is entered from the keyboard.
+
想要更精進的話:將使用者連線資訊的部份與 MySQL 的指令做成互動的模式,使用變數而不使用常數,如此可以在你退出 MySQL 前輸入多個 SQL 指令:參見[[Lazarus Database Tutorial/TryDbpp|所有程式列表]],當使用者資訊是從主控台模式輸入取得時,程式將要利用迴圈,讓 SQL 的指令可以重覆輸入 (可以不用分號做結尾),然後再將回應顯示出來,直到使用者鍵入 'quit' 為止。
  
See [[Lazarus Database Tutorial/SampleListing|Sample Console Listing]].
+
參見[[Lazarus Database Tutorial/SampleListing|主控台範例清單]]
  
 
===Connecting to MySQL from a Lazarus Application ===
 
===Connecting to MySQL from a Lazarus Application ===

Revision as of 18:20, 19 December 2010

Template:Translate

Databases portal

References:

Tutorials/practical articles:

Databases

Advantage - MySQL - MSSQL - Postgres - Interbase - Firebird - Oracle - ODBC - Paradox - SQLite - dBASE - MS Access - Zeos

導覽

本教材內容是關於如何於 Lazarus 下配合數種資料庫來工作。

Lazarus 支援數種非內建資料庫,而開發者仍應安裝各資料庫所對應的元件(Packages)。你可以透過程式碼或直接拉元件(components)至表單(from)來存取資料庫。資料感知 (data-aware) 元件代表資料庫欄位,並透過 TDataSource 設定指定的資料來源 (DataSource) 屬性物件來連接。資料來源代表一個資料表,是以連接至資料庫元件 (如:TPSQLDatabase, TSQLiteDataSet) 的 DataSet 屬性所選定的。資料感知元件位於「資料控制」籤頁內。資料來源及資料庫控制元件則位於「資料存取」的籤頁內。

Lazarus 與 MySQL

讓 MySQL 在 Linux 或 Windows 中動起來

照著 MySQL 使用手冊裡的指示,讓 mysqld 程序於背景執行。對於所有潛在的主機來源 (包含本機 'localhost',本機的名稱和其他透過網路連線的主機),所有的用戶 (包含根使用者,mysql,你自己和其他所有會用到的人) 都要設定使用權限。也要儘可能的達到安全性要求,所有使用者,包含根使用者都要有一個密碼。接著使用手冊上的範例方法來測試確定所有使用者在系統上的權限都安全可靠。

在文字模式中讓 MySQL 為 FPC 工作

在 $(fpcsrcdir)/packages/base/mysql/ 資料夾中有一個範例程式。你可以在 Lazarus 的 fpc 原始碼資料夾中找到:[環境]選單 -> [環境]選項 -> [路徑]籤頁 ->[FPC 原始碼目錄]。 mysql 的範例資料夾可能的路徑為 /usr/share/fpcsrc/packages/base/mysql/ (rpm 安裝) 或者 C:\lazarus\fpcsrc\packages\base\mysql\ (Windows)。 這個資料夾也包含了 mysql.pp, mysql_com.pp 和 mysql_version.pp。 執行這些指令碼前,你必須先建立一個 testdb 資料庫:請登入 mysql 監視器 (以根使用者登入來取得完整權限) 並執行以下 SQL 指令

CREATE DATABASE testdb;

接著確認所有相關使用者擁有適當的存取權限

GRANT ALL ON testdb TO johnny-user IDENTIFIED BY 'johnnyspassword'; 

現在你應試著去執行一個叫 mkdb 的指令碼:

sh ./mkdb

這個指令應該會失敗, 因為系統不會允許匿名者存取資料庫。所以必須修改這個指令碼讓 mysql 讀取以下這行:

mysql -u root -p  ${1-testdb} << EOF >/dev/null

接著試著再執行一次,系統提示要你輸入密碼。幸運的話你應該就可以管理剛建立的資料庫了。用以下的 mysql 指令測試一下(在 mysql 監視器中):

select * from FPdev;

即可看到一個列有 ID,使用者名稱和 Email 地址的FPC 開發者資料表了。

現在可以執行測試程式 testdb.pp 了 (這檔也許還需要先編譯過,而且可能會在第一次編譯出錯!!)。

我找出這支程式可能無法連結 MySQL 的幾個原因:

  • 我的系統 (SuSE Linux v9.0) 安裝的是 mysql v4.0.15,不同於安裝套件的版本 3。
  • 程式需要輸入使用者和密碼來存取資料庫。
  • 編譯器需要知道哪裡可以找到 MySQL 的函式庫 (如果你並沒有安裝 MYSQL 的開發函式庫,那現在快裝!)

我將 testdb.pp 另存成 trydb.pp,然後做修改 - 這樣代表原來那支還是可以隨後透過 CVS 更新。 我另外也將在 mysql/ver40/ 子目錄下找到的那支另存成 mysql_v4.pp,mysql_com_v4.pp 和 mysql_version_v4.pp,記得你單元裡的程式也要改成適當的檔名。在 trydb.pp 裡我變更 uses 敘述句為

uses mysql_v4

mysql_v4.pp 的敘述句改為

uses mysql_com_v4

另外為要使用的函式庫加入一行到 /etc/fpc.cfg 裡:

-Fl/lib;/usr/lib

接下來的動作也許不必要做,因為你在安裝開發函式庫的時候應該會自動幫你建立連結,但檢查一下總是無仿。 進行前需要先找到我的 MYSQL 用戶端函式庫是放在 /usr/lib 目錄下面的哪裡,我的狀況是先下 shell 指令:

ln -s libmysqlclient.so.12.0.0 lmysqlclient

建立一個軟連結讓 FPC 可以找的到函式庫。為了更準確一些我再建立一個連結

ln -s libmysqlclient.so.12.0.0 mysqlclient

然後放一個相同的連結在不同的其他目錄裡:不是必需,視請況而定! 然後有些使用者也許會需要增加如下的連結:

ln -s libmysqlclient.so.12.0.0 libmysqlclient.so

我修改 trydb.pp 的內容,含括進使用者連線資訊,從上到下計的內容有主機,使用者與密碼:

const
  host : Pchar= 'localhost';
  user : Pchar= 'myusername';
  passwd: Pchar = 'mypassword';

我還發現我忽叫 mysql_connect() 還是無法連上 MySQL,但使用 mysql_real_connect() ,加上一堆參數後就可以了。未來還會更複雜,參數的數目似乎從 3 版(七個)換到 4 版(八個)還有變化。在使用 mysql_real_connect 之前我還得先使用 mysql_init(),但這在原始的 mysql.pp 裡並找不到,但出現於 mysql_v4.pp。

所以連線的程式碼將會是現在這樣:

{一些額外的變數}
var
  alloc : PMYSQL;
 
{主程式片段}
 
begin
 if paramcount=1 then
   begin
   Dummy:=Paramstr(1)+#0;
   DataBase:=@Dummy[1];
   end;
 
Writeln ('Allocating Space...');
 alloc := mysql_init(PMYSQL(@qmysql));
 Write ('Connecting to MySQL...');
 sock :=  mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
 if sock=Nil then
   begin
   Writeln (stderr,'Couldnt connect to MySQL.');
   Writeln (stderr, 'Error was: ', mysql_error(@qmysql));
   halt(1);
   end;
 Writeln ('Done.');
 Writeln ('Connection data:');
{$ifdef Unix}
 writeln ('Mysql_port      : ',mysql_port);
 writeln ('Mysql_unix_port : ',mysql_unix_port);
{$endif}
 writeln ('Host info       : ',mysql_get_host_info(sock));
 writeln ('Server info     : ',mysql_stat(sock));
 writeln ('Client info     : ',mysql_get_client_info);
 
 Writeln ('Selecting Database ',DataBase,'...');
 if mysql_select_db(sock,DataBase) < 0 then
   begin
   Writeln (stderr,'Couldnt select database ',Database);
   Writeln (stderr,mysql_error(sock));
   halt (1);
   end;
{... as original contents of testdb.pp}


現在 - 準備好開始編譯 trydb.pp 了嗎?

 fpc trydb

成功!現在執行:

 ./trydb

哇!我能讀取得到 FPC 開發者的清單了!

想要更精進的話:將使用者連線資訊的部份與 MySQL 的指令做成互動的模式,使用變數而不使用常數,如此可以在你退出 MySQL 前輸入多個 SQL 指令:參見所有程式列表,當使用者資訊是從主控台模式輸入取得時,程式將要利用迴圈,讓 SQL 的指令可以重覆輸入 (可以不用分號做結尾),然後再將回應顯示出來,直到使用者鍵入 'quit' 為止。

參見主控台範例清單

Connecting to MySQL from a Lazarus Application

This tutorial shows how to connect Lazarus to the MySQL database, and execute simple queries, using only the basic Lazarus components; it uses no Data Aware components, but illustrates the principles of interfacing with the database.

Create a new project in Lazarus:

Project -> New Project -> Application

A new automatically generated Form will appear.

Enlarge the form to fill about half of the screen, then re-name the form and its caption to 'TryMySQL'.

From the Standard Component tab place three Edit Boxes on the upper left side of the Form, and immediately above each box place a label. Change the names and captions to 'Host' (and HostLLabel,HostEdit), 'UserName' (and UserLabel, UserEdit) and 'Password' (with PasswdLabel and PasswdEdit). Alternatively you could use LabelledEdit components from the Additional tab.

Select the Passwd Edit box and find the PasswordChar property: change this to * or some other character, so that when you type in a password the characters do not appear on your screen but are echoed by a series of *s. Make sure that the Text property of each edit box is blank.

Now place another Edit box and label at the top of the right side of your form. Change the label to 'Enter SQL Command' and name it CommandEdit.

Place three Buttons on the form: two on the left under the Edit boxes, and one on the right under the command box.

Label the buttons on the left 'Connect to Database' (ConnectButton)and 'Exit' (ExitButton) and the one on the right 'Send Query' (QueryButton).

Place a large Memo Box labelled and named 'Results' (ResultMemo) on the lower right, to fill most of the available space. Find its ScrollBars property and select ssAutoBoth so that scroll bars appear automatically if text fills the space. Make the WordWrap property True.

Place a Status Bar (from the Common Controls tab) at the bottom of the Form, and make its SimpleText property 'TryMySQL'.

A screenshot of the Form can be seen here: Mysql Example Screenshot

Now we need to write some event handlers.

The three Edit boxes on the left are for entry of hostname, username and password. When these have been entered satisfactorily, the Connect Button is clicked. The OnCLick event handler for this button is based on part of the text-mode FPC program above.

The responses from the database cannot now be written using the Pascal write or writeln statements: rather, the replies have to be converted into strings and displayed in the Memo box. Whereas the Pascal write and writeln statements are capable of performing a lot of type conversion 'on the fly', the use of a memo box for text output necessitates the explicit conversion of data types to the correct form of string, so Pchar variables have to be converted to strings using StrPas, and integers have to be converted with IntToStr.

Strings are displayed in the Memo box using

procedure ShowString (S : string);
(* display a string in a Memo box *)
begin
       trymysqlForm1.ResultsMemo.Lines.Add (S)
end;

The ConnectButton event handler thus becomes:

procedure TtrymysqlForm1.ConnectButtonClick(Sender: TObject);
(* Connect to MySQL using user data from Text entry boxes on Main Form *)
var strg: string;
 
begin
 
 dummy1 :=  trymysqlForm1.HostEdit.text+#0;
 host := @dummy1[1];
 dummy2 := trymysqlForm1.UserEdit.text+#0;
 user := @dummy2[1] ;
 dummy3 := trymysqlForm1.PasswdEdit.text+#0;
 passwd := @dummy3[1] ;
 alloc := mysql_init(PMYSQL(@qmysql));
 sock :=  mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
 if sock=Nil then
   begin
     strg :='Couldnt connect to MySQL.'; showstring (strg);
     Strg :='Error was: '+ StrPas(mysql_error(@qmysql)); showstring (strg);
  end
   else
   begin
     trymysqlForm1.statusBar1.simpletext := 'Connected to MySQL';
     strg := 'Now choosing database : ' + database; showstring (strg);
{$ifdef Unix}
     strg :='Mysql_port      : '+ IntToStr(mysql_port); showstring (strg);
     strg :='Mysql_unix_port : ' + StrPas(mysql_unix_port); showstring (strg);
{$endif}
     Strg :='Host info       : ' + StrPas(mysql_get_host_info(sock));
     showstring (strg);
     Strg :='Server info     : ' + StrPas(mysql_stat(sock)); showstring (strg);
     Strg :='Client info     : ' + Strpas(mysql_get_client_info);  showstring (strg);
 
     trymysqlForm1.statusbar1.simpletext := 'Selecting Database ' + DataBase +'...';
 if mysql_select_db(sock,DataBase) < 0 then
 begin
   strg :='Couldnt select database '+ Database; ShowString (strg);
   Strg := mysql_error(sock); ShowString (strg);
 end
 end;
end;


The Text Box on the right allows entry of a SQL statement, without a terminal semicolon; when you are satisfied with its content or syntax, the SendQuery button is pressed, and the query is processed, with results being written in the ResultsMemo box.

The SendQuery event handler is again based on the FPC text-mode version, except that once again explicit type-conversion has to be done before strings are displayed in the box.

A difference from the text-mode FPC program is that if an error condition is detected, the program does not halt and MySQL is not closed; instead, control is returned to the main form and an opportunity is given to correct the entry before the command is re-submitted. The application finally exits (with closure of MySQL) when the Exit Button is clicked.

The code for SendQuery follows:

procedure TtrymysqlForm1.QueryButtonClick(Sender: TObject);
var
 dumquery, strg: string;
begin
     dumquery := TrymysqlForm1.CommandEdit.text;
     dumquery := dumquery+#0;
     query := @dumquery[1];
     trymysqlForm1.statusbar1.simpletext := 'Executing query : '+ dumQuery +'...';
     strg := 'Executing query : ' + dumQuery; showstring (strg);
     if (mysql_query(sock,Query) < 0) then
     begin
       Strg :='Query failed '+ StrPas(mysql_error(sock)); showstring (strg);
     end
     else
     begin
       recbuf := mysql_store_result(sock);
       if RecBuf=Nil then
       begin
         Strg :='Query returned nil result.'; showstring (strg);
       end
       else
       begin
         strg :='Number of records returned  : ' + IntToStr(mysql_num_rows (recbuf));
         Showstring (strg);
         Strg :='Number of fields per record : ' + IntToStr(mysql_num_fields(recbuf));
         showstring (strg);
         rowbuf := mysql_fetch_row(recbuf);
         while (rowbuf <>nil) do
         begin
              Strg :='(Id: '+ rowbuf[0]+', Name: ' + rowbuf[1]+ ', Email : ' +
               rowbuf[2] +')';
              showstring (strg);
              rowbuf := mysql_fetch_row(recbuf);
         end;
       end;
     end;
end;


Save your Project, and press Run -> Run

Download MYSQL Source Code

A full listing of the program is available here Sample Source Code

Simple MySQL Demo Using the TMySQL50Connection Component

Here is code that functions as a quick demo to get up and running simply (tested on Win XP with Lighty2Go). libmysql.dll was put in the project and lazarus.exe directories (available from a directory in Lighty2Go). There is no requirement to place any components on the form other than the three edit boxes, a memo box and a few buttons. You need to add mysql50conn and sqldb to the uses statement. The Lazarus component directory must be rw for the programmer. The mysql dbms here has a user 'root' with no password, and a database test1 with table tPerson which has three fields: personid (int), surname (varchar(40)) and dob (datetime). phpMyAdmin (in Lighty2Go) was used to create the db, table and fields and insert some sample data. Note that dates in phpMyAdmin should be entered YYYY-MM-DD, though the program created below will accept dates in the usual formats. The button btnTest must be clicked first as it creates the connection with the dbms. Note the line that applies updates - without this the changed or new data will not be written back to the db though they will be in memory and can be viewed using btnFirst and btnNext.

unit unt_db;
//Example based on:
//http://www.lazarus.freepascal.org/index.php?name=PNphpBB2&file=viewtopic&t=5761
//from tpglemur on that forum
{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  mysql50conn, sqldb, StdCtrls;
type
  { TForm1 }
  TForm1 = class(TForm)
    btnTest: TButton;
    btnNext: TButton;
    btnFirst: TButton;
    btnNew: TButton;
    edtPersonID: TEdit;
    edtSurname: TEdit;
    edtDOB: TEdit;
    Memo1: TMemo;
    procedure btnFirstClick(Sender: TObject);
    procedure btnNewClick(Sender: TObject);
    procedure btnNextClick(Sender: TObject);
    procedure btnTestClick(Sender: TObject);
  private
    { private declarations }
    conn : TMySQL50Connection;
    query : TSQLQuery;
    transaction : TSQLTransaction;
    procedure Display;
  public
    { public declarations }
  end;
var
  Form1: TForm1;
implementation
{ TForm1 }
procedure TForm1.btnTestClick(Sender: TObject);
var
  S: String;
begin
  conn := TMySQL50Connection.Create(nil);
  query := TSQLQuery.Create(nil);
  transaction := TSQLTransaction.Create(nil);
  try
    try
      conn.HostName := '127.0.0.1';
      conn.UserName := 'root';
      conn.Password := '';
      conn.DatabaseName := 'test1';
      conn.Connected := True;
      conn.Transaction := transaction;
      query.DataBase := conn;
      //query.ParseSQL := true; //line not needed - this is the default anyway
      //query.ReadOnly := false; //line not needed - this is the default anyway
      query.SQL.Text := 'select * from tperson';
      query.Open;

      query.Last;
      S := IntToStr(query.RecordCount) + #13#10;
      query.First;

      while not query.EOF do
      begin
        S := S + query.FieldByName('surname').AsString + #13#10;
        query.Next;
      end;
    finally
      //query.Free;
      //conn.Free;
    end;
  except
    on E: Exception do
      ShowMessage(E.message);
  end;
  Memo1.Text:= S;
end;

procedure TForm1.Display;
begin
  edtPersonID.Text := query.FieldByName('personid').AsString;
  edtSurname.Text := query.FieldByName('surname').AsString;
  edtDOB.Text := query.FieldByName('dob').AsString;
end;

procedure TForm1.btnFirstClick(Sender: TObject);
begin
  query.First;
  Display;
end;

procedure TForm1.btnNewClick(Sender: TObject);
begin
  query.Append;
  query.FieldValues['personid'] := edtPersonID.Text;
  query.FieldValues['surname'] := edtSurname.Text;
  query.FieldValues['dob'] := edtDOB.Text;
  query.Post;  
  query.ApplyUpdates; //to apply update
  //transaction.Commit; //line not needed
end;

procedure TForm1.btnNextClick(Sender: TObject);
begin
  query.Next;
  Display;
end;

initialization
  {$I unt_db.lrs}
end.

Here is a version using the TMySQL50Connection, TSQLQuery, TSQLTransaction, TDatasource and TDBGrid components that have been placed on the form:

unit unt_mysql2;
{$mode objfpc}{$H+}
interface
uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
  mysql50conn, sqldb, StdCtrls, db, DBGrids, DbCtrls;
type
  { TForm1 }
  TForm1 = class(TForm)
    btnConnect: TButton;
    btnSave: TButton;
    btnNext: TButton;
    btnPrior: TButton;
    Datasource1: TDatasource;
    DBGrid1: TDBGrid;
    Memo1: TMemo;
    MySQL50Connection1: TMySQL50Connection;
    SQLQuery1: TSQLQuery;
    SQLTransaction1: TSQLTransaction;
    procedure btnConnectClick(Sender: TObject);
    procedure btnNextClick(Sender: TObject);
    procedure btnPriorClick(Sender: TObject);
    procedure btnSaveClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
    procedure FormCreate(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end; 
var
  Form1: TForm1; 
implementation
{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  //Set properties of components:
  //(could be done in the Object Inspector)
  MySQL50Connection1.HostName := '127.0.0.1';
  MySQL50Connection1.UserName := 'root';
  MySQL50Connection1.Password := '';
  MySQL50Connection1.DatabaseName := 'test1';
  MySQL50Connection1.Transaction := SQLTransaction1;
  //SQLQuery1.ParseSQL := true; //line not needed - this is the default
  //SQLQuery1.ReadOnly := false; //line not needed - this is the default
  SQLQuery1.SQL.Text := 'select * from tperson';
  SQLQuery1.Transaction := SQLTransaction1;
  SQLQuery1.UpdateMode := upWhereChanged;
  Datasource1.Dataset := SQLQuery1;
  DBGrid1.DataSource := Datasource1;;
end;

procedure TForm1.btnConnectClick(Sender: TObject);
var
 S : string;
begin
  try
    MySQL50Connection1.Connected := true;
    SQLQuery1.Open;

    //Tests to see if all is OK:
    SQLQuery1.Last;
    S := IntToStr(SQLQuery1.RecordCount) + #13#10;
    SQLQuery1.First;
    while not SQLQuery1.EOF do
    begin
      S := S + SQLQuery1.FieldByName('surname').AsString + #13#10;
      SQLQuery1.Next;
    end;
  except
    on E: Exception do
      ShowMessage(E.message);
  end;
  Memo1.Text:= S;
end;

procedure TForm1.btnNextClick(Sender: TObject);
begin
  SQLQuery1.Next;
end;

procedure TForm1.btnPriorClick(Sender: TObject);
begin
  SQLQuery1.Prior;
end;

procedure TForm1.btnSaveClick(Sender: TObject);
begin
  SQLQuery1.ApplyUpdates;
end;

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  //Required or get EDatabase error on close:
  MySQL50Connection1.Connected := false;
end;

initialization
  {$I unt_mysql2.lrs}
end.

Lazarus and PostgreSQL

This is a very short tutorial to get Lazarus 0.9.12 or later to connect to a PostgreSQL database, local or remote, using TPQConnection.

After correct install, follow these steps:

  • Place a PQConnection from the SQLdb tab
  • Place a SQLQuery from the SQLdb tab
  • Place a SQLTransaction from the SQLdb tab
  • Place a DataSource from the DataAccess tab
  • Place a DBGrid from the DataControls tab
  • In the PQConnection fill in:
    • transaction property with the respective SQLTransaction object
    • Database name
    • HostName
    • UserName + password
  • Check that the SQLTransaction was automatically changed to point to the PQConnection
  • In the SQLQuery fill in:
    • transaction property with the respective object
    • database property with respective object
    • SQL (something like 'select * from anytable')
  • In the DataSource object fill in the DataSet property with the SQLQuery object
  • In the DBGrid fill in the datasource as the DataSource Object

Turn everything to connected and active and the DBGrid should be filled in design time. TDBText and TDBEdit seem to work but (for me) they only _show_ _data_.

To change contents in the database, I called the DB Engine direct with the following code:

 try
   sql:= 'UPDATE table SET setting=1';
   PQDataBase.Connected:=True;
   PQDataBase.ExecuteDirect('Begin Work;');
   PQDataBase.ExecuteDirect(sql);
   PQDataBase.ExecuteDirect('Commit Work;');
   PQDataBase.Connected:=False;
 except
   on E : EDatabaseError do
     MemoLog.Append('DB ERROR:'+sql+chr(13)+chr(10)+E.ClassName+chr(13)+chr(10)+E.Message);
   on E : Exception do
     MemoLog.Append('ERROR:'+sql+chr(13)+chr(10)+E.ClassName+chr(13)+chr(10)+E.Message);
 end;


  • Notes:
    • Tested on windows, Lazarus 0.9.12 + PgSQL 8.3.1
    • Some tests in linux, Lazarus 0.9.12 and PgSQL 8.0.x


  • Instalation and errors:
    • In the tested version of Lazarus .12, fields of type "text" and "numeric" have bugs
    • I used with no problems char fixed size, int and float8
    • Sometimes restarting Lazarus solves stupid errors...
    • After some errors, the transactions remain active and should be deactivated mannually
    • Changes made in Lazarus are of course not visible until transaction commited
    • The integrated debugger seems buggy (at least in windows) - sometimes running outside of the IDE may help to find errors
    • In linux certain error messages are printed in the console -- run your program in the command line, sometimes there is some extra useful debugging info
    • Error: "Can not load Postgresql client. Is it installed (libpq.so) ?"
      • Add the path to seach libpq* from the PostgreSQL installation.
      • In linux add the path to the libpq.so file to the libraries section in your /etc/fpc.cfg file. For example : -Fl/usr/local/pgsql/lib
      • In windows, add these libs anywhere in the Path environment variable or project dir
      • I windows, I copied all the DLLs in my C:\Program Files\PostgreSQL\8.1\bin dir to another dir in the PATH
      • Or add this postgres\bin dir to the path

Lazarus 與 SQLite

by Luiz Américo

請至 sqlite4fpc homepage 取得 API reference 與更多的教材。

前言

TSqliteDataset 與 TSqlite3Dataset 繼承自 TDataset, 個自分別可存取 2.8.x 與 3.x.x sqlite 資料庫。 以下是使用Sqlite主要的優缺點:

優點:

  • 靈活: 程式設計師可以選擇使用或不使用SQL 語言,允許他們使用SQL/sqlite容許的簡單的表格配置或是任何複雜的配置
  • 自動更新資料庫: 不需要手動更新資料庫使用SQL 述敍, 單一方法來照顧它
  • 快速: 它的快取資料是放在記憶體, 使的瀏覽資料集是相當的快速
  • 沒有伺服器的安裝/設定: 只是包裝在sqlite 動態函式庫

缺點:

  • 要求外部的檔案 (sqlite 函式庫)

需求

  • For sqlite2 databases:
    • fpc 2.0.0
    • Lazarus 0.9.10
    • sqlite runtime library 2.8.15 or above (get from www.sqlite.org)
  • For sqlite3 databases:
    • fpc 2.0.2
    • Lazarus 0.9.11 (svn revision 8443 or above)
    • sqlite runtime library 3.2.1 or above (get from www.sqlite.org)

開始一個 lazarus 專案前, 請先確認以下事項:

  • the sqlite library is on the system PATH or in the executable directory
  • under Linux, put cmem as the first unit in uses clause of the main program
    • In Debian, Ubuntu and other Debian-like distros, in order to build Lazarus IDE you must install the packages libsqlite-dev/libsqlite3-dev, not only sqlite/sqlite3 (Also applies to OpenSuSe)

使用方法 (基本)

安裝 /components/sqlite 資料夾中的 package (安裝教材 here)

於設計模式下設定以下屬性

  • FileName: sqlite 檔案的路徑 [必要]
  • TableName: sql 語法中使用的表格(table)名稱 [必要]
  • Sql: 一個 SQL 的 select 語法 [非必要]

建立一個 Table (Dataset)

雙按元件圖示, 或點選右鍵選單中的 'Create Table'。便會出現一個簡單的表格編輯器。

 以下是 TSqliteDataset 與 TSqlite3Dataset 所支援的所有欄位格式:
 Integer
 AutoInc
 String
 Memo
 Bool 
 Float
 Word
 DateTime
 Date
 Time
 LargeInt
 Currency
 

取得資料

建立 Table 後, 或者在已有的 Table。以 Open 方法開啟 dataset。 如果 SQL 屬性沒有設定內容, 則所有的資料與欄位都會被傳回, 效果與以下指令相同:

 SQL:='Select * from TABLENAME'; 

修改資料 Applying changes to the underlying datafile

使用 ApplyUpdates 函式前, dataset 須包含至少一個主鍵欄位填入需求(必須為唯一且非 Null 值)

To use the ApplyUpdates function, the dataset must contain at least one field that fills the requirements for a Primary Key (values must be UNIQUE and not NULL)

這可以由兩種方式來達成:

It's possible to do that in two ways:

  • 設定 PrimaryKey 屬性為主鍵欄位的名稱
  • Set PrimaryKey property to the name of a Primary Key field
  • 新增一個 AutoInc 欄位(這比較簡單, 因為 TSqliteDataSet 會自行將此欄位當成主鍵)
  • Add an AutoInc field (This is easier since the TSqliteDataSet automatically handles it as a Primary Key)

以上兩個條件設定好其中一個後, 只要呼叫以下指令

If one of the two conditions is set then just call

 ApplyUpdates;

備註1: 若兩個條件都有設定, 則欄位會使用 PrimaryKey 來更新資料 PS1: If both conditions are set, the field corresponding to PrimaryKey is used to apply the updates.

備註2: 若 PrimaryKey 被指定的欄位不是主鍵, 則呼叫 ApplyUpdates 可能會造成資料的遺失, 所以請確定所選擇的欄位值是唯一且非 Null 值。 PS2: Setting PrimaryKey to a field that is not a Primary Key will lead to loss of data if ApplyUpdates is called, so ensure that the chosen field contains not Null and Unique values before using it.

Remarks

  • Although it has been tested with 10000 records and worked fine, TSqliteDataset keeps all the data in memory, so remember to retrieve only the necessary data (principally with Memo Fields).
  • The same datafile (Filename property) can host several tables/datasets
  • Several datasets (different combinations of fields) can be created using the same table simultaneously
  • It's possible to filter the data using WHERE statements in the sql, closing and reopening the dataset (or calling RefetchData method). But in this case, the order and number of fields must remain the same
  • It's also possible to use complex SQL statements using aliases, joins, views in multiple tables (remember that they must reside in the same datafile), but in this case ApplyUpdates won't work. If someone wants to use complex queries and to apply the updates to the datafile, mail me and I will give some hints how to do that
  • Setting filename to a sqlite2.x datafile not created by TSqliteDataset and opening it is allowed but some fields won't have the correct field type detected. These will be treated as string fields.

Generic examples can be found at fpc/fcl/db/sqlite CVS directory

Luiz Américo pascalive(at)bol(dot)com(dot)br

Lazarus and MSSQL

It is working with Zeoslib (latest cvs), see the links on bottom of page.

Lazarus and Interbase / Firebird

請看 Install Packages. 在這一頁是一個小的範例解釋如何連線到一個 IB 或 FB 主機.

也可以工作使用最後Zeoslib的版本 (取自 cvs).

FBLib Firebird Library

[1]是一個開放原始碼函式庫沒有資料 is an open Source Library No Data Aware for direct access to Firebird Relational Database from Borland Delphi / Kylix, Freepascal and Lazarus.

Current Features include:

  • Direct Access to Firebird 1.0.x 1.5.x Classic or SuperServer
  • Multiplatform [Win32,Gnu/Linux,FreeBSD)
  • Automatic select client library 'fbclient' or 'gds32'
  • Query with params
  • Support SQL Dialect 1/3
  • LGPL License agreement
  • Extract Metadata
  • Simple Script Parser
  • Only 100-150 KB added into final EXE
  • Support BLOB Fields
  • Export Data to HTML SQL Script
  • Service manager (backup,restore,gfix...)
  • Events Alerter

You can download documentation on FBLib's website.

Lazarus and dBase

Tony Maro

You might also want to visit the beginnings of the TDbf Tutorial page

FPC includes a simple database component that is similar in function to the Delphi TTable component called "TDbf" (TDbf Website) that supports a very basic subset of features for dBase files. It is not installed by default, so you will first need to install the Lazarus package from the "lazarus/components/tdbf" directory and rebuild your Lazarus IDE. It will then appear next to the TDatasource in your component palette (Data Access tab).

The TDbf component has an advantage over other database components in that it doesn't require any sort of runtime database engine. However it's not the best option for large database applications.

It's very easy to use. Simply drop a TDbf on your form, set the runtime path to the directory that your database files will be in, set the table name, and link it to your TDatasource component.

Real functionality requires a bit more effort, however. If a table doesn't already exist, you'll need to create it programmatically, unless there's a compatible table designer I'm not familiar with. Note: Current version of OpenOffice (2.0x) contains OpenOffice Base, which can create dbf files in a somewhat user-friendly way.

Attempting to open a nonexistent table will generate an error. Tables can be created programmatically through the component after the runtime path and table name are set.

For instance, to create a table called "dvds" to store your dvd collection you would drop it on your form, set the runtime path, and set the table name to "dvds". The resulting file will be called "dvds.dbf".

In your code, insert the following:

   Dbf1.FilePathFull := '/path/to/my/database';
   Dbf1.TableName := 'dvds';
   With Dbf1.FieldDefs do begin
       Add('Name', ftString, 80, True);
       Add('Description', ftMemo, 0, False);
       Add('Rating', ftString, 5, False);
   end;
   Dbf1.CreateTable;

When this code is run, your DVD collection table will be created. After that, all data aware components linked through the TDatasource to this component will allow easy access to the data.

Adding an index is a little different from your typical TTable. It must be done after the database is open. You use the same method also to rebuild the indices. For instance:

   Dbf1.Exclusive := True;
   Dbf1.Open;
   Dbf1.AddIndex('dvdsname','Name',[ixPrimary, ixUnique, ixCaseInsensitive]);
   Dbf1.AddIndex('rating.ndx', 'Rating', [ixCaseInsensitive]);
   Dbf1.Close;

The first (primary) index will be a file called "dvdsname.mdx" and the second will be a file named "rating.ndx" so in a multiple table database you must be careful not to use the same file name again.

I will try to add a more detailed example at a later date, but hopefully this will get those old Delphi programmers up and running with databases in Lazarus!


Searching and Displaying a data set

Simon Batty

In this example I wanted to search a database of books for all the titles an author has listed and then display the list in a memo box


   Dbf1.FilePathFull := '/home/somelocatio/database_location/'; // path to the database directory
   Dbf1.TableName := 'books.dbase';                             // database file (including extension)
   DbF1.Open;
   memo1.Clear;                                                 // clear the memo box
   Dbf1.FilterOptions := [foCaseInsensitive];
   Df1.Filter := 'AU=' + QuotedStr('anauthor');         // AU is the field name containing the authors
   Dbf1.Filtered := true;       // This selects the filtered set
   Dbf1.First;                  // moves the the first filtered data
   while not dbf1.EOF do        // prints the titles that match the author to the memo box
   begin
       memo1.Append(Dbf1.FieldByName('TI').AsString); // TI is the field name for titles
       dbf1.next;                                     // use .next here NOT .findnext!
   end;
   Dbf1.Close;   

Note that you can use Ddf1.findfirst to get the first record in the filtered set, then use Dbf1.next to move though the data. I found that using Dbf1.Findnext just causes the program to hang.

This database was generated using TurboBD that came with the Kylix 1. I cannot get TurboBD tables to work with Lazarus, however you can download a command line tool from TurboDB's website that allows you to convert TurboDB table to other formats.

Using TSdfDataset and TFixedDataset

TSdfDataset and TFixedDataset are two simple datasets which offer a very simple textual storage format. These datasets are very convenient for small databases, because they are fully implemented as an object pascal unit, and thus require no external libraries, and because their textual format allows them to be easely edited with a text editor.

To start with this formats, a initial database file should be created. The format is very simple, so use a text editor to do this.

Bellow is a sample database for TSdfDataset. Note that the first line has the names of the fields and that we are using commas as separators:

ID,NAMEEN,NAMEPT,HEIGHT,WIDTH,PINS,DRAWINGCODE
1,resistor,resistor,1,1,1,LINE
2,capacitor,capacitor,1,1,1,LINE
3,transistor npn,transistor npn

And here is an example database for using with TFixedDataset. Each record occupies a fixed amount of space, and if the field is smaller then it, spaces should be used to fill the remaining size.

Name = 15 chars; Surname = 15 chars; Tell = 10 chars; e_mail = 20 chars;
Piet           Pompies                  piet@pompies.net    

Using the datasets directly

Sometimes it is useful to create the dataset and work with it completely in code, and the following code will do exactly this. Note some peculiarities of TSdfDataset/TFixedDataset:

  • The lines in the database can have a maximum size of about 300. A fix is being researched.
  • It is necessary to add the field definitions. Some datasets are able to fill this information alone from the database file
  • One should set FirstLineAsSchema to true, to indicate that the first line includes the field names and positions
  • The Delimiter property holds the separator for the fields. It will not be possible to use this char in strings in the database. Similarly it will not be possible to have lineendings in the database because they mark the change between records. It's possible to overcome this by substituting the needed comma or line ending with another not often used char, like # for example. So that when showing the data on screen all # chars could be converted to line endings and the inverse when storing data back to the database. The ReplaceString routine is useful here.

<delphi> constructor TComponentsDatabase.Create; begin

 inherited Create;
 FDataset := TSdfDataset.Create(nil);
 FDataset.FileName := vConfigurations.ComponentsDBFile;
 // Not necessary with TSdfDataset

// FDataset.TableName := STR_DB_COMPONENTS_TABLE; // FDataset.PrimaryKey := STR_DB_COMPONENTS_ID;

 // Adds field definitions
 FDataset.FieldDefs.Add('ID', ftString);
 FDataset.FieldDefs.Add('NAMEEN', ftString);
 FDataset.FieldDefs.Add('NAMEPT', ftString);
 FDataset.FieldDefs.Add('HEIGHT', ftString);
 FDataset.FieldDefs.Add('WIDTH', ftString);
 FDataset.FieldDefs.Add('PINS', ftString);
 FDataset.FieldDefs.Add('DRAWINGCODE', ftString);
 // Necessary for TSdfDataset
 FDataset.Delimiter := ',';
 FDataset.FirstLineAsSchema := True;
 FDataset.Active := True;
 // Sets the initial record
 CurrentRecNo := 1;
 FDataset.First;

end; </delphi>

When using TSdfDataset directly be aware that RecNo, although it is implemented, does not work as a way to move through the dataset whether reading or writing records. The standard navigation routines like First, Next, Prior and Last work as expected, so you need to use them rather than RecNo. If you are used to using absolute record numbers to navigate around a database you can implement your own version of RecNo. Declare a global longint variable called CurrentRecNo which will hold the current RecNo value. Remember that this variable will have the same convention as RecNo, so the first record has number 1 (it is not zero-based). After activating the database initialize the database to the first record with TSdfDataset.First and set CurrentRecNo := 1

<delphi> {@@

 Moves to the desired record using TDataset.Next and TDataset.Prior
 This avoids using TDataset.RecNo which doesn't navigate reliably in any dataset.
 @param AID Indicates the record number. The first record has number 1

} procedure TComponentsDatabase.GoToRec(AID: Integer); begin

 // We are before the desired record, move forward
 if CurrentRecNo < AID then
 begin
   while (not FDataset.EOF) and (CurrentRecNo < AID) do
   begin
     FDataset.Next;
     FDataset.CursorPosChanged;
     Inc(CurrentRecNo);
   end;
 end
 // We are after the desired record, move back
 else if CurrentRecNo > AID  then
 begin
   while (CurrentRecNo >= 1) and (CurrentRecNo > AID) do
   begin
     FDataset.Prior;
     FDataset.CursorPosChanged;
     Dec(CurrentRecNo);
   end;
 end;

end; </delphi>

Using with data-aware controls

Related Links

Contributors and Changes

This page has been converted from the epikwiki version.