Function/ru

From Free Pascal wiki
Jump to navigationJump to search

Deutsch (de) English (en) español (es) suomi (fi) français (fr) русский (ru)

Функция — это подпрограмма, которая, в отличие от процедур, возвращает значение. Вызов функции практически заменяется возвращаемым значением. Если состояние переключателя компилятора {$extendedSyntax} отключено, вызовы функций не могут отображаться как непродуктивные операторы, но должны быть целиком или частью выражения.

Слово function является зарезервированным словом.

Возвращаемое значение

В дополнение к обычной процедуре формальная сигнатура функции содержит тип возвращаемого значения: список формальных параметров должен сопровождаться двоеточием и типом возвращаемого значения. Например, следующая функция возвращает Boolean

function myFunction(const firstParameter: real): Boolean;

При реализации функций есть несколько способов определить возвращаемое значение функции.

 1program functionDemo(input, output, stderr);
 2
 3{$mode objFPC}
 4
 5// традиционный синтаксис:
 6// результат сохраняется в переменной
 7// его имя такое же, как у функции
 8function myLine(const x: real): real;
 9begin
10	myLine := 0.5 * x + 2;
11end;

Если {$modeswitch result+}, заданный {$mode objFPC} и {$mode Delphi}, внутри блока реализации также доступен результат специального идентификатора:

13// используя специальный идентификатор `result`
14function myParabola(const x: real): real;
15begin
16	result := sqr(x) - 1;
17end;

Кроме того, в {$mode objFPC} подпрограмма exit также установит возвращаемое значение и покинет стековый кадр. В предыдущих двух примерах могли появиться дополнительные операторы, и они были бы выполнены, уже после того, как exit подпрограмма выполнится. Это поведение оператора return в C или других языках программирования.

19// использование процедуры выхода exit
20function even(const x: longint): Boolean;
21begin
22  exit(not odd(x));
23end;

В языке ассемблера применяются другие правила. Если тип возвращаемого значения является целым числом, используется регистр-накопитель, при условии, что он помещается туда:

25// на ассемблере:
26// возвращаемый тип умещается в один регистр => использовать регистр-накопитель
27function zero(const x: int64): Boolean;
28{$ifDef CPUx86_64}
29assembler; register;
30{$asmMode intel}
31asm
32	// xor изменяет флаги => поместите его перед тестом
33	xor rax, rax     // rax := 0    (удалить остаток)
34	
35	test x, x        // x = 0 ?
36	setz al          // rax := ZF
37	
38        // Когда вы изучаете вывод ассемблера
39        // вы заметите, что компилятор автоматически вставляет код
40        // который перемещает содержимое rax в нужное место в стеке,
41        // пока не появится подсказка noStackFrame
42        // (автоматически устанавливается некоторыми уровнями оптимизации)
43        // инструктирует компилятор опустить кадр стека, если это возможно.
44end;
45{$else}
46begin
47	result := x = 0;
48end;
49{$endIf}

В противном случае, в зависимости от того, какой режим {$asmMode} активен, можно использовать макрос @result (Intel) или __result (AT&T).

51type
52	bodyAttributes = record
53		surfaceArea: real;
54		volume: real;
55	end;
56
57// на ассемблере:
58// возвращаемый тип не помещается в аккумулятор => макрос @result дает адрес
59function sphere(const radius: real): bodyAttributes;
60{$ifDef CPUx86_64}
61assembler;
62{$asmMode intel}
63const
64	three: longint = 3;
65	four: longint = 4;
66var
67	r: real;
68asm
69	pextrq r, radius, 0 // r := (@radius+0)^
70	lea rax, @result    // rax := @result
71	fld r               // radius
72	
73	fld st(0)           // radius radius
74	fild four           // 4 radius radius
75	fldpi               // pi 4 radius radius
76	fmul                // 4*pi radius radius
77	fxch                // radius 4*pi radius
78	fld st(0)           // radius radius 4*pi radius
79	fmul                // radius^2 4*pi radius
80	fmul                // 4*pi*radius^2 radius
81	fst [rax].bodyAttributes.surfaceArea
82	
83	fmul                // 4*pi*radius^3
84	fild three          // 3 4*pi*radius^3
85	fdivp               // 4/3*pi*radius^3
86	fst [rax].bodyAttributes.volume
87end;
88{$else}
89begin
90	sphere.surfaceArea := 4 * pi() * sqr(radius);
91	sphere.volume := 4 / 3 * pi() * sqr(radius) * abs(radius);
92end;
93{$endIf}

Первоначально Паскаль ожидал ровно одно присваивание переменной результата (в зависимости от того, что используется). Однако FPC не запрещает множественные присваивания. Он выдаст предупреждение, если не был использован ни один из возможных идентификаторов результата или процедура выхода не написана.

Warning
Function result does not seem to be set (рус. Предупреждение: результат функции, похоже, не установлен)
You can get this warning if the compiler thinks that a function return value is not set. This will not be displayed for assembler procedures, or procedures that contain assembler blocks.(рус. Вы можете получить это предупреждение, если компилятор считает, что возвращаемое значение функции не установлено. Это не будет отображаться для ассемблерных процедур или процедур, содержащих ассемблерные блоки.)
95begin
96	writeLn(sphere(2.0).surfaceArea);
97end.

Обратите внимание, что в случае перегрузок операторов в формальной подписи должен быть объявлен специальный вид функции, идентификатор переменной результата. Подробнее см. в статье.

Замечания

Pure functions это функции, не зависящие от внешнего состояния.

См.также