SqlDBHowto/pl

From Free Pascal wiki
Jump to navigationJump to search

Deutsch (de) English (en) español (es) français (fr) Nederlands (nl) polski (pl) 中文(中国大陆)‎ (zh_CN)

Databases portal

References:

Tutorials/practical articles:

Databases

Advantage - MySQL - MSSQL - Postgres - Interbase - Firebird - Oracle - ODBC - Paradox - SQLite - dBASE - MS Access - Zeos
Instrukcja do SqlDB

Ten tekst jest zaplanowany jako instrukcja w stylu „jak to zrobić”. Chcę odpowiedzieć na kilka pytań jedno po drugim i wyjaśnić, jak korzystać z różnych klas. Wszystkie te pytania są stawiane jedno po drugim i tworzą rodzaj samouczka.

Postaram się to sformułować w taki sposób, aby tekst mógł być użyty zarówno dla Lazarusa, jak i Free Pascala. Jednak przykłady dotyczą FreePascala (czyli są to aplikacje konsolowe).

Gdzie mogę znaleźć oficjalną dokumentację?

Proszę zapoznać się z oficjalną dokumentacją pod adresem dokumentacja SQLDB.

Jak połączyć się z serwerem bazy danych?

SqlDB nie łączy się bezpośrednio z serwerem bazy danych, ale używa klienta, który odpowiada używanemu serwerowi bazy danych. SqlDB wysyła polecenia do biblioteki klienta; biblioteka klienta łączy się z bazą danych i przekazuje polecenia. Oznacza to, że aby nawiązać połączenie z bazą danych, na komputerze musi być zainstalowana biblioteka klienta. W systemie Windows klientem jest zwykle biblioteka .dll, w Linuksie .so, a pod OS/X .dylib.

Gdy biblioteka klienta jest poprawnie zainstalowana, możesz połączyć się z serwerem bazy danych za pomocą komponentu TSQLConnection. Różne komponenty TSQLConnection są dostępne dla różnych serwerów baz danych (patrz SQLdb_Package):

Uwaga dotycząca MySQL - Istnieje wiele różnic pomiędzy wersjami klienta, w tym zakresie, że klienci i połączenia nie mogą być wymieniane. Jeśli zainstalowana jest biblioteka klienta MySQL w wersji 4.1, musisz użyć połączenia TMySQL41Connection. Nie jest to związane z serwerem MySQL; używając biblioteki klienckiej MySQL 4.1 możesz prawdopodobnie połączyć się z serwerem MySQL 5.0 (zobacz dokumentację MySQL, aby dowiedzieć się, jakie kombinacje są obsługiwane).

Chociaż różne bazach danych różnią się w szczegółach, to w praktyce musisz ustawić tylko cztery właściwości, aby połączyć się z serwerem bazy danych:

  • nazwa serwera lub adres IP
  • nazwa bazy danych
  • nazwa użytkownika
  • hasło

Gdy te właściwości są ustawione, możesz utworzyć połączenie za pomocą metody 'open'. Jeśli połączenie nie powiedzie się, zostanie zgłoszony wyjątek EDatabaseError. Użyj właściwości 'connected', aby sprawdzić, czy nawiązano połączenie z serwerem bazy danych. Użyj metody 'close', aby zakończyć połączenie z serwerem.

Program ConnectDB;

{$mode objfpc}{$H+}

uses
  IBConnection;

function CreateConnection: TIBConnection;
begin
  result := TIBConnection.Create(nil);
  result.Hostname := 'localhost';
  result.DatabaseName := '/opt/firebird/examples/employee.fdb';
  result.UserName := 'sysdba';
  result.Password := 'masterkey';
end;
 
var   
  AConnection : TIBConnection;

begin
  AConnection := CreateConnection;
  AConnection.Open;
  if Aconnection.Connected then
    writeln('Połączenie udało się!')
  else
    writeln('Wypisanie tego tekstu nie jest to możliwe! ' +
            'Ten kod nie zostanie wykonany, ponieważ w przypadku ' +
            'niepowodzenia połączenia zgłoszony zostanie wyjątek.');
  AConnection.Close;
  AConnection.Free;
end.

Jeśli zostanie zgłoszony wyjątek, uważnie przeczytaj komunikat o błędzie. Możliwe, że serwer bazy danych nie działa albo nazwa użytkownika, hasło, nazwa bazy danych lub adres IP są wpisane niepoprawnie. Jeśli komunikat o błędzie informuje, że nie można znaleźć biblioteki klienta, to sprawdź, czy klient jest poprawnie zainstalowany. Często komunikat o błędzie zawiera dosłownie nazwę szukanego pliku.

Jak wykonać bezpośrednie zapytania/utworzyć tabelę?

SqlDB - nazwa mówi wszystko - działa tylko z serwerem baz danych, który korzysta z SQL. SQL oznacza 'Structured Query Language' (czyli „Strukturalny język zapytań”). SQL to język opracowany w celu umożliwienia pracy z relacyjnymi bazami danych. Praktycznie każdy system baz danych ma swój własny dialekt, ale duża liczba instrukcji SQL jest taka sama dla wszystkich systemów baz danych.

W FPC wystepują pewne różnice pomiędzy:

  • Instrukcjami SQL, które zwracają informacje (zestaw danych - dataset). W tym celu musisz użyć komponentu TSQLQuery; patrz #Jak odczytać dane z tabeli?.
  • Instrukcjami, które nie zwracają informacji, ale robią coś innego, np. uaktualniają dane. W tym celu możesz również użyć metody 'ExecuteDirect' połączenia TSQLConnection. (Możesz również użyć tego, jeśli otrzymujesz w odpowiedzi zestaw danych, ale nie jesteś zainteresowany wynikami, np. w możliwej do wybrania procedurze składowanej).

Większość systemów baz danych wykonuje instrukcje SQL w ramach transakcji. Jeśli chcesz, aby zmiany dokonane w ramach transakcji były dostępne w innych transakcjach lub te zmiany były dostępne nawet po zamknięciu transakcji(!), musisz zatwierdzić transakcję instrukcją 'commit'.

Do obsługi transakcji w Sqldb służy komponent TSQLTransaction. Instrukcja SQL wykonywana przez Sqldb zawsze musi być wykonywana w ramach transakcji, nawet jeśli system bazy danych nie obsługuje transakcji. Ponadto istnieją systemy baz danych, które obsługują transakcje, ale dla których TSQLConnection nie obsługuje (jeszcze) transakcji. Nawet wtedy musisz użyć komponentu TSQLTransaction.

Aby użyć TSQLConnection.ExecuteDirect do wykonania instrukcji SQL, musisz określić, która transakcja ('Transaction') ma być użyta. Z kolei, aby skorzystać z TSQLTransaction musisz określić, który komponent TSQLConnection ma być użyty.

Poniższy przykład tworzy tabelę 'TBLNAMES' z polami 'NAME' i 'ID' oraz wstawia dwa rekordy. Tym razem przy użyciu SQLite. Użyte instrukcje SQL nie zostały wyjaśnione. Więcej informacji na temat instrukcji SQL, ich użycia i składni można znaleźć w dokumentacji systemu baz danych. Zauważ, że ten przykład nie próbuje wychwycić żadnych błędów, to bardzo źle! Zajrzyj do Wyjątki.

program CreateTable;
{$mode objfpc} {$ifdef mswindows}{$apptype console}{$endif}
uses
  sqldb, sqlite3conn; 
 
var 
  AConnection : TSQLite3Connection;
  ATransaction : TSQLTransaction;
 
begin
  AConnection := TSQLite3Connection.Create(nil);
  AConnection.DatabaseName := 'test_dbase';
 
  ATransaction := TSQLTransaction.Create(AConnection);
  AConnection.Transaction := ATransaction;
  AConnection.Open;
  ATransaction.StartTransaction;
  AConnection.ExecuteDirect('create table TBLNAMES (ID integer, NAME varchar(40));'); 
 
  ATransaction.Commit;
 
  ATransaction.StartTransaction;
  AConnection.ExecuteDirect('insert into TBLNAMES (ID,NAME) values (1,''Name1'');'); 
  AConnection.ExecuteDirect('insert into TBLNAMES (ID,NAME) values (2,''Name2'');'); 
  ATransaction.Commit; 
  AConnection.Close;
  ATransaction.Free;	
  AConnection.Free;
end.

Jak odczytać dane z tabeli?

Użyj komponentu TSQLQuery, aby odczytać dane z tabeli. Komponent TSQLQuery musi być połączony z komponentem TSQLConnection i komponentem TSQLTransaction, aby mógł poprawnie wykonać swoją pracę. Ustawienie TSQLConnection i TSQLTransaction zostało omówione w #Jak połączyć się z serwerem bazy danych? i #Jak wykonać bezpośrednie zapytania/utworzyć tabelę?.

Gdy TSQLConnection, TSQLTransaction i TSQLQuery są połączone, TSQLQuery wymaga dalszej konfiguracji do pracy. TSQLQuery ma właściwość 'SQL' zawierającą obiekt TStrings. Ta właściwość 'SQL' zawiera instrukcję SQL, która musi zostać wykonana. Jeśli wszystkie dane z tabeli nazwa_tabeli muszą zostać odczytane, ustaw właściwość 'SQL' na:

'SELECT * FROM nazwa_tabeli;'

.

Użyj metody 'open', aby odczytać tabelę z serwera i umieścić dane w zbiorze danych TSQLQuery. Dostęp do danych można uzyskać za pośrednictwem TSQLQuery, dopóki zapytanie nie zostanie zamknięte za pomocą metody 'close'.

TSQLQuery jest podklasą TDataset. TDataset posiada kolekcję 'Fields', która zawiera wszystkie kolumny tabeli. TDataset śledzi również bieżący rekord. Użyj metod 'First', 'Next', 'Prior' i 'Last', aby zmienić bieżący rekord. 'Bof' zwraca 'True', jeśli osiągnięty został pierwszy rekord, a 'Eof' zwraca 'True', jeśli osiągnięty zostanie ostatni rekord. Aby odczytać wartość pola w bieżącym rekordzie, najpierw znajdź odpowiedni obiekt 'TField', a następnie użyj 'AsString', 'AsInteger' itp.

Przykład: odczyt danych z tabeli

Poniżej znajduje się przykład, który wyświetla wszystkie wartości tabeli, tak jak została stworzona w powyższym przykładzie CreateTable. Skopiuj plik test_database do katalogu roboczego ShowData. Zauważ, że w tym przykładzie także nie przeprowadzono sprawdzania błędów!

Program ShowData;
 {$mode objfpc} {$ifdef mswindows}{$apptype console}{$endif}
uses
  DB, Sysutils, sqldb, sqlite3conn;

var
  AConnection  : TSQLConnection;
  ATransaction : TSQLTransaction;
  Query        : TSQLQuery;
 
begin
  AConnection := TSQLite3Connection.Create(nil);
  ATransaction := TSQLTransaction.Create(AConnection);
  AConnection.Transaction := ATransaction;
  AConnection.DatabaseName := 'test_dbase';
  Query := TSQLQuery.Create(nil);
  Query.SQL.Text := 'select * from tblNames';
  Query.Database := AConnection;
  Query.Open;
  while not Query.Eof do
  begin
    Writeln('ID: ', Query.FieldByName('ID').AsInteger, 'Name: ' +
                                  Query.FieldByName('Name').AsString);
    Query.Next;
  end;
  Query.Close;
  AConnection.Close;
  Query.Free;
  ATransaction.Free;
  AConnection.Free;
end.

(Powyższy kod oczywiście nie jest całkiem ukończony, bo brakuje mu bloków 'try...finally'. Jednak powyższy kod ma na celu pokazanie kodu obsługi bazy danych, a zatem pominięto ostatnie poprawki.) Należy pamiętać, że 'TSQLTransaction.StartTransaction' nie jest używany. To nie jest konieczne. Po otwarciu TSQLQuery, wykonywane jest polecenie SQL, a jeśli żadna transakcja nie jest dostępna, to transakcja jest uruchamiana automatycznie. Programista nie musi jawnie rozpoczynać transakcji. To samo dotyczy połączenia utrzymywanego przez TSQLConnection. Połączenie jest otwierane w razie potrzeby, wiersz 'Aconnection.Open' nie jest tak naprawdę wymagany. Jeśli transakcja TSQLTransaction zostanie zniszczona, zostanie wykonane automatyczne wycofanie. Ewentualne zmiany danych zawartych w transakcji zostaną utracone.

Dlaczego TSQLQuery.RecordCount zawsze zwraca wartość 10?

Aby policzyć rekordy w zbiorze danych, użyj '.RecordCount'. Zauważ jednak, że '.RecordCount' pokazuje liczbę rekordów, które zostały już załadowane z serwera. Ze względu na wydajność, SqlDB domyślnie nie odczytuje wszystkich rekordów podczas otwierania TSQLQuery, a tylko pierwsze 10. Dopiero po uzyskaniu dostępu do jedenastego rekordu zostanie załadowany następny zestaw 10 rekordów itd. Użycie metody '.Last' sprawi, że wszystkie rekordy zostaną załadowane.

Jeśli chcesz poznać rzeczywistą liczbę rekordów na serwerze, możesz najpierw wywołać '.Last', a następnie '.RecordCount'.

Dostępny jest też sposób alternatywny. Liczbę rekordów zwracanych przez serwer określa właściwość '.PacketRecords'. Wartość domyślna to 10; jeśli ustawisz ją na -1, to wszystkie rekordy zostaną załadowane jednocześnie.

W obecnej stabilnej wersji FPC '.RecordCount' nie uwzględnia filtrów, tj. pokazuje sumę niefiltrowanych rekordów.

Jeśli potrzebujesz dokładnej liczby rekordów, często lepszym pomysłem jest bezpośrednie zapytanie o liczbę rekordów w zapytaniu za pomocą innego zapytania SQL, ale musisz to zrobić w tej samej transakcji, ponieważ inne transakcje mogły zmienić liczbę rekordów w międzyczasie.

Lazarus

Lazarus posiada różne komponenty do wyświetlania danych z zestawu TDataset na formularzu. Zamiast instrukcji While-loop i Writeln, jak pokazano powyżej, można użyć komponentów do wyświetlenia danych w tabeli. Umieść na formularzu odpowiednie komponenty TSQLConnection, TSQLTransaction i TSQLQuery, a następnie połącz je i odpowiednio ustaw. Dodatkowo będziesz potrzebować TDatasource; ustaw właściwość 'TDatasource.Dataset' na używany komponent TSQLQuery. (Uwaga nie ustawiaj właściwości 'TSQLQuery.Datasource' na użyty komponent TDatasource. Właściwość 'TSQLQuery.Datasource' jest używana tylko w tabelach master-detail - patrz MasterDetail). Następnie możesz umieścić TDBGrid na formularzu i ustawić właściwość 'Datasource' siatki na komponent TDatasource, który dodałeś wcześniej.

Aby sprawdzić, czy wszystko działa, ustaw właściwość 'Connected' TSQLConnection na 'True' w Lazarus IDE. IDE natychmiast spróbuje połączyć się z serwerem bazy danych. Jeśli to zadziała, możesz ustawić właściwość 'TSQLQuery.Active' na 'True'. Jeśli wszystko jest w porządku, zobaczysz - w IDE - bezpośrednio na ekranie wszystkie dane z tabeli.

Jak zmienić dane w tabeli?

Aby zmienić dane w rekordzie (lub rekordach), powrzechną praktyką jest użycie TSQLQuery do pobrania rekordów, które chcesz zmienić, wprowadzienie tam zmian, a następnie przesłanie ich z powrotem do bazy danych. TDataSet (z którego pochodzi TSQLQuery) musi być ustawiony na tryb edycji. Aby przejść do trybu edycji, wywołaj metody '.Edit', '.Insert' lub '.Append'. Użyj metody '.Edit', aby zmienić bieżący rekord. Użyj '.Insert', aby wstawić nowy rekord przed bieżącym rekordem. Użyj '.Append', aby wstawić nowy rekord na końcu tabeli. W trybie edycji możesz zmieniać wartości pól poprzez właściwość 'Fields'. Użyj metody 'Post', aby sprawdzić poprawność nowych danych, jeśli dane są prawidłowe, tryb edycji zostaje opuszczony. Jeśli przejdziesz do innego rekordu - na przykład używając '.Next' - i zestaw danych jest w trybie edycji, to najpierw zostanie wywołany '.Post'. Użyj metody '.Cancel', aby odrzucić wszystkie zmiany wprowadzone od ostatniego wywołania '.Post' i wyjść z trybu edycji.

Query.Edit;
Query.FieldByName('NAME').AsString := 'Edited name';
Query.Post;

Powyższe nie jest jeszcze pełną historią. TSQLQuery wywodzi się z TBufDataset, który wykorzystuje buforowane aktualizacje. Aktualizacja buforowana oznacza, że ​​po wywołaniu 'Post' zmiany w zestawie danych są widoczne od razu, ale nie są wysyłane na serwer bazy danych. Dzieje się tak, że zmiany są utrzymywane w dzienniku zmian. Po wywołaniu metody '.ApplyUpdates' wszystkie zmiany w dzienniku zmian są wysyłane do bazy danych. Dopiero wtedy serwer bazy danych będzie wiedział o zmianach. Zmiany są wysyłane na serwer w ramach transakcji TSQLTransaction. Upewnij się, że poprawnie ustawiłeś transakcję przed wywołaniem 'ApplyUpdates'. Po zastosowaniu aktualizacji należy wykonać zatwierdzenie, aby zapisać zmiany na serwerze bazy danych.

Poniżej znajduje się przykład zmiany danych w tabeli, przesłanie zmian na serwer i zatwierdzenie transakcji. Ponownie, bez sprawdzania błędów, więc jest to nadal źle!

Program EditData;
{$mode objfpc} {$ifdef mswindows}{$apptype console}{$endif}
uses
    db, sqldb, sqlite3conn;
var 
  AConnection : TSQLConnection;
  ATransaction : TSQLTransaction;
  Query : TSQLQuery;
 
begin
  AConnection := TSQLite3Connection.Create(nil);
  ATransaction := TSQLTransaction.Create(AConnection);
  AConnection.Transaction := ATransaction;
  AConnection.DatabaseName := 'test_dbase';
  Query := TSQLQuery.Create(nil);
  Query.DataBase := AConnection;
  Query.SQL.Text := 'select * from tblNames where ID = 2';
  Query.Open;
  Query.Edit;
  Query.FieldByName('NAME').AsString := 'Name Number 2';
  Query.Post;
  Query.UpdateMode := upWhereAll;         // zdefiniowany w db
  Query.ApplyUpdates;
  ATransaction.Commit;
  Query.Free;
  ATransaction.Free;
  AConnection.Free;
end.

Rzeczywista praca zaczyna się od instrukcji SQL „select * from tblNames where ID = 2” identyfikującej rekord (lub rekordy), który chcesz zmienić. Jeśli pominiesz część "where ID = 2", TSQLQuery pozornie ustawi ID (i inne pola liczb całkowitych?) na 1. I dlatego będzie działać tylko na rekordach, w których ID=1. Aby zapoznać się z właściwością 'UpdateMode', czytaj dalej.

W jaki sposób SqlDB wysyła zmiany do serwera bazy danych?

W przykładzie kodu w #Jak zmienić dane w tabeli? znajdziesz linię

Query.UpdateMode := upWhereAll;

bez wyjaśnienia, co ona robi. Najlepszym sposobem, aby dowiedzieć się, co robi ta linia, jest pominięcie jej. Jeśli pominiesz instrukcję i dokładnie wykonasz ten przykład, to otrzymasz następujący komunikat o błędzie: Nie określono zapytania o aktualizację i nie udało się go wygenerować. (Brak pól do umieszczenia w miejscu, w którym znaleziono oświadczenie) Aby zrozumieć, co poszło nie tak, musisz zrozumieć, w jaki sposób zmiany są wysyłane do serwera bazy danych. Jedynym sposobem uzyskania danych na serwerze SQL jest wykonywanie zapytań SQL. SQL ma trzy typy zapytań dla trzech różnych sposobów manipulowania rekordem. Aby utworzyć nowy rekord, zmienić lub usunąć wstawienie rekordu, instrukcje aktualizacji i usunięcia są wykonywane odpowiednio. Oświadczenie o aktualizacji może wyglądać następująco:

update TBLNAMES set NAME='Edited name' where ID=1;

Aby wysłać zmianę do serwera bazy danych, Sqldb musi złożyć zapytanie aktualizacyjne. Do złożenia zapytania potrzebne są trzy rzeczy:

Nazwa tabeli
nazwa tabeli jest pobierana podczas analizowania zapytania wybierającego, chociaż nie zawsze to działa.
Klauzula UPDATE lub INSERT
zawierają pola, które należy zmienić.
Klauzula WHERE
zawiera pola określające, które rekordy powinny zostać zmienione.

Każde pole (każde TField w Fields) ma właściwość ProviderFlags. Tylko pola z pfInUpdate w ProviderFlags będą używane w klauzuli aktualizacji lub wstawiania zapytania. Domyślnie wszystkie pola mają ustawione „pfInUpdate” we właściwości „ProviderFlags”.

To, które pola są używane w klauzuli WHERE zależy od właściwości UpdateMode zapytania oraz właściwości ProviderFlags pól. Pola, które mają wartość pfInkey we właściwości ProviderFlags są zawsze używane w klauzuli WHERE. Pole będzie miało automatycznie ustawioną flagę pfInKey, jeśli pole jest częścią klucza podstawowego tabeli, a 'TSQLQuery.UsePrimaryKeyAsKey' zwraca wartość 'True'.

Domyślna wartość UpdateMode zapytania to upWhereKeyOnly. W tym trybie aktualizacji tylko pola z pfInkey we właściwości ProviderFlags są używane w klauzuli WHERE. Jeśli żadne z pól nie ma ustawionej flagi pfInKey, wówczas żadne pola nie są dostępne dla klauzuli WHERE i zostanie zwrócony komunikat o błędzie z początku tej sekcji. Możesz rozwiązać problem poprzez:

  • Dodanie klucza podstawowego do tabeli i ustawienie TSQLQuery.UsePrimaryKeyAsKey na 'True' lub
  • Ustawienie flagi pfInkey dla jednego lub więcej pól w kodzie.

Właściwość UpdateMode zna jeszcze dwie możliwe wartości. 'upWhereAll' może być użyty do dodania wszystkich pól z flagą 'pfInWhere' ustawioną na klauzulę WHERE. Domyślnie wszystkie pola mają ustawioną tę flagę. 'upWhereChanged' może służyć do dodawania tylko tych pól, które mają ustawioną flagę 'pfInWhere' oraz te, które zostały zmienione w bieżącym rekordzie.

Jak radzić sobie z błędami

Błędy w czasie wykonywania są nieuniknione, dyski mogą się zapełniać, niezbędne biblioteki lub aplikacje pomocnicze mogą być niedostępne, coś idzie nie tak i musimy na to pozwolić. FPC dość dobrze wykrywa i radzi sobie z błędami w czasie wykonywania. Zwykle daje zwięzłe i rozsądne wyjaśnienie, co poszło nie tak. Jednakże z pewnością będziesz chciał samodzielnie monitorować i obsługiwać błędy z wielu powodów -

  • Prawdopodobnie nie chcesz, aby program kończył swoje działanie przy pierwszych oznakach kłopotów.
  • Jeśli będziemy kontynuować, upewnijmy się, że odzyskana jest jakakolwiek pamięć przydzielona w obszarze problemowym, nie chcemy żadnych wycieków pamięci.
  • Jeśli jednak zamierzamy zrobić krok wstecz, dajmy użytkownikowi wyjaśnienie kontekstowe.

Poniższy fragment kodu jest oparty na powyższych przykładach, ale tym razem sprawdza on błędy w krytycznych miejscach. Kluczem są bloki try...finally...end oraz try...except...end. Możesz to przetestować, wykonując takie czynności jak, odinstalowanie SQLite3, umieszczenie fikcyjnego pliku w miejscu bazy danych test_dbase i tak dalej.

program DemoDBaseWithErrors;
{$mode objfpc} {$ifdef mswindows}{$apptype console}{$endif}
uses
  DB, Sysutils, sqldb, sqlite3conn;
var
    Connect : TSQLite3Connection;
    Trans : TSQLTransaction;


procedure WriteTable (Command : string);
begin
	Connect.ExecuteDirect(Command);
    	Trans.Commit;
end;

procedure ReadTable ();
var
   Query : TSQLQuery;
   Count : smallint;
begin
    Count := 0;
    try
        Query := TSQLQuery.Create(nil);
        Query.DataBase := Connect;
        Query.SQL.Text:= 'select * from tblNames';
        Query.Open;          // Spowoduje to również otwarcie Connect
        while not Query.EOF do begin
            writeln('ID: ', Query.FieldByName('ID').AsInteger, '  Name: ' +
                              Query.FieldByName('Name').AsString);
            Query.Next;
            Count := Count + 1;
        end;
    finally
        Query.Close;
        Query.Free;
    end;
    writeln('W sumie znaleziono ' + InttoStr(Count) + ' wierszy.');
end;

procedure FatalError(ClassName, Message, Suggestion : string);
begin
    writeln(ClassName);
    writeln(Message);
    writeln(Suggestion);
    Connect.Close;              // To prawdopodobnie głupie martwienie się o zwolnienie pamięci,
    Trans.free;                 // skoro zamierzamy wywołać halt(), ale to jest demo, dobrze?
    Connect.Free;               
    halt();
end;

begin
    Connect := TSQLite3Connection.Create(nil);
    Trans := TSQLTransaction.Create(Connect);
	Connect.Transaction := Trans;
    Connect.DatabaseName := 'test_dbase';
    try
        if not fileexists(Connect.DatabaseName) then begin
            Connect.Open;   // generuje błąd EInOutError, jeśli (np.) SQLite nie jest zainstalowany
            Trans.StartTransaction;
            WriteTable('create table TBLNAMES (ID integer Primary Key, NAME varchar(40));');
            Trans.Commit;
        end;
        Connect.open;
        Trans.StartTransaction;
        WriteTable('insert into TBLNAMES (NAME) values (''AName1'');');
        WriteTable('insert into TBLNAMES (NAME) values (''AName2'');');
    except
        on E : EDatabaseError do
            FatalError(E.ClassName, E.Message, 'Czy plik zawiera poprawną bazę danych?');
        on E : EInOutError do
            FatalError(E.ClassName, E.Message, 'Czy zainstalowałeś SQLite (i pakiet deweloperski)?');
        on E : Exception do
            FatalError(E.ClassName, E.Message, 'Stało się coś naprawdę złego.');
     end;
    ReadTable();
    Connect.Close;
    Trans.Free;
    Connect.Free;
end.

Jak wykonać zapytanie za pomocą TSQLQuery?

Obok instrukcji zwracających zestaw danych (zobacz #Jak odczytać dane z tabeli?) SQL zawiera instrukcje, które nie zwracają danych. Na przykład instrukcje INSERT, UPDATE i DELETE nie zwracają danych. Instrukcje te można wykonać za pomocą zapytania TSQLConnection.ExecuteDirect, ale można również skorzystać z TSQLQuery. Jeśli nie oczekujesz danych zwrotnych, użyj TSQLQuery.ExecSQL zamiast TSQLQuery.Open. Jak wspomniano wcześniej, użyj "TSQLQuery.Open", aby otworzyć zestaw danych zwrócony przez instrukcję SQL.

Poniższa procedura tworzy tabelę i wstawia dwa rekordy za pomocą TSQLQuery.

procedure CreateTable;
  
var 
  Query : TSQLQuery;
  
begin
  Query := TSQLQuery.Create(nil);
  try
    Query.Database := AConnection;

    Query.SQL.Text := 'create table TBLNAMES (ID integer, NAME varchar(40));';
    Query.ExecSQL;
 
    Query.SQL.Text := 'insert into TBLNAMES (ID,NAME) values (1,''Name1'');';
    Query.ExecSQL;
  
    Query.SQL.Text := 'insert into TBLNAMES (ID,NAME) values (2,''Name2'');';
    Query.ExecSQL;
  finally
    Query.Free;
  end;
end;

Jak używać parametrów w zapytaniu?

W przykładzie kodu #Jak wykonać zapytanie za pomocą TSQLQuery? to samo zapytanie jest używane dwukrotnie, różnią się tylko wartości do wstawienia. Lepszym sposobem na to jest użycie parametrów w zapytaniu.

Składnia parametrów w zapytaniach różni się w zależności od systemu baz danych, ale różnice są obsługiwane przez TSQLQuery. Zastąp wartości w zapytaniu dwukropkiem, po którym następuje nazwa parametru, którego chcesz użyć. Na przykład:

Query.SQL.Text := 'insert into TBLNAMES (ID,NAME) values (:ID,:NAME);';

To zapytanie utworzy dwa parametry: 'ID' i 'NAME'. Aby określić parametry, zapytanie jest parsowane w momencie przypisania lub zmiany tekstu TSQLQuery.SQL. Wszystkie istniejące parametry zostaną usunięte, a nowe parametry zostaną dodane do właściwości 'TSQLQuery.Params'. Przypisywanie wartości do parametru jest podobne do przypisywania wartości do pola w zbiorze danych:

Query.Params.ParamByName('Name').AsString := 'Name1';

W zapytaniu nie można powiedzieć, jakie dane mają być przechowywane w parametrze. Typ danych parametru jest określany w momencie pierwszego przypisania wartości do parametru. Przypisując wartość za pomocą '.AsString', parametrowi przypisywany jest typ danych 'ftString'. Typ danych można określić bezpośrednio, ustawiając właściwość 'DataType'. Jeśli do parametru zostanie przypisany nieprawidłowy typ danych, wystąpią problemy podczas otwierania lub wykonywania zapytania. Zobacz Typ pola bazy danych, aby uzyskać więcej informacji na temat typów danych.

Zapytanie select

Przykładem zapytania select z parametrami byłaby zmiana czegoś takiego:

  Query.SQL.Text := 'select ID,NAME from TBLNAMES where NAME = '''+Edit1.Text+''' ORDER BY NAME ';

na coś takiego:

  Query.SQL.Text := 'select ID,NAME from TBLNAMES where NAME = :NAMEPARAM ORDER BY NAME ';
  Query.Params.ParamByName('NAMEPARAM').AsString := Edit1.Text;

Przykład

Poniższy przykład tworzy taką samą tabelę jak w poprzednim przykładzie, ale teraz używane są parametry:

procedure CreateTableUsingParameters;
  
var 
  Query : TSQLQuery;
  
begin
  Query := TSQLQuery.Create(nil);
  try
    Query.Database := AConnection;

    Query.SQL.Text := 'create table TBLNAMES (ID integer, NAME varchar(40));';
    Query.ExecSQL;

    Query.SQL.Text := 'insert into TBLNAMES (ID,NAME) values (:ID,:NAME);';
    Query.Prepare;
  
    Query.Params.ParamByName('ID').AsInteger := 1;
    Query.Params.ParamByName('NAME').AsString := 'Name1';
    Query.ExecSQL;
  
    Query.Params.ParamByName('ID').AsInteger := 2;
    Query.Params.ParamByName('NAME').AsString := 'Name2';
    Query.ExecSQL;

    //Query.UnPrepare; // nie trzeba tego samemu wywoływać; powinien być wywoływany przez Query.Close
    Query.Close;
  finally
    Query.Free;
  end;
end;

Zauważ, że ten przykład wymaga więcej kodu niż przykład bez parametrów. Jaki jest zatem pożytek z używania parametrów?

Jednym z powodów jest szybkość. Przykład z parametrami jest szybszy, ponieważ serwer bazy danych analizuje zapytanie tylko raz (w instrukcji .Prepare lub przy pierwszym uruchomieniu).

Innym powodem używania przygotowanych instrukcji jest zapobieganie wstrzykiwania SQL (SQL-injection) (zobacz także Bezpieczne programowanie).

Wreszcie w niektórych przypadkach po prostu upraszcza kodowanie.

Rozwiązywanie problemów: rejestrowanie TSQLConnection

Możesz pozwolić TSQLConnection rejestrować to, co robi. Może to być przydatne do dokładnego sprawdzenia, co Twój program Lazarus wysyła do bazy danych, do debugowania samych komponentów bazy danych i być może do optymalizacji zapytań. W dodatku, jeśli używasz przygotowanych instrukcji/sparametryzowanych zapytań (patrz sekcja powyżej), parametry są często wysyłane binarnie przez potomka TSQLConnection (np. TIBConnection), więc nie możesz po prostu skopiować/wkleić zalogowanego SQL do narzędzia zapytań do bazy danych. Niezależnie od tego, rejestrowanie połączeń może dać dużo wglądu w to, co robi twój program.

Alternatywy to:

  1. możesz użyć debuggera do przechodzenia przez kod bazy danych, jeśli zbudowałeś FPC (i Lazarusa) z włączonym debugowaniem.
  2. jeśli używasz sterowników ODBC (przynajmniej w systemie Windows), możesz włączyć wyjście tracelog w panelu sterowania ODBC.
  3. wiele baz danych pozwala monitorować wszystkie komendy wysyłane do niej z określonego adresu IP/połączenia.

Jeśli korzystasz z rejestrowania TSQLConnection, wymagane są dwie rzeczy:

  1. wskaż typy zdarzeń, które Twoje połączenie TSQLConnection powinno rejestrować
  2. skojarz TSQLConnection z funkcją, która odbierze zdarzenia i przetworzy je (zapisze je do pliku, wyświetli na ekranie itp.).

Ta funkcja musi być typu TDBLogNotifyEvent (patrz sqldb.pp), więc musi mieć sygnaturę typu:

TDBLogNotifyEvent = Procedure (Sender : TSQLConnection; EventType : TDBEventType; Const Msg : String) of object;

FPC (lub: sposób manualny)

Przykładem może być fragment kodu:

uses
...
TSQLConnection, //lub obiekt potomny, taki jak TIBConnection, TMSSQLConnection
...
var
type 
  TMyApplication = class(TCustomApplication); // to jest nasza aplikacja, która korzysta z połączenia
...
  private
    // Ten przykład przechowuje zarejestrowane zdarzenia na tej liście ciągów:
    FConnectionLog: TStringList;
...
  protected
    // Ta procedura odbierze zdarzenia, które są rejestrowane przez połączenie:
    procedure GetLogEvent(Sender: TSQLConnection; EventType: TDBEventType; Const Msg : String);
...
  procedure TMyApplication.GetLogEvent(Sender: TSQLConnection;
    EventType: TDBEventType; const Msg: String);
  // Ta procedura jest wywoływana przez TSQLConnection i zapisuje odebrane komunikaty
  // w dzienniku FConnectionLog typu stringlist
  var
    Source: string;
  begin
    // Nicely right aligned...
    case EventType of
      detCustom:   Source:='Custom:  ';
      detPrepare:  Source:='Prepare: ';
      detExecute:  Source:='Execute: ';
      detFetch:    Source:='Fetch:   ';
      detCommit:   Source:='Commit:  ';
      detRollBack: Source:='Rollback:';
      else Source:='Nieznane zdarzenie. Popraw kod programu.';
    end;
    FConnectionLog.Add(Źródło + ' ' + Msg);
  end;

...
  // Musimy powiedzieć naszemu TSQLConnection, co ma rejestrować:
    FConnection.LogEvents:=LogAllEvents; //= [detCustom, detPrepare, detExecute, detFetch, detCommit, detRollBack]
    // ... i do jakiej procedury to połączenie powinno wysyłać zdarzenia:
    FConnection.OnLog:=@Self.GetLogEvent;
...
  // teraz możemy użyć połączenia, a lista ciągów FConnectionLog wypełni się komunikatami dziennika.

Możesz również użyć GlobalDBLogHook TSQLConnection zamiast rejestrować wszystko z wielu połączeń.

Lazarus (lub: szybszy sposób)

Podsumowując, powyższy opis to sposób rejestrowania komend przez FPC, jak wskazano we wstępie; jeśli używasz Lazarusa, szybszym sposobem jest przypisanie obsługi zdarzenia do zdarzenia OnLog TSQLConnection.

Zobacz także