Dynamic array/ru

From Free Pascal wiki

English (en) suomi (fi) français (fr) 日本語 (ja) русский (ru)

Динамический массив - это массив, размеры которого неизвестны во время компиляции. Динамический массив не является единственным типом, предоставляющим массивы переменной длины, но с 2018 года он является единственным, который поддерживает FPC.

Использование

Концепция

Определение динамического массива будет выделять пространство только для указателя. Во время выполнения различные подпрограммы будут обеспечивать удобное использование, но что более важно, синтаксис доступа к элементам массива путем помещения индексов в квадратные скобки поддерживается компилятором (реализован как автоматическое разыменование указателя).

Индексы динамических массивов всегда являются неотрицательными целыми числами, начинающимися с нуля для первого элемента. Невозможно использовать перечислительный тип, любой другой порядковый тип в качестве индекса или изменить первый элемент, заданный индексом 1.

Определение

Одномерный динамический массив определяется так:

array of char

Обратите внимание, что размерность [массива] не указан.

Для определения многомерного массива в качестве базового типа указывается сам массив.

array of array of longInt

Задание размерности

Процедура компилятора setLength изменит длину динамического массива при условии, что памяти достаточно.

1 program setLengthDemo(input, output, stdErr);
2 var
3 	sieve: array of longWord;
4 begin
5 	setLength(sieve, 1337);
6 end.

Процедура выделяет память для стольких записей базового типа, сколько указано, плюс некоторые данные для управления. Затем она copies (копирует) все элементы старого массива в новый. Новые поля, которых раньше не было, инициализируются по умолчанию с помощью встроенного механизма.

Размер многомерных массивов также можно изменить с помощью setLength.

1 program multidimensionalSetLengthDemo(input, output, stdErr);
2 var
3 	samples: array of array of smallInt;
4 begin
5 	setLength(samples, 12, 64);
6 end.

Допустимые индексы для первого измерения выборки находятся в диапазоне 0..11, в то время как действительные индексы для его второго измерения находятся в диапазоне 0..63.

Один весьма полезный факт заключается в том, что ограничение в неизменности всех размеров [статического массива] не распространяется на динамические массивы.

 1 program binomialPotence(input, output, stdErr);
 2 var
 3 	pascalsTriangle: array of array of longWord;
 4 	exponent: longInt;
 5 	factor: longInt;
 6 begin
 7 	setLength(pascalsTriangle, 20);
 8 	
 9 	setLength(pascalsTriangle[0], 1);
10 	pascalsTriangle[0][0] := 1;
11 	
12 	setLength(pascalsTriangle[1], 2);
13 	pascalsTriangle[1][0] := 1;
14 	pascalsTriangle[1][1] := 1;
15 	
16 	// строим значения простым сложением
17 	for exponent := 2 to high(pascalsTriangle) do
18 	begin
19 		setLength(pascalsTriangle[exponent], exponent + 1);
20 		pascalsTriangle[exponent][0] := 1;
21 		pascalsTriangle[exponent][exponent] := 1;
22 		for factor := 1 to exponent - 1 do
23 		begin
24 			pascalsTriangle[exponent][factor] :=
25 				pascalsTriangle[exponent - 1][factor - 1] +
26 				pascalsTriangle[exponent - 1][factor];
27 		end;
28 	end;
29 	
30 	// ...

Инициализация

Начиная с FPC 3.0.0 типы динамических массивов, которые не являются анонимными, автоматически снабжаются «конструктором», как это возможно уже знакомо по объектно-ориентированному программированию. Это позволяет объединить вызовы setLength и серию присвоения значений в одном операторе:

1 program dynamicArrayCreateDemo(input, output, stdErr);
2 type
3 	truths = array of boolean;
4 var
5 	l: truths;
6 begin
7 	l := truths.create(false, true, true, false, true, false, false);
8 end.

Конечно, вы также можете вкладывать массивы:

 1 program nestedDynamicArrayCreateDemo(input, output, stdErr);
 2 type
 3 	truths = array of boolean;
 4 	pattern = array of truths;
 5 var
 6 	p: pattern;
 7 begin
 8 	p := pattern.create(
 9 			truths.create(false, false),
10 			truths.create(true, false),
11 			truths.create(true, false, false),
12 			truths.create(true, true, false)
13 		);
14 end.

Обращение

Имейте в виду, что динамические массивы являются указателями. Присвоение переменных динамического массива друг другу копирует не какую-либо полезную нагрузку, а только адрес. Это отличается от поведения статических массивов.

Если вы хотите дублировать данные, вы должны использовать system.copy.

 1 program dynamicArrayCopyDemo(input, output, stdErr);
 2 
 3 var
 4 	foo, bar: array of char;
 5 
 6 procedure printArrays;
 7 begin
 8 	writeLn('foo[0] = ', foo[0], '; bar[0] = ', bar[0]);
 9 end;
10 
11 begin
12 	setLength(foo, 1);
13 	foo[0] := 'X';
14 	// копируем _адрес_
15 	bar := foo;
16 	write('     начальное значение: ');
17 	printArrays;
18 	
19 	// изменяем содержимое _посредством_ _второго_ адреса 
20 	bar[0] := 'O';
21 	write('изменено посредством 2-го адр: ');
22 	printArrays;
23 	
24 	// копируем содержимое
25 	bar := copy(foo, 0, length(foo));
26 	bar[0] := 'X';
27 	write(' скопировано и изменено: ');
28 	printArrays;
29 end.

Только с помощью copy оба массива могут быть изменены независимо.

Как указано выше, setLength копирует данные. Выделенная строка в примере выше (семантически) эквивалентна setLength(bar, length(bar)).

Динамические массивы считаются ссылками. Вызов setLength(myDynamicArrayVariable, 0) фактически делает myDynamicArrayVariable:= nil и уменьшает количество ссылок. Только когда счетчик ссылок достигает нуля, блок памяти освобождается.

 1 program dynamicArrayNilDemo(input, output, stdErr);
 2 var
 3 	foo, bar: array of char;
 4 begin
 5 	setLength(foo, 1);
 6 	foo[0] := 'X';
 7 	// копируем ссылку, увеличиваем счетчик ссылок 
 8 	bar := foo;
 9 	// foo становится nil, счетчик ссылок уменьшается 
10 	setLength(foo, 0);
11 	writeLn('length(foo) = ', length(foo),
12 		'; length(bar) = ', length(bar));
13 	
14 	// уменьшаем количество ссылок в очередной раз
15 	bar := nil;
16 	writeLn('length(foo) = ', length(foo),
17 		'; length(bar) = ', length(bar));
18 end.

Тем не менее, динамические массивы финализируются автоматически. Нет необходимости вручную устанавливать setLength(, 0) для всех ваших ссылок, когда программа заканчивается или когда выходит из области видимости в целом.

Без {$rangeChecks on} возможен выход за пределы массива. Это означает, что при итерации по динамическим массивам невозможно работать без low и high значений, чтобы определить допустимые индексы (первый является необязательным, поскольку динамические массивы всегда начинаются с нуля). В качестве альтернативы можно использовать циклы for… in, если индекс не требуется.

Помните, что sizeOf динамического массива соответствует размеру указателя.

Приложение

См. также