Command line parameters and environment variables/fr

│ English (en) │ español (es) │ suomi (fi) │ français (fr) │ русский (ru) │

Présentation

Quand un programme est démarré, un utlisateur peut transmettre des paramètres de ligne de commandes et définir des variables d'environnement. P. ex., le compilateur FreePascal obtient la plupart de ces paramètres via les options de ligne de commande:

 fpc -Fudirectory -gh unit1.pas

Paramètres de la ligne de commande

Les bases

Un programme Pascal peut accéder aux paramètres via les fonctions ParamStr et ParamCount. ParamStr(0) est le nom de programme lui-même (et le chemin d'accès _SI_ le système d'exploitation le permet). ParamStr(1) est le premier paramètre. ParamCount est le nombre de paramètres.

program Project1;

{$mode objfpc}{$H+}

var
  I: Integer;
begin
  WriteLn('Programme: ', ParamStr(0));
  for I := 1 to ParamCount do
    WriteLn('Param ', I, ': ', ParamStr(I));
end.

P. ex.:

 $ /tmp/project1 -a
 Program: /tmp/project1
 Param 1: -a

Orienté utilisateur

Un bon programme devrait donner un message d'aide quand il est invoqué avec de mauvais paramètres et devrait suivre une manière commune dpour transmettre les paramètres. L'unité CustApp, qui vient avec FPC, fournit la classe TCustomApplication, laquelle fournit des fonctions pour contrôler et lire facilement des paramètres. Bien sûr, vous pouvez toujours accéder directement aux paramètres via ParamStr et ParamCount.

Toute application LCL utilise ceci automatiquement. L'objet Application est une TCustomApplication.

Si vous voulez écrire un programme non LCL, puis créer un nouveau projet dans Lazarus du type 'Application Console'. Ceci créera un project1.lpr avec quelques goodies sympas dont presque tous les programmes ont besoin. Allez à la méthode DoRun pour spécifier ce que fait votre programme.

Contrôler un paramètre

Avec TCustomApplication, vous pouvez accéder aux paramètres par leur nom. P. ex., votre programme pourrait afficher un texte d'aide quand l'utilisateur donne le paramètre d'aide courant -h. -h' est une option courte. La forme longue est le --help. Pour tester si l'utilisateur a appelé le programme avec -h ou --help, vous pouvez utiliser;

if HasOption('h', 'help') then begin
  WriteHelp;
  Halt;
end;

Note: Cela est valable dans la méthode DoRun. Dans une fiche LCL, vous devez qualifier HasOption avec Application.. P. ex.:

if Application.HasOption('h', 'help') then begin
  WriteHelp;
  Halt;
end;

// Si vous voulez seulement proposer l'option courte, utilisez:
if HasOption('h', '') then ...

//  Si vous voulez seulement proposer l'option longue, utilisez:
if HasOption('help') then ...

Contrairement à ce que laisse penser l'exemple de présentation, il n'est pas possible de cumuler plusieurs options courtes derrière un seul '-', ainsi -dh n'est pas reconnue comme une écriture condensée de -d -h.

Lire la valeur d'un paramètre

Chaque paramètre peut donner une valeur. Par exemple:

 project1 -f filename

ou avec la forme longue

 project1 --file=filename

WriteLn('f=', GetOptionValue('f', 'file'));

Note: si vous obtenez le message d'erreur Option at position 1 needs an argument : f. alors vous avez oubliez d'ajouter l'option dans l'appel CheckOptions.

Contrôler la validité de paramètres

Les paramètre de ligne de commande sont du texte libre, aussi l'utilisateur peut facilement taper des erreurs. Contrôler la syntaxe des paramètres est en conséquence obligatoire. Vous pouvez utiliser la méthode CheckOptions pour cela:

Vous pouvez définir quels paramètres sont permis, lesquels ont besoin d'un paramètre et en cas d'erreur de syntaxe, vous pouvez obtenir un message plus les mauvaises options pour afficher des erreurs utiles et détaillées.

Exemples:

ErrorMsg := CheckOptions('hf:', 'help file:');

Cela permet de transmettre des options courtes -f value et -h. Il permet de transmettre les options longues --help ou --file=filename. Il ne permet pas de passer --help avec une valeur, ni --file sans valeur.

Variables d'environnement

Trois fonctions de bases sont fournies pour travailler avec les variables d'environnement.

GetEnvironmentVariable

GetEnvironmentString

GetEnvironmentVariableCount

Exemple:

var
  I: Integer;
begin
  WriteLn('PATH = ' + GetEnvironmentVariable('PATH'));

  WriteLn('Toutes les variables d''environnement:');
  for I := 0 to GetEnvironmentVariableCount - 1 do 
    WriteLn(GetEnvironmentString(I));
end.

Il est aussi possible de charger toutes les variables d'environnement dans un objet TStringList et d'accéder à une paire nom-valeur de manière simple. En effet, la liste de chaîne manipule automatiquement le séparateur qui est par défaut '='.

var
  I: Integer;
  EnvVars: TStringList;
begin
  EnvVars := TStringList.Create;
  try
    // Charge toutes les variables dans une liste de chaînes
    for I := 0 to GetEnvironmentVariableCount - 1 do 
      EnvVars.Add(GetEnvironmentString(I));

    WriteLn('PATH = ' + EnvVars.Values['PATH']);

    WriteLn('Toutes les variables d''environnement:');
    for I := 0 to EnvVars.Count - 1 do 
      WriteLn(EnvVars.Names[I] + ' = ' + EnvVars.ValueFromIndex[I]);
  finally 
    EnvVars.Free;
  end;
end.