Solution 4/fr

From Lazarus wiki

English (en) français (fr) 日本語 (ja) 中文(中国大陆)‎ (zh_CN)

Tutoriel de Pascal Objet : Sous-programmes / Solution de l'exercice

(* Auteur:    Tao Yue
   Date:      13 July 2000
   Description:
      Résout les Tours de Hanoï
   Version:
      1.0 - version originale
*)

program TowersofHanoi;

var
   numdiscs : integer;

(********************************************************)

procedure DoTowers (NumDiscs, OrigPeg, NewPeg, TempPeg : integer);
(* Explanation of variables:
      NumDiscs -- nombre de disque sur OrigPeg
      OrigPeg -- numéro du piquet de la tour
      NewPeg -- numéro du piquet où déplacer la tour
      TempPeg -- piquet pour le stockage temporaire
*)

begin
   (* Faites attention à la condition d'arrêt -- un disque *)
   if NumDiscs = 1 then
      writeln (OrigPeg, ' ---> ', NewPeg)
   (* Faites attention à tous les autres cas *)
   else
      begin
         (* En premier, déplacer tous les disques sauf le disque
            du bas vers TempPeg, en utilisant NewPeg comme piquet
            temporaire pour ce transfert *)
         DoTowers (NumDiscs-1, OrigPeg, TempPeg, NewPeg);
         (* Maintenant, déplacer le disque le plus bas depuis OrigPeg
            vers NewPeg *)
         writeln (OrigPeg, ' ---> ', NewPeg);
         (* Finalement, déplacer les disques qui sont actuellement
            sur TempPeg vers NewPeg, en utilisant OrigPeg comme
            piquet temporaire pour ce transfert *)
         DoTowers (NumDiscs-1, TempPeg, NewPeg, OrigPeg)
      end
end;

(********************************************************)


begin    (* Main *)
   write ('Veuillez entrer le nombre de disques dans la tour ===> ');
   readln (numdiscs);
   writeln;
   DoTowers (numdiscs, 1, 3, 2)
end.     (* Main *)
Sommaire