SQLdb Tutorial1/zh CN

From Lazarus wiki
Jump to navigationJump to search

│ Deutsch (de) │ English (en) │ español (es) │ français (fr) │ 日本語 (ja) │ 中文（中国大陆） (zh_CN) │

介绍(Introduction)

编撰目的: 通过实例演示SQLDB包的使用。

阅读对象: 数据库编程的初学者/新手。如果对文中涉及的数据库和SQL的基础知识不太清楚，请阅读相应的书籍。

使用的数据库： Firebird和她自带的示例数据库employee.fdb。不用Firebird也可以使用其它数据库，但需要作些调整，文中相应位置有补充说明。

文章太长？： 虽然本教程看起来很长，但笔墨大多用于解释要求你键入相关内容的原因。在文章末尾你可以看到，创建一个能够正常运行的应用程序，你实际上编写的代码量不是很大。对于许多有经验的开发者而言，你可以略读（就是忽略已经熟知的细节而快速翻阅各操作步骤的主要内容），并能迅速理解下一步将要做的事情。还嫌累赘的话，读到基本示例一节结尾处即可停止阅读，而且你已经创建了一个能够工作的程序。

译文来源： Swen编撰了德语版，BigChimp做了英译，但对内容做了扩展，特别是基本示例后的部分。 lioncn根据英文版翻译为简体中文（翻译ing,请耐心等待）。德语用户请注意：Swen希望保留德语版的原样。如果你想修改德语版，你可以将Swen的版本重新命名并在此基础上重新编撰一个新的德语版。

致谢： 没有Joost 和 Michael 的帮助本教程可能永远不会出现。

（原文：This tutorial intends to show the usage of the SQLdb Package on the basis of practical examples. It is primarily targeted at newbies. If somebody is looking for basics about databases and SQL, he should read the corresponding books. For this tutorial I use Firebird with the example database employee.fdb. Other databases can also be used; some adjustments will need to be made which are mentioned in the text.

While this tutorial may seem long, it mostly is just a lot of text that explains why you should type what you type. As you can see at the end, the amount of actual code you will need for a working application is not that great. More experienced developers will hopefully be able to glance through the instructions and quickly understand what's going on. Also, you can stop at the end of the Basic example chapter and have a working program.

This tutorial is based on a German tutorial by Swen, but it is extended, especially after the Basic example. Swen wants the German version to remain as-is. If this is a problem, we can rename this version and base a new German translation on that.

Thanks to Joost and Michael. Without their help this tutorial probably never would have come about.）

系统需求(Requirements)

Lazarus： 为减少示范实例出错的可能，尽量使用最新版的Lazarus (要求随带的FPC 不低于2.2.2)。如果找不到SQLdb包，现在就安装(Package -> Install/Uninstall packages ... -> SQLDBLaz 1.0.1)

Firebird数据库： 安装不低于2.0版的Firebird。示范实例假定你使用标准安装而未作任何修改(比如管理员用户名为 SYSDBA，密码为 masterkey)，而且安装了示例数据库 employee.fdb 。

其他数据库： 也可使用MySQL, PostgreSQL, Oracle, SQLite 或其他的使用 ODBC 桥接的数据库： 要求数据库/表结构必须根据所使用的数据库而作相应修改（见下文），并使用继承自“TSQLConnector”的对应数据库组件（也如下所示）进行连接。如果所使用的数据库对于事务处理等方面与Firebird有显著差异，请在有关条文的做说明以方便后来者。

（原文：If possible you should use a recent Lazarus version (with FPC 2.2.2 or newer) for this tutorial. If the SQLdb package isn't already installed, you should do it now (Package -> Install/Uninstall packages ... -> SQLDBLaz 1.0.1).

Furthermore you need Firebird (if possible version 2.0 or newer). The examples assume that the standard settings (e.g user name SYSDBA and password masterkey) were not changed, and that you have the employee sample database installed.）

You can use another database (e.g. MySQL, PostgreSQL, Oracle, SQLite or another database using ODBC): you'd have to have the proper database /table structure (see below), and use the relevant TSQLConnector descendant (also indicated below). If your database has significant differences regarding transactions etc. please make a note in the relevant section.）

Win平台下使用Firebird数据库必备的库文件(Firebird database libraries on Windows)

Firebird客户端DLL： 在win平台的开发机上必须安装Firebird客户端DLL。安装位置可以是win的系统目录（如\windows\system32），但最好是安装在开发项目的目录和可执行文件的输出目录中，这样做的好处是，一来是在集成开发环境中开发设计时就能看到数据，二来是能够正确无误地运行编译过的程序。

安装Firebird客户端DLL的最容易的方法是：下载安装Firebird 2.5的嵌入版

方法如下：

展开下载的压缩包，将下列文件复制到开发项目目录： <bash> fbembed.dll firebird.msg ib_util.dll icudt30.dll icuin30.dll icuuc30.dll Microsoft.VC80.CRT.manifest msvcp80.dll msvcr80.dll </bash> Firebird分为两种结构：嵌入式和C/S结构。它们所使用的客户端DLL是通用的。所以再将嵌入式使用的fbembed.dll 改名为C/S结构使用的 fbclient.dll即可，或者将fbembed.dll复制为新文件fbclient.dll，就完成了Firebird客户端DLL的安装。

最后，编译项目－－就算项目为空也编译－－会自动创建输出目录，复制DLL到输出目录。

（原文：Finally, on Windows you will need to have the Firebird client DLLs present, optionally in your system directory, but preferably in your project directory (for design time support in the IDE) and in the output directory where the executable is (to run the compiled program). One easy way to get the client DLLs is: download Firebird Embedded 2.5 from [1] Extract these files to your application directory: <bash> fbembed.dll firebird.msg ib_util.dll icudt30.dll icuin30.dll icuuc30.dll Microsoft.VC80.CRT.manifest msvcp80.dll msvcr80.dll </bash> Rename fbembed.dll to fbclient.dll (the name for a regular, client-server Firebird client). The embedded Firebird DLL can also act as a regular Firebird client.

Finally, compile your project (even if it empty) once to create the output directory, and copy the dlls into that directory.）

其他平台下使用Firebird数据库必备的库文件(Firebird database libraries on other systems)

在Linux/OSX下，也需要安装Firebird客户端共享库文件。 在linux下，使用对应发行版的程序安装方法来安装Firebird客户端包，如Debian中执行 <bash> aptitude install libfbclient2 </bash> 来完成安装。

（原文：On Linux/OSX, you will also need the Firebird client shared libraries. On Linux you can use your distribution's method of getting programs to get the Firebird client packages, e.g. on Debian: <bash> aptitude install libfbclient2 </bash> ）

未安装employee.fdb数据库?(No employee.fdb installed?)

如果没有安装示例数据库 employee.fdb，或者使用其它数据库，请使用如下SQL语句生成最小版本的数据表CUSTOMER，文中后面会利用到。 

/* 创建数据表： */
CREATE TABLE CUSTOMER
(
  CUST_NO CUSTNO NOT NULL,
  CUSTOMER VARCHAR(25) NOT NULL,
  CITY VARCHAR(25),
  COUNTRY VARCHAR(15),
  CONSTRAINT INTEG_60 PRIMARY KEY (CUST_NO)
);

/* 录入几条数据：  */
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2001', 'Michael Design', 'San Diego', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2002', 'VC Technologies', 'Dallas', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2003', 'Klämpfl, Van Canneyt and Co.', 'Boston', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2004', 'Felipe Bank', 'Manchester', 'England');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2005', 'Joost Systems, LTD.', 'Central Hong Kong', 'Hong Kong');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2006', 'Van der Voort International', 'Ottawa', 'Canada');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2007', 'Mrs. Mauvais', 'Pebble Beach', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2008', 'Asinine Vacation Rentals', 'Lihue', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2009', 'Fax', 'Turtle Island', 'Fiji');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2010', 'FPC Corporation', 'Tokyo', 'Japan');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2011', 'Dynamic Intelligence Corp', 'Zurich', 'Switzerland');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2012', '3D-Pad Corp.', 'Paris', 'France');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2013', 'Swen Export, Ltd.', 'Milan', 'Italy');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2014', 'Graeme Consulting', 'Brussels', 'Belgium');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2015', 'Klenin Inc.', 'Den Haag', 'Netherlands');

(原文：If you don't have the employee sample database installed or are using a different database, here is a minimal version of the table we'll be using: 

CREATE TABLE CUSTOMER
(
  CUST_NO CUSTNO NOT NULL,
  CUSTOMER VARCHAR(25) NOT NULL,
  CITY VARCHAR(25),
  COUNTRY VARCHAR(15),
  CONSTRAINT INTEG_60 PRIMARY KEY (CUST_NO)
);

Some data so you can at least show something: 

INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2001', 'Michael Design', 'San Diego', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2002', 'VC Technologies', 'Dallas', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2003', 'Klämpfl, Van Canneyt and Co.', 'Boston', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2004', 'Felipe Bank', 'Manchester', 'England');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2005', 'Joost Systems, LTD.', 'Central Hong Kong', 'Hong Kong');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2006', 'Van der Voort International', 'Ottawa', 'Canada');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2007', 'Mrs. Mauvais', 'Pebble Beach', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2008', 'Asinine Vacation Rentals', 'Lihue', 'USA');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2009', 'Fax', 'Turtle Island', 'Fiji');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2010', 'FPC Corporation', 'Tokyo', 'Japan');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2011', 'Dynamic Intelligence Corp', 'Zurich', 'Switzerland');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2012', '3D-Pad Corp.', 'Paris', 'France');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2013', 'Swen Export, Ltd.', 'Milan', 'Italy');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2014', 'Graeme Consulting', 'Brussels', 'Belgium');
INSERT INTO CUSTOMER (CUST_NO, CUSTOMER, CITY, COUNTRY) VALUES ('2015', 'Klenin Inc.', 'Den Haag', 'Netherlands');

）

基本示例(Basic example)

项目与所需组件(Project and components)

首先，创建一个新Lazarus项目。

在组件面板的SQLdb控件页拖拉一个TIBConnection, 一个 TSQLTransaction 和一个 TSQLQuery 控件到窗体。

TIBConnection： 是 Interbase/Firebird 专用连接组件，使用其它数据库，就必须换用 'SQLDB' 页的相应的其它数据库连接组件，如使用 TSQLite3Connection 连接 SQLite 数据库。关于设置其它数据库连接的方法不在本文讨论范围，感兴趣的可参见 Databases 详细讨论。

TSQLTransaction 和 TSQLQuery： SQLdb 连接所支持的所有数据库都会利用到这两个组件。

显示数据： 利用 'Data Controls' 页的 TDBGrid 组件。先添加 'Data Access' 页内一个 TDatasource 控件后才能将 TDBGrid 连接到数据库。例中使用 'Standard' 页的 TButton 来触发这个动作。

现在已经添加好了首个示例中必须的所有组件。加大 TDBGrid 大小以有足够空间显示表中所有数据。

（原文：First you should create a new Lazarus project.

To get access to our database we need one TIBConnection, one TSQLTransaction and one TSQLQuery component from the 'SQLdb' tab in the component palette. TIBConnection is an Interbase/Firebird specific connection component. If you are using a different database, substitute the proper component from the 'SQLDB' tab, e.g. a TSQLite3Connection for an SQLite database. Discussion of setting up any database access libraries is out of scope for this tutorial; see e.g. Databases for that.

The other two components, TSQLTransaction and TSQLQuery, can be used for all databases that are supported by SQLdb.

To display the data, we use a TDBGrid component, which can be found on the 'Data Controls' tab. To connect this component to the database components we need a TDatasource component from the 'Data Access' tab. To trigger the actions we use a TButton from the 'Standard' tab.

Now we have all components needed for the first example. You can enlarge the TDBGrid to have enough space to display all data.）

组件连接关系(Link the components)

连接组件：如果使用对象检查器是非常简单的，也可以使用代码来实现。

1、设置 IBConnection1 的 'Transaction' 属性指向 'SQLTransaction1'，这会使得 SQLTransaction1 的 'Database' 属性自动变更为 'IBConnection1'；

2、设置 SQLQuery1 的 'Database' 属性指向 'IBConnection1'，Lazarus 会自动添加 'Transaction' 属性值；

3、设置 Datasource1 的 'Dataset' 属性指向 'SQLQuery1'；

4、设置 DBGrid1 的 'Datasource1' 属性指向 'Datasource'。


（原文：Next we need to connect our components. A very simple way is to use the object inspector, but you can also do this in your source code. Change the 'Transaction' property of IBConnection1 to 'SQLTransaction1'. This causes the 'Database' property of SQLTransaction1 to automatically change to 'IBConnection1'. In the next step you should change the 'Database' property of SQLQuery1 to 'IBConnection1'. Lazarus automatically adds the value for the 'Transaction' property. Now we change the 'Dataset' property of Datasource1 to 'SQLQuery1'. Finally we change the 'Datasource' property of DBGrid1 to 'Datasource1'.）

连接到数据库(Connecting to the database)

How can we now show the data from our database on the screen? First we need to tell IBConnection1 where the employee.fdb database is located (usually in the .../examples/empbuild/ subdirectory of your Firebird installation). Again you have the choice, if you want to use the object inspector to assign the path or if you want to do it directly in your source code.

We choose to use the object inspector: set the IBConnection1 'HostName' property to the Firebird server name or IP adddress; use localhost if Firebird is running on your development machine. Change the 'DatabaseName' property of IBConnection1 to the path to the employee.fdb file on the database server(e.g. C:\Program Files\Firebird\Firebird_2_0\examples\empbuild\EMPLOYEE.FDB on a Windows machine).

Before the database server grants access to the data, it will check authorisation via username and password. A serious database application will ask the user for both values, when the application is started, and send these to the server when connecting.

However, for now, to simplify matters, we use the object inspector again to hard code these. Change the 'UserName' property to 'SYSDBA' and 'Password' to 'masterkey'.

Now check if all settings so far are correct: set the 'Connected' property to 'True'. If the database path isn't correct or if username or password are wrong, you will get an error message. If the connection was successful, you should cut it now (set it to 'False').

You should now have something like the following screenshot:

Form and components set up

选择欲显示的数据(Choosing what data to show)

Although the connection was successful, no data was displayed. The reason is simple. We haven't told the database server which data to return: the employee.fdb database contains several tables, and we haven't told Firebird the table we want to see. If you don't know the structure of a database, you can use tools like FlameRobin, to display the contents. Lazarus also provides such a tool - the DataDesktop. You can find it in the /tools/lazdatadesktop/ subdirectory of Lazarus. Open the project lazdatadesktop.lpi and compile it (FPC 2.3.x is currently required) (of course you have saved our example project before).

The DataDesktop in action

Back to our example. We want to display all data from the table 'CUSTOMER'. The SQL instruction for that is: 

select * from CUSTOMER

We need to assign this command to the 'SQL' property of SQLQuery1. In the source code of our project this would look like: 

SQLQuery1.SQL.Text := 'select * from CUSTOMER';

The SQL instruction must be enclosed by single quotes. You also have the ability to assign the content of another component (e.g. Edit1.Text). This is not always a good idea; see Secure programming (a more advanced text) for details on SQL injection.

When the user clicks on the button on our form, data retrieval should start. Let's start coding this. Double click on Button1. Lazarus then creates the skeleton of the necessary procedure. In our source code we should find the following lines: 

procedure TForm1.Button1Click(Sender: TObject);
begin

end;

Between begin and end we must enter the instructions needed to display the data. The 'SQL' property of SQLQuery1 can only be changed, if SQLQuery1 is not active. That's why we close the component first: 

SQLQuery1.Close;

Then we assign our SQL instruction to the 'SQL' property, overwriting any previous SQL commands: 

SQLQuery1.SQL.Text := 'select * from CUSTOMER';

Now we need to establish the connection to the database, activate the transaction and open the query: 

IBConnection1.Connected := True;
SQLTransaction1.Active := True;
SQLQuery1.Open;

You can omit the first two instructions, because they are done automatically by the third instruction (but this will not happen in the contrary case, when you close the connection). If you compile the project at this point, you could already see the data from the 'CUSTOMER' table.

However, a serious application must take care that all open database connections are properly closed when not needed anymore. Otherwise the secondary effects would not be foreseeable. So, we use the OnClose event of our form (create it with a double click in the object inspector): 

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin

end;

To close the connection we use the reverse order compared to our opening code: 

SQLQuery1.Close;
SQLTransaction1.Active := False;
IBConnection1.Connected := False;

小结(Summary)

到目前为止，你已经学会使用 SQLdb 包连接到Firebird数据库，还有如何在屏幕上显示数据表的内容。

遵循前面的步骤，目前代码应该如下所示：

（原文：Up to now we have learned, how to connect to a Firebird database using the SQLdb package and how to display the contents of a table on the screen.

If you followed the previous steps, then your code should look like:） 

unit Unit1; 

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, IBConnection, sqldb, db, FileUtil, Forms, Controls,
  Graphics, Dialogs, DBGrids, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Datasource1: TDatasource;
    DBGrid1: TDBGrid;
    IBConnection1: TIBConnection;
    SQLQuery1: TSQLQuery;
    SQLTransaction1: TSQLTransaction;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
  private
    { private declarations }
  public
    { public declarations }
  end; 

var
  Form1: TForm1; 

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
  SQLQuery1.Close;
  SQLQuery1.SQL.Clear;
  SQLQuery1.SQL.Text:= 'select * from CUSTOMER';
  IBConnection1.Connected:= True;
  SQLTransaction1.Active:= True;
  SQLQuery1.Open;
end;

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  SQLQuery1.Close;
  SQLTransaction1.Active:= False;
  IBConnection1.Connected:= False;
end;

end.

加强版的基本示例(Enhancement of the basic example)

While the application works, we can add some refinements.

动态数据库连接(Dynamic database connection)

Up to now, we used a fixed database server name, database location, username and password for simplicity. As mentioned, "real" applications often let users specify their own username and password.

Let's change the form so we can specify them: add two TEdits from the standard menu. Set their name properties to Username and Password. Set the Password's PasswordChar property to * (the asterisk) for some security. If you want to make it easier (and less secure, of course) to connect, you can set the UserName Text property to a valid database user, such as SYSDBA. You could even set the Password Text property to masterkey, easy for testing on developer machines if security doesn't matter... Cosmetically, adding some labels so people know what they're supposed to type is useful.

Also, to make it easier to connect to any 'employee.fdb' sample database on any Firebird/Interbase server, we add two textboxes for server name and database path. Add another two TEdits, and name them ServerName and DatabaseName. If you want, you can set the 'Text' property to default sensible values for your situation, e.g. localhost and C:\Program Files\Firebird\Firebird_2_5\examples\empbuild\EMPLOYEE.FDB Labels to explain what users need to enter would help here, too.

For clarity, we're going to remove the connection info from our designtime components: on the IBConnection1 component, remove all text from the UserName, Password, DatabaseName and HostName properties.

Now, finally, we need to tell our database connection component how to connect. This should normally only be necessary only at the beginning of an application run. In our case the existing 'Button1' code is a good way to set up the connection: Add code until you get: 

procedure TForm1.Button1Click(Sender: TObject);
begin
  SQLQuery1.Close;
  //Connection settings for Firebird/Interbase database
  //only needed when we have not yet connected:
  if IBConnection1.Connected = false then
  begin
    IBConnection1.HostName := ServerName.Text;
    IBConnection1.DatabaseName := DatabaseName.Text;
    IBConnection1.Username := UserName.Text;
    IBConnection1.Password := Password.Text;
    // Now we've set up our connection, visually show that
    // changes are not possibly any more
    ServerName.ReadOnly:=true;
    DatabaseName.ReadOnly:=true;
    UserName.ReadOnly:=true;
    Password.ReadOnly:=true;
  end;  
  SQLQuery1.SQL.Text:= 'select * from CUSTOMER';
  IBConnection1.Connected:= True;
  SQLTransaction1.Active:= True;
  SQLQuery1.Open;
end;

Now run and test if you can connect.

  • Other databases: obviously, where it says IBConnection1, use your specific connection component. Also, you might need to set other properties on your components, so you might need more textboxes, or different contents.

过滤数据(Filtering data)

Often, tables contain a huge amount of data that the user doesn't want to see (and that might take a long time to query from the database and travel over the network). Let's assume, that only the customers from the USA should be displayed. Therefore the SQL instruction in 'SQLQuery1' would look like: 

select * from CUSTOMER where COUNTRY = 'USA'

... which would translate to something like: 

SQLQuery1.SQL.Text := 'select * from CUSTOMER where COUNTRY = 'USA'';

There are two reasons why we will not use this instruction for our example application:

First there is a problem with the usage of the single quote. The compiler would interpret the quote before USA as a closing quote (the first quote is before the select from...) and so the SQL instruction would become invalid. Solution: double the inside quotes: 

SQLQuery1.SQL.Text := 'select * from CUSTOMER where COUNTRY = ''USA''';

The second, more important reason is the fact, that we probably don't know what constraints the user will want to filter on. We don't want to limit the flexibility of the user.

To get this flexibility, first we change our SQL query statement and replace 'USA' by a placeholder (a parameter in SQL speak): change the Button1click procedure and replace 

SQLQuery1.SQL.Text := 'select * from CUSTOMER';

with 

  SQLQuery1.SQL.Text:= 'select * from CUSTOMER where COUNTRY = :COUNTRY';

The SQL parameter is marked by the leading colon. To allow the user to enter a value for the filter, we place a TEdit component ('Standard' tab in the component palette) on our form. Delete the value of its 'Text' property. We can now fill the SQL parameter with the text, which was entered in TEdit by using the 'Params' property of TSQLQuery. Add this below the previous statement: 

SQLQuery1.Params.ParamByName('COUNTRY').AsString := Edit1.Text;

The parameter can be specified by its position or name. Using the name should improve the readability of the source code, and obviously helps if you insert more parameters in the middle of existing parameters.

Overall the procedure should now look like: 

procedure TForm1.Button1Click(Sender: TObject);
begin
  SQLQuery1.Close;
  //Connection settings for Firebird/Interbase database
  //only needed when we have not yet connected:
  if IBConnection1.Connected = false then
  begin
    IBConnection1.HostName := ServerName.Text;
    IBConnection1.DatabaseName := DatabaseName.Text;
    IBConnection1.Username := UserName.Text;
    IBConnection1.Password := Password.Text;
    // Now we've set up our connection, visually show that
    // changes are not possibly any more
    ServerName.ReadOnly:=true;
    DatabaseName.ReadOnly:=true;
    UserName.ReadOnly:=true;
    Password.ReadOnly:=true;
  end; 
  SQLQuery1.SQL.Text:= 'select * from CUSTOMER where COUNTRY = :COUNTRY';
  SQLQuery1.Params.ParamByName('COUNTRY').AsString := Edit1.Text;
  IBConnection1.Connected:= True;
  SQLTransaction1.Active:= True;
  SQLQuery1.Open;
end;

Now you can play around a bit with filtering using Edit1. If you enter a country that's not present in the database, an empty grid is shown.

错误处理(Error handling)

The application should run, but sometimes, serious problems can occur. Because client and server are usually physically separated, it's often not clear at first sight why a problem occurred. Was the server shut down or has somebody unplugged a network connection? Databases, even embedded databases can crash (e.g. when the disk is full, or just due to a bug), leaving the application hanging.

Access to a database should therefore always be integrated in a try ... except and/or try ... finally loop. Only that way is it ensured, that database errors can be handled and the user isn't left out in the rain. A rudimental routine for our example application could look as follows: 

begin
  try
    SQLQuery1.Close;
    ...
    SQLQuery1.Open;
  except
    //EDatabaseError is a general error, but we're dealing with Firebird/Interbase, so:
    on E: EIBDatabaseError do
    begin
      MessageDlg('Error','A database error has occurred. Technical error message: ' + E.Message,mtError,[mbOK],0);
      Edit1.Text:='';
    end;
  end;
end;
  • Other database users: if you don't use Firebird/Interbase, you can either use the more generic EDatabaseError, or your own specialized databaseerror, if you need more details.

使用表格编辑数据(Editing data using the grid

编辑(Editing)

Up to now, if you tried to edit data in the grid, the changes would not be saved. This is because the SQLQuery1 is not instructed to send the changes to the database transaction at the right moment. We need to fix this, and then commit the transaction in the database, so all changes get written. For this, you would use code like this: 

SQLQuery1.ApplyUpdates; //Pass user-generated changes back to database...
SQLTransaction1.Commit; //... and commit them using the transaction.
//SQLTransaction1.Active now is false

We want to make sure any edits (inserts, updates, deletes) are written to the database:

  • when the users changes the filtering criteria and presses the button to query the database
  • when the form is closed

It makes sense to make a separate procedure for this that is called in those two instances. Go to the code, and add an empty line here: 

  TForm1 = class(TForm)
    Button1: TButton;
    Datasource1: TDatasource;
    DBGrid1: TDBGrid;
    Edit1: TEdit;
    IBConnection1: TIBConnection;
    SQLQuery1: TSQLQuery;
    SQLTransaction1: TSQLTransaction;
*****insert the empty line here****
    procedure Button1click(Sender: TObject);
    procedure Formclose(Sender: TObject; var Closeaction: Tcloseaction);
  private

then type 

    procedure SaveChanges;

press shift-ctrl-c (default combination) to let code completion automatically create the corresponding procedure body.

We need to add error handling and check that the transaction is active - remember, this code also gets called when pressing the button the first time, when the transaction is not active yet. We get: 

procedure Tform1.Savechanges;
// Saves edits done by user, if any.
begin
  try
    if SQLTransaction1.Active=true then
    // Only if we are within a started transaction
    // otherwise you get "Operation cannot be performed on an inactive dataset"
    begin
      SQLQuery1.ApplyUpdates; //Pass user-generated changes back to database...
      SQLTransaction1.Commit; //... and commit them using the transaction.
      //SQLTransaction1.Active now is false
    end;
  except
  on E: EIBDatabaseError do
    begin
      MessageDlg('Error', 'A database error has occurred. Technical error message: ' +
        E.Message, mtError, [mbOK], 0);
      Edit1.Text := '';
    end;
  end;
end;

Now we need to call this procedure at the appropriate moments: 

procedure Tform1.Button1click(Sender: TObject);
begin
  SaveChanges; //Saves changes and commits transaction
  try
    SQLQuery1.Close;
....

and 

procedure Tform1.Formclose(Sender: TObject; var Closeaction: Tcloseaction);
begin
  SaveChanges; //Saves changes and commits transaction
  SQLQuery1.Close;
....

Now test and see if edits made in the dbgrid are saved to the database.

隐藏主键列(Hiding primary key column)

Often, you don't want your users to see autonumber/generated primary keys as they are only meant to maintain referential integrity. If users do see them, they might want to try the edit the numbers, get upset that the numbers change, there are gaps in the numbers, etc.

In our example, CUST_NO is the primary key, with content auto-generated by Firebird using triggers and a sequence/generator. This means that you can insert a new record without specifying the CUST_NO; Firebird will create one automatically.

We could simply change our SQLQuery1.SQL.Text property to not include CUST_NO, but this would lead to problems when editing data - a primary key is handy in those circumstances for uniquely identifying the row/record in question.

Therefore, let's use a trick to query for all columns/fields in the table, but keep the grid from showing the first field, CUST_NO: in the Button1Click procedure, add code so it looks like: 

procedure Tform1.Button1click(Sender: TObject);
begin
...
    SQLQuery1.Open;
    // Hide the primary key column which is the first column in our queries.
    // We can only do this once the DBGrid has created the columns
    DBGrid1.Columns[0].Visible:=false;

Recompile, and check to see if the primary key column is really hidden.

  • Other databases: a lot of other databases use an 'autonumber' or 'autoinc' type of field to provide auto-generated field content. Try changing your table definition and see if it works.

插入新数据(Inserting new data)

If you insert new rows/records without any CUST_NO information you may have noticed that you get an error message: Field CUST_NO is required, but not supplied. This also happens if you hid the CUST_NO column, as in the previous section.

The reason: Lazarus thinks that CUST_NO is required. That's not so strange, because it is a primary key and the underlying table definition in the database does say it is required.

If we can instruct Lazarus that this field is not actually required, we can pass empty values (=NULL values) to the database. Fortunately, a query's field object has a Required property that does exactly that.

Change the code to something like: 

    SQLQuery1.Open;
    {
    Make sure we don't get problems with inserting blank (=NULL) CUST_NO values, e.g.:
    Field CUST_NO is required, but not supplied
    We need to tell Lazarus that, while CUST_NO is a primary key, it is not required
    when inserting new records.
    }
    SQLQuery1.FieldByName('CUST_NO').Required:=false;
    // Hide the primary key column which is the first column in our queries.
    // We can only do this once the DBGrid has created the columns
    DBGrid1.Columns[0].Visible:=false;

删除数据(Deleting data)

Up to now, I haven't found a way to delete records/rows in the grid. While there might be a way to do this using keyboard combinations, you can make it easier for your users by letting them use the mouse to do this. You don't even need to code a single line for this functionality...

On the 'Data Controls' tab, select a TDBNavigator component and drop it on the form, above the grid.

To indicate what the navigator should be linked to, set its DataSource property to your existing datasource ('DataSource1') using the Object Inspector. Now you can use the button on the DBNavigator to delete records, but also insert them, and move around. Also, when editing cells/fields, you can use the Cancel button to cancel your edits.

小结(Summary)

如果按上文的步骤照做，你已经学会从数据库取回数据，过滤数据，在表格中编辑和删除数据。

目前的代码应类似如下所示：

（原文：If you followed along up to now, you can retrieve data from the database, filter it, and edit and delete data in the grid. Your code should look something like this:） 

unit sqldbtutorial1unit;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, IBConnection, sqldb, DB, FileUtil, Forms, Controls,
  Graphics, Dialogs, DBGrids, StdCtrls, DbCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    DatabaseName: TEdit;
    Datasource1: TDatasource;
    DBGrid1: TDBGrid;
    Dbnavigator1: Tdbnavigator;
    Edit1: TEdit;
    Label2: Tlabel;
    Label3: Tlabel;
    Label4: Tlabel;
    Label5: Tlabel;
    Password: TEdit;
    UserName: TEdit;
    ServerName: TEdit;
    IBConnection1: TIBConnection;
    Label1: TLabel;
    SQLQuery1: TSQLQuery;
    SQLTransaction1: TSQLTransaction;
    procedure SaveChanges;
    procedure Button1click(Sender: TObject);
    procedure Formclose(Sender: TObject; var Closeaction: Tcloseaction);
  private
    { private declarations }
  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure Tform1.Savechanges;
// Saves edits done by user, if any.
begin
  try
    if SQLTransaction1.Active=true then
    // Only if we are within a started transaction
    // otherwise you get "Operation cannot be performed on an inactive dataset"
    begin
      SQLQuery1.ApplyUpdates; //Pass user-generated changes back to database...
      SQLTransaction1.Commit; //... and commit them using the transaction.
      //SQLTransaction1.Active now is false
    end;
  except
  on E: EIBDatabaseError do
    begin
      MessageDlg('Error', 'A database error has occurred. Technical error message: ' +
        E.Message, mtError, [mbOK], 0);
      Edit1.Text := '';
    end;
  end;
end;


procedure Tform1.Button1click(Sender: TObject);
begin
  SaveChanges; //Saves changes and commits transaction
  try
    SQLQuery1.Close;
    //Connection settings for Firebird/Interbase database
    //only needed when we have not yet connected:
    if IBConnection1.Connected = false then
    begin
      IBConnection1.HostName := ServerName.Text;
      IBConnection1.DatabaseName := DatabaseName.Text;
      IBConnection1.Username := UserName.Text;
      IBConnection1.Password := Password.Text;
      // Now we've set up our connection, visually show that
      // changes are not possibly any more
      ServerName.ReadOnly:=true;
      DatabaseName.ReadOnly:=true;
      UserName.ReadOnly:=true;
      Password.ReadOnly:=true;
    end;
    SQLQuery1.SQL.Text := 'select * from CUSTOMER where COUNTRY = :COUNTRY';
    SQLQuery1.Params.ParamByName('COUNTRY').AsString := Edit1.Text;
    IBConnection1.Connected := True;
    SQLTransaction1.Active := True; //Starts a new transaction
    SQLQuery1.Open;
    {
    Make sure we don't get problems with inserting blank (=NULL) CUST_NO values, i.e. error message:
    "Field CUST_NO is required, but not supplied"
    We need to tell Lazarus that, while CUST_NO is a primary key, it is not required
    when inserting new records.
    }
    SQLQuery1.FieldByName('CUST_NO').Required:=false;
    {
    Hide the primary key column which is the first column in our queries.
    We can only do this once the DBGrid has created the columns
    }
    DBGrid1.Columns[0].Visible:=false;
  except
    //EDatabaseError is a general error, but we're dealing with Firebird/Interbase, so:
    on E: EIBDatabaseError do
    begin
      MessageDlg('Error', 'A database error has occurred. Technical error message: ' +
        E.Message, mtError, [mbOK], 0);
      Edit1.Text := '';
    end;
  end;
end;

procedure Tform1.Formclose(Sender: TObject; var Closeaction: Tcloseaction);
begin
  SaveChanges; //Saves changes and commits transaction
  SQLQuery1.Close;
  SQLTransaction1.Active := False;
  IBConnection1.Connected := False;
end;

end.

无需改变代码就能在程序中嵌入数据库(Embedded database without code changes)

Win平台下的Firebird(Firebird on Windows)

Win平台Firebird用户的奖赏：如你按本文照做（哪怕你仅仅完成了基本示例），只要将嵌入式Firebird的fbembed.dll 改名为C/S结构Firebird所用的 fbclient.dll，Lazarus程序就可以连接C/S结构Firebird（一般是安装在另一台机器上或者是你的开发机上）。

此外，您也可以复制 employee.fdb数据库到你的应用程序目录，再运行应用程序，既不需安装数据库服务器，也不需要设置“服务器名称”编辑框，就能使用嵌入式Firebird来直接连接到数据库文件。

这为一类用户带来了极大的方便：想给终端用户部署数据库应用程序，但又不想自找麻烦地去安装服务器，免除了烦琐的部署步骤：如检查是否已经安装了服务器，数据库版本是否是正确，防火墙是否开启等。

2011年9月：在近期的 FreePascal的 SVN 开发版本，FPC 尝试首先加载fbembed.dll，所以你不需要再为此而重命名为fbclient.dll。

（原文：A bonus for Firebird users on Windows: if you have been following this tutorial (even if you only did the basic example), you renamed the fbembed.dll embedded Firebird library to fbclient.dll. With this, Lazarus could connect to regular Firebird servers (either on another machine or on your local machine). However, you can also copy the employee.fdb database to your application directory, run the application, clear the Server name TEdit and use Firebird embedded to directly connect to the database file, without any servers set up.

This is great if you want to deploy database applications to end users, but don't want the hassle of installing servers (checking if a server is already installed, if it's the right version, having users check firewalls, etc).

September 2011: in recent development (SVN) versions of FreePascal, FPC tries to first load fbembed.dll, so you need not rename fbclient.dll anymore for this to work.）

Linux/OSX/Unix平台下的Firebird(Firebird on Linux/OSX/Unix)

Linux/OSX 平台下应该也能够找到方法来进行嵌入式部署。参看 Firebird 技巧提示。欢迎修改、完善本节内容。

（原文：There must be a way to get this to work on Linux/OSX. See Firebird for hints and links. Updates to the wiki are welcome.）

其他数据库(Other databases)

你所使用的数据库可能提供同样的功能。 Sqlite 数据库如同它的名字所示，理所当然的可以进行嵌入式部署。欢迎针对你所使用的数据库来修改、完善本节内容。

（原文：Your database might offer similar functionality. Sqlite certainly does as it is meant for embedded deployment. Updates of this wiki for other database systems are welcome.）

参见(See also)

Retrieved from "https://wiki.freepascal.org/index.php?title=SQLdb_Tutorial1/zh_CN&oldid=133255"